PREP_Main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: provide intitial guess for ROCFLO-MP.
!
! Description: the initialization is done sepoarately for each region.
!              Flow conditions can vary between the regions.
!
! Input: case name from the list of arguments
!
! Output: none
!
! Notes: none
!
!******************************************************************************
!
! $Id: PREP_Main.F90,v 1.7 2008/12/06 08:44:50 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

PROGRAM rocflo_init

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
#ifdef GENX
  USE prep_modinterfaces, ONLY : genxinitsolution, genxwritesolution
#endif
  USE prep_modinterfaces, ONLY : rflo_readregiontopology, getgrid, &
           initinputvalues, readinputfile, readbcinputfile, &
           checkbcvalidity, printprepinput, initializeflowfield, &
           rflo_writesolutionregion, buildversionstring
  USE prep_modbcdistribution, ONLY : bcdistributionfiles
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#ifdef GENX
  include 'roccomf90.h'
#endif

! ... loop variables
  INTEGER :: ireg, ilev

! ... local variables
  CHARACTER(CHRLEN) :: casename, verbosity, msg, versionstring, headerstring
#ifdef GENX
  CHARACTER(CHRLEN) :: wins, winv
#endif

  INTEGER :: ipc, jpc, kpc, gridlevel
  INTEGER :: margin, versionwidth, errorflag
  INTEGER, PARAMETER :: headerwidth = 53

  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)

!******************************************************************************

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'ROCFLO_Init',&
  'PREP_Main.F90' )

! initialize global parameters ------------------------------------------------

  global%verbLevel = verbose_none

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = 0._rfreal    ! no physical time set
  global%currentIter = 0            ! no iteration yet
  global%resInit     = 1._rfreal

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = masterproc    ! default process number (if not MPI)
  global%mpierr     = err_none
  global%error      = err_none

  global%pi  = 4._rfreal*atan(1._rfreal)
  global%rad = global%pi/180._rfreal

! print header ----------------------------------------------------------------

!#ifdef MPI
!  CALL MPI_Init( global%mpierr )
!  IF (global%mpierr /=0 ) CALL ErrorStop( global,ERR_MPI_TROUBLE,__LINE__ )
!#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *        ROCFLO-MP: Solution Initialization         *'
  WRITE(stdout,  '(A)') solver_name//'  *        ==================================         *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! print required input and read argument list ---------------------------------

  WRITE(stdout,'(/,A,/,A,/,8(A,/))') &
    solver_name//' Required Rocflo-Prep input:', &
    solver_name, &
    solver_name//'   <casename>        =>  command line input', &
    solver_name//'   <verbosity>       =>  command line input', &
    solver_name//'   grid level        => .inp file: # MULTIGRID: START', &
    solver_name//'   input grd format  => .inp file: # FORMATS: GRID', &
    solver_name//'   output sol format => .inp file: # FORMATS: SOLUTION', &
    solver_name//'   unsteadiness      => .inp file: # TIMESTEP: FLOWTYPE', &
    solver_name//'   spec. heat ratio  => .inp file: # REFERENCE: GAMMA', &
    solver_name//'   initial solution  => .inp file: # INITFLOW: all'

  CALL getarg(1,casename)
  CALL getarg(2,verbosity)

  IF (len_trim(casename)==0 .OR. &
      len_trim(verbosity)==0) THEN
    WRITE(stdout,'(/,A,/)') &
      solver_name//' Usage: rfloprep <casename> <verbosity>'
!#ifdef MPI
!    CALL MPI_Finalize( global%mpierr )
!#endif
    stop
  ENDIF

  READ(casename ,*) global%casename
  READ(verbosity,*) global%verbLevel

! initial process for Genx ----------------------------------------------------

#ifdef GENX
  CALL com_init

! load Rocout module
  CALL com_set_verbose( 1 )
  CALL rocout_load_module( 'OUT')
#endif

! read, check and print user input --------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading region topology ...'

  CALL rflo_readregiontopology( global,regions )

  WRITE(stdout,'(A)') solver_name//' Reading user input file  ...'

  CALL initinputvalues( regions )

  CALL readinputfile( regions )

  WRITE(stdout,'(A)') solver_name//' Checking BC consistency  ...'

  CALL readbcinputfile( regions )

  CALL checkbcvalidity( regions )

  IF (global%verbLevel >= verbose_low) CALL printprepinput( regions )

! check grid level and obtain volume grid -------------------------------------

  WRITE(stdout,'(A)') solver_name//' Reading grid  ...'

  gridlevel = global%startLevel

  DO ireg=1,global%nRegions
    IF (regions(ireg)%nGridLevels < gridlevel) THEN
      WRITE(msg,1000) solver_name,ireg,gridlevel
      CALL errorstop( global,err_grid_level,__line__,msg )
    ENDIF
    DO ilev=2,regions(ireg)%nGridLevels
      ipc = regions(ireg)%levels(ilev-1)%grid%ipc
      jpc = regions(ireg)%levels(ilev-1)%grid%jpc
      kpc = regions(ireg)%levels(ilev-1)%grid%kpc
      regions(ireg)%levels(ilev)%grid%ipc = ipc/2
      regions(ireg)%levels(ilev)%grid%jpc = jpc/2
      regions(ireg)%levels(ilev)%grid%kpc = kpc/2
    ENDDO
    
    CALL getgrid( gridlevel,ireg,regions )
  ENDDO

! create bc distribution files if applicable ----------------------------------

  WRITE(stdout,'(A)') solver_name//' Write BC distribution to files ...'

  CALL bcdistributionfiles( regions )

! check for Genx format -------------------------------------------------------

  IF (global%solutFormat==2) THEN
#ifndef GENX
    CALL errorstop( global,err_unknown_format,__line__, &
         'compile with GENX=1 for format=2 (Genx HDF format)' )
#endif
  ENDIF

! generate initial guess (regionwise) -----------------------------------------

  WRITE(stdout,'(A)') solver_name//' Generating and storing solution ...'

  DO ireg=1,global%nregions
    WRITE(stdout,'(A,I5.5)') solver_name//'   - region ',ireg

    IF (global%solutFormat==2) THEN
#ifdef GENX
      CALL genxinitsolution( gridlevel,ireg,regions,wins,winv )
      CALL genxwritesolution( gridlevel,ireg,regions(ireg),wins,winv )
#endif
    ELSE
      CALL initializeflowfield( gridlevel,regions(ireg) )
      CALL rflo_writesolutionregion( ireg,regions )

      DEALLOCATE( regions(ireg)%levels(gridlevel)%mixt%cv,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF   !  solFormat
  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

!#ifdef MPI
!  CALL MPI_Finalize( global%mpierr )
!#endif

1000 FORMAT(a,' Region ',i5,', grid level= ',i2,'.')

END PROGRAM rocflo_init

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PREP_Main.F90,v $
! Revision 1.7  2008/12/06 08:44:50  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:18:00  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2005/05/03 03:20:01  wasistho
! enabled modified cyl.Taylor inflow profile
!
! Revision 1.4  2005/05/02 18:07:54  wasistho
! added cylindrical Taylor inflow profile capability
!
! Revision 1.3  2005/04/29 03:31:45  wasistho
! added distribution bc file generator
!
! Revision 1.2  2004/12/03 03:29:42  wasistho
! rflo_modinterfacesprep to prep_modinterfaces
!
! Revision 1.1  2004/12/03 02:20:08  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:40:49  wasistho
! lower to upper case
!
! Revision 1.30  2004/11/16 07:16:32  jiao
! Updated to call Rocout_load_module directly instead of calling through
! COM_load_module, to allow static linking.
!
! Revision 1.29  2004/11/14 17:23:09  jiao
! Removed conditional compilation for CHARM.
!
! Revision 1.28  2004/11/14 05:42:16  jiao
! Changed to use TCHARM_GETARG when CHARM is defined.
!
! Revision 1.27  2004/09/08 05:18:30  wasistho
! commented ifdef MPI, as it is always one processor operation anyway
!
! Revision 1.26  2004/07/28 01:47:04  wasistho
! cosmetics and cleanup
!
! Revision 1.25  2004/07/27 20:28:13  wasistho
! added readBcInputFile and checkBcValidity
!
! Revision 1.24  2004/07/27 03:34:47  wasistho
! add printPrepInput
!
! Revision 1.23  2004/07/23 04:32:18  wasistho
! Genx: readin from Rocin, standalone: read .inp file i.o. command line input
!
! Revision 1.22  2004/06/30 00:00:19  wasistho
! migrated to Roccom-3
!
! Revision 1.21  2003/05/25 18:11:30  jiao
! Added support for Charm.
!
! Revision 1.20  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.19  2003/04/10 03:44:38  jblazek
! Merged .ini file into .inp file.
!
! Revision 1.18  2003/03/20 23:31:50  jiao
! ACH: Changed ModInterfaces to RFLO_ModInterfacesPrep.
!
! Revision 1.17  2003/03/20 19:44:22  haselbac
! Corrected mistake in phased check-in
!
! Revision 1.16  2003/03/20 19:35:43  haselbac
! Modified RegFun call to avoid probs with long 'PREP_Main.F90' names
!
! Revision 1.15  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.14  2002/09/20 22:22:37  jblazek
! Finalized integration into GenX.
!
! Revision 1.13  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.12  2002/07/16 21:34:37  jblazek
! Prefixed screen output with SOLVER_NAME.
!
! Revision 1.11  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
! Revision 1.10  2002/06/14 17:35:11  jblazek
! Added version string.
!
! Revision 1.9  2002/06/07 16:40:37  jblazek
! Grid & solution for all regions in one file.
!
! Revision 1.8  2002/03/18 21:31:55  jblazek
! Made codes compatible with MPI.
!
! Revision 1.7  2002/02/21 23:25:07  jblazek
! Blocks renamed as regions.
!
! Revision 1.6  2002/02/16 07:16:00  jblazek
! Added implicit residual smoothing.
!
! Revision 1.5  2002/01/11 17:20:19  jblazek
! Added time stamp or iteration number to file names.
!
! Revision 1.4  2002/01/10 18:21:30  jblazek
! Added iteration number and initial residual to solution file.
!
! Revision 1.3  2002/01/08 22:09:17  jblazek
! Added calculation of face vectors and volumes.
!
! Revision 1.2  2002/01/02 15:57:08  jblazek
! Added flow initialization.
!
! Revision 1.1.1.1  2001/12/03 21:44:05  jblazek
! Import of RocfluidMP
!
!******************************************************************************