SPLT_Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: split up single region into multiple grids and generate
!          corresponding topology file.
!
! Description: region can be splitted either in i-, j-, or in k-direction.
!
! Input: file names, split direction, number of grids.
!
! Output: to file.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: SPLT_Main.F90,v 1.4 2008/12/06 08:44:51 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

PROGRAM rocflo_split

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE splt_modinterfaces, ONLY : rflo_readregiontopology, &
           rflo_getdimensdummynodes, rflo_getnodeoffset, rflo_readgridregion, &
           splitgrid, splittopology, rflo_writegridregion, &
           rflo_writeregiontopology, buildversionstring
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... loop variables
  INTEGER :: ireg

! ... local variables
  CHARACTER(CHRLEN) :: casenameold, casenamenew, versionstring, headerstring

  INTEGER :: gridformat, splitdirection, nsplits
  INTEGER :: strlen, ibn, ien, inoff, ijnoff
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: margin, versionwidth, errorflag
  INTEGER, PARAMETER :: headerwidth = 53

  TYPE(t_global), POINTER :: globalold, globalnew
  TYPE(t_region), POINTER :: regionsold(:), regionsnew(:)

!******************************************************************************

  ALLOCATE( globalold )
  ALLOCATE( globalnew )

  globalold%nFunTree = 0
  CALL registerfunction( globalold,'ROCFLO_Split',&
  'SPLT_Main.F90' )

! initialize global parameters ------------------------------------------------

  globalold%verbLevel = verbose_none

  globalold%flowType    = flow_steady  ! stationary flow
  globalold%currentTime = -1._rfreal   ! no physical time set
  globalold%currentIter = -1           ! no iteration

  globalold%inDir  = './'              ! directory path
  globalold%outDir = './'

  globalold%nProcAlloc = 1
  globalold%myProcid   = masterproc    ! default process number (not an MPI code)
  globalold%mpierr     = err_none
  globalold%error      = err_none

  globalold%pi  = 4._rfreal*atan(1._rfreal)
  globalold%rad = globalold%pi/180._rfreal

! print header ----------------------------------------------------------------

#ifdef MPI
  CALL mpi_init( globalold%mpierr )
  IF (globalold%mpierr /=0 ) &
    CALL errorstop( globalold,err_mpi_trouble,__line__ )
#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *             ROCFLO-MP: Grid Split Up              *'
  WRITE(stdout,  '(A)') solver_name//'  *             ========================              *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! read user input -------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Case name of old grid:'
  READ(stdin,'(A)') casenameold

  WRITE(stdout,'(A)') solver_name//' Case name of new grid:'
  READ(stdin,'(A)') casenamenew

  WRITE(stdout,'(A)') solver_name//' Grid format (ASCII=1, binary=2):'
  READ(stdin,*) gridformat

  WRITE(stdout,'(A)') solver_name//' Split direction (i=1, j=2, k=3):'
  READ(stdin,*) splitdirection

  WRITE(stdout,'(A)') solver_name//' Number of new regions:'
  READ(stdin,*) nsplits

! figure out grid format

  IF (gridformat <= 1) THEN
    globalold%gridFormat = format_ascii
  ELSE
    globalold%gridFormat = format_binary
  ENDIF

! read old topology -----------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading old topology ...'

  globalold%casename = casenameold

  CALL rflo_readregiontopology( globalold,regionsold )

  IF (globalold%nRegions > 1) THEN
    WRITE(stdout,'(/,A)') solver_name//' Tool works only for SINGLE region.'
#ifdef MPI
    CALL mpi_finalize( globalold%mpierr )
#endif
    stop
  ENDIF

! read old grid ---------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Reading old grid ...'

! allocate memory

  regionsold(1)%nDumCells = 0
  CALL rflo_getdimensdummynodes( regionsold(1),1,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( regionsold(1),1,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

  ALLOCATE( regionsold(1)%levels(1)%grid%xyz(3,ibn:ien),stat=errorflag )
  globalold%error = errorflag
  IF (globalold%error /= 0) CALL errorstop( globalold,err_allocate,__line__ )

! read grid

  CALL rflo_readgridregion( 1,regionsold )

! split the grid --------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name//' Splitting the grid ...'

  globalnew = globalold

  globalnew%casename = casenamenew
  globalnew%nRegions = nsplits

  ALLOCATE( regionsnew(globalnew%nRegions),stat=errorflag )
  globalold%error = errorflag
  IF (globalold%error /= 0) CALL errorstop( globalold,err_allocate,__line__ )

! set global within regionsNew = globalNew

  DO ireg=1,globalnew%nRegions
    regionsnew(ireg)%global => globalnew
  ENDDO

! do the splitting

  CALL splitgrid( splitdirection,regionsold,regionsnew )

  CALL splittopology( splitdirection,regionsold,regionsnew )

! write new grid and topology

  WRITE(stdout,'(A)') solver_name//' Writing data ...'

  DO ireg=1,globalnew%nRegions
    CALL rflo_writegridregion( ireg,regionsnew )
  ENDDO

  CALL rflo_writeregiontopology( regionsnew )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( globalold )

  WRITE(stdout,'(/,A,/)') solver_name//' Finished.'

#ifdef MPI
  CALL mpi_finalize( globalold%mpierr )
#endif

END PROGRAM rocflo_split

!******************************************************************************
!
! RCS Revision history:
!
! $Log: SPLT_Main.F90,v $
! Revision 1.4  2008/12/06 08:44:51  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:01  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/12/03 03:33:15  wasistho
! rflo_modinterfacessplit to splt_modinterfaces
!
! Revision 1.1  2004/12/03 02:41:15  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:45:30  wasistho
! lower to upper case
!
! Revision 1.7  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.6  2003/03/20 22:32:37  haselbac
! Renamed ModInterfaces
!
! Revision 1.5  2003/03/20 19:45:54  haselbac
! Corrected mistake in phased check-in
!
! Revision 1.4  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.3  2002/09/20 22:22:37  jblazek
! Finalized integration into GenX.
!
! Revision 1.2  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/07/12 21:50:08  jblazek
! Added tool to split single grid into multiple regions.
!
!******************************************************************************