PLAG_CECellsFaceVectors.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy face vectors in corner and edge cells from an adjacent 
!          region on the same processor
!
! Description: none.
!
! Input: regions = data of all regions,
!        iReg    = current region number.
!
! Output: plag%si,sj,sk = face vectors.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: PLAG_CECellsFaceVectors.F90,v 1.4 2008/12/06 08:44:33 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_cecellsfacevectors( regions, iReg )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region, t_level, t_dcell
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag 
  USE modindexing, ONLY   : getijk
  USE modinterfaces, ONLY : rflo_getcelloffset,         &
                            rflo_getcornercellsindices, &
                            rflo_getedgecellsindices,   &
                            rflo_getnodeoffset
  USE moderror
  USE modparameters
  USE plag_modparameters
  USE plag_modinterfaces, ONLY : plag_rflo_getfacemapping
  IMPLICIT NONE
  
#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER, INTENT(IN)     :: ireg

! ... loop variables
  INTEGER :: i, icorner, iedge, iface, ijk, j, k, ldir

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev, ncorners, nedges, nfaces, ndir
  INTEGER :: icoff, ijcoff, inoff, ijnoff
  INTEGER :: icoffsrc, ijcoffsrc, iregsrc
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: ijkc, ijkccsrc, ijkecsrc

  INTEGER :: iccsrc, jccsrc, kccsrc
  INTEGER :: iecsrc, jecsrc, kecsrc
  INTEGER :: ndumcellssrc

  INTEGER :: inoffsrc, ijnoffsrc, ijkn, ijkcnsrc, ijkensrc
  INTEGER :: icnsrc, jcnsrc, kcnsrc
  INTEGER :: iensrc, jensrc, kensrc
  INTEGER :: nodecorn, nodecornsrc, nodeedge, nodeedgesrc 
  INTEGER :: idirsrc, jdirsrc, kdirsrc, ldirsrc, ifacesrc
  INTEGER :: srcdir(3),srcface(6)
  INTEGER :: srcindexmapmat(3,4)
  
  REAL(RFREAL), DIMENSION(3,3)          :: sfacecorn, sfaceedge
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: psi, psj, psk, &
                                           psisrc, psjsrc, psksrc

  TYPE(t_region),      POINTER :: pregion
  TYPE(t_level),       POINTER :: plevel
  TYPE(t_global),      POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_CECellsFaceVectors.F90,v $ $Revision: 1.4 $'

  global => regions(ireg)%global
    
  CALL registerfunction( global, 'PLAG_CECellsFaceVectors',&
  'PLAG_CECellsFaceVectors.F90' )

! Get dimensions --------------------------------------------------------------

  ilev  = regions(ireg)%currLevel
  ncorners = 8
  nedges   = 12
  nfaces   = 6
  ndir     = 3

! Set pointers ----------------------------------------------------------------
  
  pregion => regions(ireg)
  plevel  => regions(ireg)%levels(ilev) 

  psi     => regions(ireg)%levels(ilev)%plag%si
  psj     => regions(ireg)%levels(ilev)%plag%sj
  psk     => regions(ireg)%levels(ilev)%plag%sk

! Get node offset ------------------------------------------------------------

  CALL rflo_getnodeoffset( pregion,ilev,inoff,ijnoff )

! Loop over edges -------------------------------------------------------------

  DO iedge=1,nedges 

! - Bypass for noninteracting regions -----------------------------------------

    IF( .NOT. plevel%edgeCells(iedge)%interact ) goto 1999

! -- Bypass for degenerate edge cells -----------------------------------------

    IF( plevel%edgeCells(iedge)%degenrt /= degenerat_none ) goto 1999

! - Loop over edge cell indices -----------------------------------------------
        
    CALL rflo_getedgecellsindices( pregion,ilev,iedge, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )

    ijk = 0 
    DO k=kbeg,kend
    DO j=jbeg,jend
    DO i=ibeg,iend
      ijk     =  ijk + 1
      ijkn = indijk(i,j,k,inoff, ijnoff)

! -- Source region infrastructure ----------------------------------------
            
      iregsrc      = plevel%edgeCells(iedge)%cells(ijk)%srcRegion            

      IF ( iregsrc > 0 ) THEN
        ijkecsrc     = plevel%edgeCells(iedge)%cells(ijk)%srcCell
        ndumcellssrc = regions(iregsrc)%nDumCells

        CALL rflo_getcelloffset( regions(iregsrc),ilev,icoffsrc,ijcoffsrc )
        CALL getijk( ijkecsrc,icoffsrc,ijcoffsrc,ndumcellssrc, &
                     iecsrc,jecsrc,kecsrc )

        CALL rflo_getnodeoffset( regions(iregsrc),ilev,inoffsrc,ijnoffsrc )
        ijkensrc = indijk(iecsrc,jecsrc,kecsrc,inoffsrc,ijnoffsrc)

! -- Find face mapping for source region --------------------------------------
        
        srcindexmapmat= plevel%edgeCells(iedge)%cells(ijk)%srcIndexMapMat 

        CALL plag_rflo_getfacemapping(srcindexmapmat,srcdir,srcface)

        idirsrc = srcdir(1); jdirsrc = srcdir(2); kdirsrc = srcdir(3);

! -- Check if both regions are on the same processor --------------------------

        IF ( regions(iregsrc)%procid == global%myProcid ) THEN

! --- Set pointers for edge cells ---------------------------------------------

          psisrc => regions(iregsrc)%levels(ilev)%plag%si
          psjsrc => regions(iregsrc)%levels(ilev)%plag%sj
          psksrc => regions(iregsrc)%levels(ilev)%plag%sk

! --- Loop over all the Faces -------------------------------------------------
! --- Note: assumption of coordinate alignment between regions removed --------

          DO iface = 1, nfaces
            SELECT CASE (iface)
              CASE(1,3,5)
                nodeedge    = indijk(i,j,k,inoff, ijnoff)

              CASE(2)
                nodeedge    = indijk(i+1,j,k,inoff, ijnoff)

              CASE(4)
                nodeedge    = indijk(i,j+1,k,inoff, ijnoff)

              CASE(6)
                nodeedge    = indijk(i,j,k+1,inoff, ijnoff)
            END SELECT ! iFace  

            ifacesrc = srcface(iface)
            SELECT CASE (ifacesrc)
              CASE(1,3,5)
                nodeedgesrc = indijk(iecsrc,jecsrc,kecsrc,inoffsrc,ijnoffsrc)

              CASE(2)
                nodeedgesrc = indijk(iecsrc+1,jecsrc,kecsrc,inoffsrc,ijnoffsrc)

              CASE(4)
                nodeedgesrc = indijk(iecsrc,jecsrc+1,kecsrc,inoffsrc,ijnoffsrc)

              CASE(6)
                nodeedgesrc = indijk(iecsrc,jecsrc,kecsrc+1,inoffsrc,ijnoffsrc)
            END SELECT ! iFaceSrc

! --- Determine direction mapping for face normals ----------------------------

            DO ldir = 1,ndir
              ldirsrc=srcdir(ldir)
              SELECT CASE (ldirsrc)
                CASE(icoord)
                  sfaceedge(xcoord:zcoord,ldirsrc) = psisrc(xcoord:zcoord,nodeedgesrc)
                
                CASE(jcoord)
                  sfaceedge(xcoord:zcoord,ldirsrc) = psjsrc(xcoord:zcoord,nodeedgesrc)
                
                CASE(kcoord)
                  sfaceedge(xcoord:zcoord,ldirsrc) = psksrc(xcoord:zcoord,nodeedgesrc)
              END SELECT ! ldirSrc
            ENDDO ! ldir

! --- Load face normal vectors ------------------------------------------------
            
            psi(xcoord:zcoord,nodeedge) = sfaceedge(xcoord:zcoord,icoord)
            psj(xcoord:zcoord,nodeedge) = sfaceedge(xcoord:zcoord,jcoord)
            psk(xcoord:zcoord,nodeedge) = sfaceedge(xcoord:zcoord,kcoord)
          ENDDO ! iFace  

        END IF ! procid 
      END IF   ! iRegSrc 

    ENDDO   ! i
    ENDDO   ! j
    ENDDO   ! k

1999 CONTINUE 
      
  ENDDO      ! iEdge
      
! Loop over corners -----------------------------------------------------------

  DO icorner=1,ncorners

! - Bypass for noninteracting regions -----------------------------------------

    IF( .NOT. plevel%cornerCells(icorner)%interact ) goto 2999

! -- Bypass for degenerate corner cells ---------------------------------------

    IF( plevel%cornerCells(icorner)%degenrt /= degenerat_none ) goto 2999

! - Loop over corner cell indices ---------------------------------------------
        
    CALL rflo_getcornercellsindices( pregion,ilev,icorner, &
                                     ibeg,iend,jbeg,jend,kbeg,kend )
        
    ijk = 0 
    DO k=kbeg,kend
    DO j=jbeg,jend
    DO i=ibeg,iend
      ijk  =  ijk + 1
      ijkn = indijk(i,j,k,inoff, ijnoff)
  
! - Source region infrastructure -----------------------------------------
            
      iregsrc  =  plevel%cornerCells(icorner)%cells(ijk)%srcRegion 

      IF ( iregsrc > 0 ) THEN
        ijkccsrc     = plevel%cornerCells(icorner)%cells(ijk)%srcCell           
        ndumcellssrc = regions(iregsrc)%nDumCells

        CALL rflo_getcelloffset( regions(iregsrc),ilev,icoffsrc,ijcoffsrc )
        CALL getijk( ijkccsrc,icoffsrc,ijcoffsrc,ndumcellssrc, &
                     iccsrc,jccsrc,kccsrc )

        CALL rflo_getnodeoffset( regions(iregsrc),ilev,inoffsrc,ijnoffsrc )
        ijkcnsrc = indijk(iccsrc,jccsrc,kccsrc,inoffsrc,ijnoffsrc)

! -- Find face mapping for source region --------------------------------------
        
        srcindexmapmat= plevel%cornerCells(icorner)%cells(ijk)%srcIndexMapMat 

        CALL plag_rflo_getfacemapping(srcindexmapmat,srcdir,srcface)

        idirsrc = srcdir(1); jdirsrc = srcdir(2); kdirsrc = srcdir(3);

! -- Check if both regions are on the same processor --------------------------

        IF ( regions(iregsrc)%procid == global%myProcid ) THEN

! --- Set pointers for corner cells -------------------------------------------

          psisrc => regions(iregsrc)%levels(ilev)%plag%si
          psjsrc => regions(iregsrc)%levels(ilev)%plag%sj
          psksrc => regions(iregsrc)%levels(ilev)%plag%sk

! --- Loop over all the Faces -------------------------------------------------
! --- Note: assumption of coordinate alignment between regions removed --------

          DO iface = 1, nfaces
            SELECT CASE (iface)
              CASE(1,3,5)
                nodecorn    = indijk(i,j,k,inoff, ijnoff)

              CASE(2)
                nodecorn    = indijk(i+1,j,k,inoff, ijnoff)

              CASE(4)
                nodecorn    = indijk(i,j+1,k,inoff, ijnoff)

              CASE(6)
                nodecorn    = indijk(i,j,k+1,inoff, ijnoff)
            END SELECT  ! iFace 

            ifacesrc = srcface(iface)
            SELECT CASE (ifacesrc)
              CASE(1,3,5)
                nodecornsrc = indijk(iccsrc,jccsrc,kccsrc,inoffsrc,ijnoffsrc)

              CASE(2)
                nodecornsrc = indijk(iccsrc+1,jccsrc,kccsrc,inoffsrc,ijnoffsrc)

              CASE(4)
                nodecornsrc = indijk(iccsrc,jccsrc+1,kccsrc,inoffsrc,ijnoffsrc)

              CASE(6)
                nodecornsrc = indijk(iccsrc,jccsrc,kccsrc+1,inoffsrc,ijnoffsrc)
            END SELECT  ! iFaceSrc

! --- Determine direction mapping for face normals ----------------------------

            DO ldir = 1,ndir
              ldirsrc=srcdir(ldir)
              SELECT CASE (ldirsrc)
                CASE(icoord)
                  sfacecorn(xcoord:zcoord,ldirsrc) = psisrc(xcoord:zcoord,nodecornsrc)
                
                CASE(jcoord)
                  sfacecorn(xcoord:zcoord,ldirsrc) = psjsrc(xcoord:zcoord,nodecornsrc)
                
                CASE(kcoord)
                  sfacecorn(xcoord:zcoord,ldirsrc) = psksrc(xcoord:zcoord,nodecornsrc)
              END SELECT ! ldirSrc
            ENDDO ! ldir

! --- Load face normal vectors ------------------------------------------------

            psi(xcoord:zcoord,nodecorn) = sfacecorn(xcoord:zcoord,icoord)
            psj(xcoord:zcoord,nodecorn) = sfacecorn(xcoord:zcoord,jcoord)
            psk(xcoord:zcoord,nodecorn) = sfacecorn(xcoord:zcoord,kcoord)
          ENDDO ! iFace 

        END IF ! procid 
      END IF   ! iRegSrc 
 
    ENDDO   ! i
    ENDDO   ! j
    ENDDO   ! k

2999 CONTINUE

  ENDDO       ! iCorner

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_cecellsfacevectors

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_CECellsFaceVectors.F90,v $
! Revision 1.4  2008/12/06 08:44:33  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:45  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:23  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:57:12  fnajjar
! Initial revision after changing case
!
! Revision 1.7  2004/11/29 19:25:07  fnajjar
! Added bypass statement for dengerate cells
!
! Revision 1.6  2004/02/11 23:12:35  fnajjar
! Included RFLO_GetNodeOffset in ModInterfaces call
!
! Revision 1.5  2004/02/10 21:46:37  fnajjar
! Added capability to remove coordinate alignment between corner-edge regions
!
! Revision 1.4  2004/01/28 16:10:28  fnajjar
! Moved statements inside IF iReg for correct syntax
!
! Revision 1.3  2004/01/14 21:27:24  fnajjar
! Included definition of nFaces
!
! Revision 1.2  2003/12/05 23:45:30  fnajjar
! Fixed metrics for edge and corner cells based on face looping
!
! Revision 1.1  2003/11/12 21:37:59  fnajjar
! Initial import of Corner-Edge cells Infrastructure
!
!******************************************************************************