PREP_GetGrid.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: obtain volume and surface grid.
!
! Description: none.
!
! Input: gridLevel  = initial grid level
!        regions    = data for all regions
!        iReg       = region number
!
! Output: vol-grid.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PREP_GetGrid.F90,v 1.7 2008/12/06 08:44:50 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE getgrid( gridLevel,iReg,regions )

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modbndpatch, ONLY   : t_patch
  USE prep_modinterfaces, ONLY : rflo_getdimensdummynodes, &
         rflo_getnodeoffset, rflo_getpatchindicesnodes, rflo_readgridregion, &
         rflo_copygeometrydummy, rflo_extrapolategeometry, &
         rflo_generatecoarsegrids
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER :: gridlevel,ireg
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ipatch, i, j, k, ijkn, ng1, ng2

! ... local variables
  TYPE(t_global), POINTER :: global
  TYPE(t_patch) , POINTER :: patch

  INTEGER :: ilev, lbound, inoff, ijnoff
  INTEGER :: ibn, ien, idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, dims(2), errorflag

!******************************************************************************

  global => regions(1)%global
  CALL registerfunction( global,'GetGrid',&
  'PREP_GetGrid.F90' )

! read grid -------------------------------------------------------------------
  
! allocate memory for grid

  regions(ireg)%currLevel = gridlevel
  ilev                    = regions(ireg)%currLevel

  CALL rflo_getdimensdummynodes( regions(ireg),ilev,idnbeg,idnend, &
                                 jdnbeg,jdnend,kdnbeg,kdnend )
  CALL rflo_getnodeoffset( regions(ireg),ilev,inoff,ijnoff )
  ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
  ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)
  ALLOCATE( regions(ireg)%levels(ilev)%grid%xyz(3,ibn:ien),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! read volume grid

  CALL rflo_readgridregion( ireg,regions )

  CALL rflo_copygeometrydummy( regions(ireg) )      ! copy to dummy nodes
  CALL rflo_extrapolategeometry( regions(ireg) )    ! extrapolate

! define surface grid

  DO ipatch=1,regions(ireg)%nPatches

    patch   => regions(ireg)%levels(ilev)%patches(ipatch)
    lbound  =  patch%lbound

! - get dimensions, allocate memory

    dims(1) = abs(patch%l1end-patch%l1beg) + 2    ! nodal values
    dims(2) = abs(patch%l2end-patch%l2beg) + 2
    ALLOCATE( patch%surfCoord(3,dims(1),dims(2)),stat=errorflag )
    global%error = errorflag
    IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

    CALL rflo_getpatchindicesnodes( regions(ireg),patch,ilev, &
                                    ibeg,iend,jbeg,jend,kbeg,kend )

! - initialize bcSet

    patch%mixt%bcSet = .false.

! - copy coordinates to temporary array

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkn = indijk(i,j,k,inoff,ijnoff)
          IF      (lbound==1 .OR. lbound==2) THEN
            IF (lbound == 2) THEN
              ng1 = j - jbeg + 1
            ELSE
              ng1 = jend - j + 1
            ENDIF
            ng2 = k - kbeg + 1
          ELSE IF (lbound==3 .OR. lbound==4) THEN
            ng1 = k - kbeg + 1
            IF (lbound == 4) THEN
              ng2 = i - ibeg + 1
            ELSE
              ng2 = iend - i + 1
            ENDIF
          ELSE IF (lbound==5 .OR. lbound==6) THEN
            IF (lbound == 6) THEN
              ng1 = i - ibeg + 1
            ELSE
              ng1 = iend - i + 1
            ENDIF
            ng2 = j - jbeg + 1
          ENDIF
          patch%surfCoord(1,ng1,ng2) = &
                    regions(ireg)%levels(ilev)%grid%xyz(xcoord,ijkn)
          patch%surfCoord(2,ng1,ng2) = &
                    regions(ireg)%levels(ilev)%grid%xyz(ycoord,ijkn)
          patch%surfCoord(3,ng1,ng2) = &
                    regions(ireg)%levels(ilev)%grid%xyz(zcoord,ijkn)
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO        ! iPatch

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE getgrid

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PREP_GetGrid.F90,v $
! Revision 1.7  2008/12/06 08:44:50  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:18:00  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/08/19 15:41:06  mparmar
! Renamed patch variables
!
! Revision 1.4  2005/09/30 00:13:16  wasistho
! added copy geometry to dummy
!
! Revision 1.3  2005/05/03 08:17:30  wasistho
! initialized bcSet to false
!
! Revision 1.2  2005/05/03 03:20:17  wasistho
! enabled modified cyl.Taylor inflow profile
!
! Revision 1.1  2005/05/02 18:09:34  wasistho
! added cylindrical Taylor inflow profile capability
!
!
!
!******************************************************************************