RFLO_WriteRegionTopology.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write topology of all regions to file.
!
! Description: none.
!
! Input: regions = region dimensions and topology
!
! Output: to file.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_WriteRegionTopology.F90,v 1.3 2008/12/06 08:44:07 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_writeregiontopology( regions )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, ipatch

! ... local variables
  CHARACTER(2*CHRLEN+4) :: fname

  INTEGER :: bctype, srcl1beg, srcl1end, srcl2beg, srcl2end, errorflag

  TYPE(t_patch), POINTER :: patch

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'RFLO_WriteRegionTopology',&
  'RFLO_WriteRegionTopology.F90' )

! open file & write number of regions

  fname = trim(global%outDir)//trim(global%casename)//'.top'
  OPEN(if_topol,file=fname,form='formatted',status='unknown',iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  WRITE(if_topol,'(A)',err=10) '# topology for: '//trim(global%casename)
  WRITE(if_topol,'(A)',err=10) '#'
  WRITE(if_topol,  *  ,err=10) global%nRegions

! write topology of each region (at grid level 1 - the finest grid)

  DO ireg=1,global%nRegions
    WRITE(if_topol,*,err=10) ireg,regions(ireg)%nGridLevels
    WRITE(if_topol,*,err=10) regions(ireg)%nPatches, &
                                    regions(ireg)%levels(1)%grid%ipc, &
                                    regions(ireg)%levels(1)%grid%jpc, &
                                    regions(ireg)%levels(1)%grid%kpc

! - loop over all patches of a region

    DO ipatch=1,regions(ireg)%nPatches

      patch => regions(ireg)%levels(1)%patches(ipatch)
      bctype = patch%bcType

! --- patch with neighbour

      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
          (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        IF (patch%align) THEN          ! l1 aligned with 11Src
          srcl1beg = -patch%srcL1beg
          srcl1end = -patch%srcL1end
          srcl2beg =  patch%srcL2beg
          srcl2end =  patch%srcL2end
        ELSE                           ! l1 aligned with l2Src
          srcl1beg =  patch%srcL1beg
          srcl1end =  patch%srcL1end
          srcl2beg = -patch%srcL2beg
          srcl2end = -patch%srcL2end
        ENDIF
        WRITE(if_topol,*,err=10)    &
          patch%bcType   ,patch%lbound   , &
          -patch%l1beg   ,-patch%l1end   , &
           patch%l2beg   , patch%l2end   , &
          patch%srcRegion,patch%srcLbound, &
          srcl1beg       ,srcl1end       , &
          srcl2beg       ,srcl2end       , &
          patch%bcCoupled

! --- no neighbour

      ELSE
        WRITE(if_topol,*,err=10)    &
          patch%bcType   ,patch%lbound   , &
          patch%l1beg    ,patch%l1end    , &
          patch%l2beg    ,patch%l2end    , &
          0,0,0,0,0,0    ,patch%bcCoupled
      ENDIF

    ENDDO   ! iPatch
  ENDDO     ! iReg

  CLOSE(if_topol,iostat=errorflag)
  global%error = errorflag
  IF (global%error /= 0) &
    CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )

! error handling --------------------------------------------------------------

  CALL deregisterfunction( global )
  goto 999

10  CONTINUE
  CALL errorstop( global,err_file_write,__line__,'File: '//trim(fname) )

999 CONTINUE

END SUBROUTINE rflo_writeregiontopology

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_WriteRegionTopology.F90,v $
! Revision 1.3  2008/12/06 08:44:07  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:21  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:17  wasistho
! lower to upper case
!
! Revision 1.6  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.5  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.4  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.3  2002/09/20 22:22:35  jblazek
! Finalized integration into GenX.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
!******************************************************************************