PREP_InitializeFlowField.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: initialize flow field in a region.
!
! Description: none.
!
! Input: iReg = region number
!        iLev = grid level
!
! Output: region = region data (mixt%cv)
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PREP_InitializeFlowField.F90,v 1.8 2008/12/06 08:44:50 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE initializeflowfield( iLev,region )

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE prep_modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset
  USE modmixture, ONLY : t_mixt, t_mixt_input
  USE modparameters
  USE prep_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER :: ilev

  TYPE(t_region), TARGET :: region

! ... loop variables
  INTEGER :: i,j,k, ijk, ijkn(8)

! ... local variables
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ibc, iec, ndum, ijknbeg, ijknend
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend, errorflag

  REAL(RFREAL) :: gam1, qvel, xc, xb, xe, velx

  TYPE(t_mixt), POINTER :: mixt
  TYPE(t_mixt_input)    :: input

!******************************************************************************

  CALL registerfunction( region%global,'InitializeFlowField',&
  'PREP_InitializeFlowField.F90' )

! start

  mixt  => region%levels(ilev)%mixt
  input =  region%mixtInput
  ndum  =  region%nDumCells

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
  iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

  ALLOCATE( mixt%cv(5,ibc:iec),stat=errorflag )
  region%global%error = errorflag
  IF (region%global%error /= 0) &
    CALL errorstop( region%global,err_allocate,__line__ )

  IF (input%prepIniCase==initflo_uniform) THEN
    IF (input%iniXsplit > 0.5_rfreal*huge(1._rfreal)) THEN
      DO ijk = ibc,iec
        gam1 = region%global%refGamma - 1._rfreal
        qvel = 0.5_rfreal*(input%iniVelX*input%iniVelX+ &
                           input%iniVelY*input%iniVelY+ &
                           input%iniVelZ*input%iniVelZ)

        mixt%cv(cv_mixt_dens,ijk) = input%iniDens
        mixt%cv(cv_mixt_xmom,ijk) = input%iniVelX*input%iniDens
        mixt%cv(cv_mixt_ymom,ijk) = input%iniVelY*input%iniDens
        mixt%cv(cv_mixt_zmom,ijk) = input%iniVelZ*input%iniDens
        mixt%cv(cv_mixt_ener,ijk) = input%iniPress/gam1 + input%iniDens*qvel
      ENDDO
    ELSE
      DO k=kdcbeg,kdcend
        DO j=jdcbeg,jdcend
          DO i=idcbeg,idcend

            ijk     = indijk(i,j,k,icoff,ijcoff)
            ijkn(1) = indijk(i  ,j  ,k  ,inoff,ijnoff)
            ijkn(2) = indijk(i+1,j  ,k  ,inoff,ijnoff)
            ijkn(3) = indijk(i+1,j+1,k  ,inoff,ijnoff)
            ijkn(4) = indijk(i  ,j+1,k  ,inoff,ijnoff)
            ijkn(5) = indijk(i  ,j  ,k+1,inoff,ijnoff)
            ijkn(6) = indijk(i+1,j  ,k+1,inoff,ijnoff)
            ijkn(7) = indijk(i+1,j+1,k+1,inoff,ijnoff)
            ijkn(8) = indijk(i  ,j+1,k+1,inoff,ijnoff)

            gam1 = region%global%refGamma - 1._rfreal
            xc   = 0.125_rfreal* &
                  (region%levels(ilev)%grid%xyz(xcoord,ijkn(1)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(2)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(3)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(4)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(5)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(6)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(7)) + &
                   region%levels(ilev)%grid%xyz(xcoord,ijkn(8)))
            IF (xc <= input%iniXsplit) THEN 
              qvel = 0.5_rfreal*(input%iniVelX*input%iniVelX+ &
                                 input%iniVelY*input%iniVelY+ &
                                 input%iniVelZ*input%iniVelZ)

              mixt%cv(cv_mixt_dens,ijk) = input%iniDens
              mixt%cv(cv_mixt_xmom,ijk) = input%iniVelX*input%iniDens
              mixt%cv(cv_mixt_ymom,ijk) = input%iniVelY*input%iniDens
              mixt%cv(cv_mixt_zmom,ijk) = input%iniVelZ*input%iniDens
              mixt%cv(cv_mixt_ener,ijk) = input%iniPress/gam1+input%iniDens*qvel
            ELSE
              qvel = 0.5_rfreal*(input%iniVelX2*input%iniVelX2+ &
                                 input%iniVelY2*input%iniVelY2+ &
                                 input%iniVelZ2*input%iniVelZ2)

              mixt%cv(cv_mixt_dens,ijk) = input%iniDens2
              mixt%cv(cv_mixt_xmom,ijk) = input%iniVelX2*input%iniDens2
              mixt%cv(cv_mixt_ymom,ijk) = input%iniVelY2*input%iniDens2
              mixt%cv(cv_mixt_zmom,ijk) = input%iniVelZ2*input%iniDens2
              mixt%cv(cv_mixt_ener,ijk) = input%iniPress2/gam1+input%iniDens2*qvel
            ENDIF  ! xc
          ENDDO    ! i
        ENDDO      ! j
      ENDDO        ! k
    ENDIF          ! iniXsplit
  ENDIF            ! prepIniCase

  IF (input%prepIniCase==initflo_piston_expan) THEN
    DO k=kdcbeg,kdcend
      DO j=jdcbeg,jdcend
        DO i=idcbeg,idcend

          ijk     = indijk(i,j,k,icoff,ijcoff)
          ijkn(1) = indijk(i  ,j  ,k  ,inoff,ijnoff)
          ijkn(2) = indijk(i+1,j  ,k  ,inoff,ijnoff)
          ijkn(3) = indijk(i+1,j+1,k  ,inoff,ijnoff)
          ijkn(4) = indijk(i  ,j+1,k  ,inoff,ijnoff)
          ijkn(5) = indijk(i  ,j  ,k+1,inoff,ijnoff)
          ijkn(6) = indijk(i+1,j  ,k+1,inoff,ijnoff)
          ijkn(7) = indijk(i+1,j+1,k+1,inoff,ijnoff)
          ijkn(8) = indijk(i  ,j+1,k+1,inoff,ijnoff)
          ijknbeg = indijk(1            ,j  ,k  ,inoff,ijnoff)
          ijknend = indijk(idcend-ndum+1,j  ,k  ,inoff,ijnoff)

          gam1 = region%global%refGamma - 1._rfreal
          xc   = 0.125_rfreal* &
                (region%levels(ilev)%grid%xyz(xcoord,ijkn(1)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(2)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(3)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(4)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(5)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(6)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(7)) + &
                 region%levels(ilev)%grid%xyz(xcoord,ijkn(8)))
          xb   = region%levels(ilev)%grid%xyz(xcoord,ijknbeg)
          xe   = region%levels(ilev)%grid%xyz(xcoord,ijknend)

!          velX = (xc-xb)/(xe-xb)*input%iniVelX           ! 1-block
          velx = (xc-input%iniXsplit)/ &                  ! multi-block
                 region%global%refLength*input%iniVelX 

          qvel = 0.5_rfreal*(velx*velx+ &
                             input%iniVelY*input%iniVelY+ &
                             input%iniVelZ*input%iniVelZ)

          mixt%cv(cv_mixt_dens,ijk) = input%iniDens
          mixt%cv(cv_mixt_xmom,ijk) =          velx*input%iniDens
          mixt%cv(cv_mixt_ymom,ijk) = input%iniVelY*input%iniDens
          mixt%cv(cv_mixt_zmom,ijk) = input%iniVelZ*input%iniDens
          mixt%cv(cv_mixt_ener,ijk) = input%iniPress/gam1+input%iniDens*qvel
        ENDDO  ! i
      ENDDO  ! j
    ENDDO  ! k
  ENDIF  ! iniCase

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE initializeflowfield

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PREP_InitializeFlowField.F90,v $
! Revision 1.8  2008/12/06 08:44:50  mtcampbe
! Updated license.
!
! Revision 1.7  2008/11/19 22:18:00  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.6  2005/09/21 20:36:52  wasistho
! added xsplit parameter in pistonExpand case
!
! Revision 1.5  2005/09/21 19:04:15  wasistho
! modified initial condition for expanding piston case
!
! Revision 1.4  2005/09/09 03:30:45  wasistho
! added Expanding-Piston case kernel
!
! Revision 1.3  2005/08/03 17:51:31  wasistho
! added domain-splitting feature to initial condition
!
! Revision 1.2  2004/12/03 03:29:08  wasistho
! rflo_modinterfacesprep to prep_modinterfaces
!
! Revision 1.1  2004/12/03 02:20:08  wasistho
! added prefix
!
! Revision 1.1  2004/12/03 00:40:49  wasistho
! lower to upper case
!
! Revision 1.9  2003/05/15 02:57:07  jblazek
! Inlined index function.
!
! Revision 1.8  2003/04/23 22:51:43  olawlor
! Added TARGET attribute to region variable, since
! pointers are cached into it.
!
! Revision 1.7  2003/03/20 22:27:56  haselbac
! Renamed ModInterfaces
!
! Revision 1.6  2003/03/20 19:44:22  haselbac
! Corrected mistake in phased check-in
!
! Revision 1.5  2003/03/20 19:35:43  haselbac
! Modified RegFun call to avoid probs with long 'PREP_InitializeFlowField.F90' names
!
! Revision 1.4  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.3  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.2  2002/02/21 23:25:07  jblazek
! Blocks renamed as regions.
!
! Revision 1.1  2002/01/02 15:57:08  jblazek
! Added flow initialization.
!
!******************************************************************************