PLAG_RFLO_FindGridMapping.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: find the grid transformation between regions connecting at 
!          corner-edge cells for proper metrics.
!
! Description: none.
!
! Input: regions = data of all regions,
!        iReg    = current region number.
!
! Output: indexMapMat   = index mapping matrix.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: PLAG_RFLO_FindGridMapping.F90,v 1.4 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_rflo_findgridmapping( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region, t_level, t_dcell
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag 
  USE modindexing, ONLY   : getijk
  USE modinterfaces, ONLY : rflo_getcelloffset,         &
                            rflo_getcornercellsindices, &
                            rflo_getedgecellsindices
  USE moderror
  USE modparameters
  USE plag_modparameters
  USE plag_modinterfaces, ONLY : plag_rflo_findsourcecell, &
                                 plag_rflo_getfacemapping
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)


! ... loop variables
  INTEGER :: i, icorner, iedge, ireg, ijk, j, k, nt

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev, ncorners, nedges, ntedge, ntcorn
  INTEGER :: iregsrc, ijkn, ic, jc, kc
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: inoff, ijnoff

  INTEGER :: ndumcellssrc
  INTEGER :: iregtemp, iregsrctemp, igridmapmat
  INTEGER :: srcdir(3),srcface(6)
  INTEGER :: srcindexmapmat(3,4)
  
  LOGICAL :: found

  TYPE(t_region),      POINTER :: pregion
  TYPE(t_level),       POINTER :: plevel
  TYPE(t_global),      POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PLAG_RFLO_FindGridMapping.F90,v $ $Revision: 1.4 $'

  global => regions(1)%global
    
  CALL registerfunction( global, 'PLAG_RFLO_FindGridMapping',&
  'PLAG_RFLO_FindGridMapping.F90' )

! Get dimensions --------------------------------------------------------------

  ncorners = 8
  nedges   = 12
  ntedge   = 2
  ntcorn   = 3

! Search for source regions ===================================================

  DO ireg=1,global%nRegions
    ilev=1

! - Set pointers --------------------------------------------------------------
  
      plevel  => regions(ireg)%levels(ilev)

      pregion => regions(ireg)

! - Get node offset -----------------------------------------------------------

      CALL rflo_getnodeoffset( pregion,ilev,inoff,ijnoff )

! - Loop over edges -----------------------------------------------------------

      DO iedge=1,nedges 

! -- Bypass for noninteracting regions ----------------------------------------

        IF( .NOT. plevel%edgeCells(iedge)%interact ) goto 1999

! -- Loop over edge cell indices ----------------------------------------------
        
        CALL rflo_getedgecellsindices( pregion,ilev,iedge, &
                                       ibeg,iend,jbeg,jend,kbeg,kend )
        ijk = 0 
        DO k=kbeg,kend
        DO j=jbeg,jend
        DO i=ibeg,iend
          ijk = ijk + 1

! --- Source region infrastructure --------------------------------------------
            
          iregsrc = plevel%edgeCells(iedge)%cells(ijk)%srcRegion
     
          ic = i; jc = j; kc =k;
          iregtemp=ireg 
          DO nt=1,ntedge
            CALL plag_rflo_findsourcecell( regions,iregtemp,ilev,ic,jc,kc, &
                                           found,iregsrctemp,srcindexmapmat )
            IF(found) EXIT
            iregtemp = iregsrctemp
          END DO ! nt

! --- Extract mapping between regions sharing an edge -------------------------
                           
          plevel%edgeCells(iedge)%cells(ijk)%srcIndexMapMat = srcindexmapmat
        ENDDO   ! i
        ENDDO   ! j
        ENDDO   ! k

1999    CONTINUE 
      
      ENDDO      ! iEdge
      
! - Loop over corners ---------------------------------------------------------

      DO icorner=1,ncorners

! -- Bypass for noninteracting regions ----------------------------------------

        IF( .NOT. plevel%cornerCells(icorner)%interact ) goto 2999

! -- Loop over corner cell indices --------------------------------------------
        
        CALL rflo_getcornercellsindices( pregion,ilev,icorner, &
                                         ibeg,iend,jbeg,jend,kbeg,kend )
        
        ijk = 0 
        DO k=kbeg,kend
        DO j=jbeg,jend
        DO i=ibeg,iend
          ijk = ijk + 1
  
! -- Source region infrastructure ---------------------------------------------
            
          iregsrc  =  plevel%cornerCells(icorner)%cells(ijk)%srcRegion 
          
          ic = i; jc = j; kc =k;
          iregtemp=ireg
          DO nt=1,ntcorn
            CALL plag_rflo_findsourcecell( regions,iregtemp,ilev,ic,jc,kc, &
                                           found,iregsrctemp,srcindexmapmat )
            IF(found) EXIT
            iregtemp = iregsrctemp
          END DO ! nt

! -- Extract mapping between regions sharing a corner -------------------------

          plevel%cornerCells(icorner)%cells(ijk)%srcIndexMapMat = srcindexmapmat
        ENDDO   ! i
        ENDDO   ! j
        ENDDO   ! k

2999    CONTINUE

      ENDDO     ! iCorner
  ENDDO         ! iReg

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )
  
END SUBROUTINE plag_rflo_findgridmapping

!******************************************************************************
SUBROUTINE plag_rflo_findsourcecell( regions,iReg,iLev,ic,jc,kc, &
                                     found,iregsrc,indexmapmat )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region, t_level
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getpatchindices
  USE moderror
  USE modparameters
  USE plag_modinterfaces, ONLY : plag_rflo_sourcecell
  IMPLICIT NONE

! ... parameters
  INTEGER, INTENT(IN)    :: ireg, ilev
  INTEGER, INTENT(INOUT) :: ic, jc, kc
  INTEGER, INTENT(OUT)   :: iregsrc
  INTEGER, INTENT(OUT)   :: indexmapmat(3,4)
 
  LOGICAL, INTENT(OUT)    :: found

  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ilb, ipatch

! ... local variables
  LOGICAL :: hit, debug

  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend, ipatchsrc
  INTEGER :: bctype, lbound, ibeg, iend, jbeg, jend, kbeg, kend

  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch, patchsrc

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'PLAG_RFLO_FindSourceCell',&
  'PLAG_RFLO_FindGridMapping.F90' )

  found = .false.

! Get dimensions --------------------------------------------------------------

  CALL rflo_getdimensphys( regions(ireg),ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )

! Find a suitable patch to start from -----------------------------------------

  hit = .false.     ! no patch found yet

! Check if cell is within the patch -------------------------------------------

  DO ipatch=1,regions(ireg)%nPatches
    patch => regions(ireg)%levels(ilev)%patches(ipatch)
    bctype = patch%bcType
    lbound = patch%lbound
    IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
        (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
      CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      IF      ((lbound==1 .AND. ic<ipcbeg) .OR. &
               (lbound==2 .AND. ic>ipcend)) THEN
        IF ((jc>=jbeg .AND. jc<=jend) .AND. &
            (kc>=kbeg .AND. kc<=kend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ELSE IF ((lbound==3 .AND. jc<jpcbeg) .OR. &
               (lbound==4 .AND. jc>jpcend)) THEN 
        IF ((ic>=ibeg .AND. ic<=iend) .AND. &
            (kc>=kbeg .AND. kc<=kend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ELSE IF ((lbound==5 .AND. kc<kpcbeg) .OR. &
               (lbound==6 .AND. kc>kpcend)) THEN
        IF ((jc>=jbeg .AND. jc<=jend) .AND. &
            (ic>=ibeg .AND. ic<=iend)) THEN
          hit = .true.
          EXIT
        ENDIF
      ENDIF
    ENDIF  ! bcType
  ENDDO    ! iPatch

! cell just outside the patch? ------------------------------------------------

  IF (.NOT. hit) THEN
    DO ipatch=1,regions(ireg)%nPatches
      patch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = patch%bcType
      lbound = patch%lbound
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )
        IF      ((lbound==1 .AND. ic<ipcbeg) .OR. &
                 (lbound==2 .AND. ic>ipcend)) THEN       ! face 1, 2
          IF (kc<kpcbeg .AND. kbeg==kpcbeg .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (kc>kpcend .AND. kend==kpcend .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc<jpcbeg .AND. jbeg==jpcbeg .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc>jpcend .AND. jend==jpcend .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF ((lbound==3 .AND. jc<jpcbeg) .OR. &
                 (lbound==4 .AND. jc>jpcend)) THEN       ! face 3, 4
          IF (kc<kpcbeg .AND. kbeg==kpcbeg .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (kc>kpcend .AND. kend==kpcend .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic<ipcbeg .AND. ibeg==ipcbeg .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic>ipcend .AND. iend==ipcend .AND. &
              (kc>=kbeg .AND. kc<=kend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF ((lbound==5 .AND. kc<kpcbeg) .OR. &
                 (lbound==6 .AND. kc>kpcend)) THEN       ! face 5, 6
          IF (jc<jpcbeg .AND. jbeg==jpcbeg .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (jc>jpcend .AND. jend==jpcend .AND. &
              (ic>=ibeg .AND. ic<=iend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic<ipcbeg .AND. ibeg==ipcbeg .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
          IF (ic>ipcend .AND. iend==ipcend .AND. &
              (jc>=jbeg .AND. jc<=jend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ENDIF
      ENDIF  ! bcType
    ENDDO    ! iPatch
  ENDIF      ! .NOT. hit

! cell at some corner? --------------------------------------------------------

  IF (.NOT. hit) THEN
    DO ipatch=1,regions(ireg)%nPatches
      patch => regions(ireg)%levels(ilev)%patches(ipatch)
      bctype = patch%bcType
      lbound = patch%lbound
      IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
          (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
          (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
        CALL rflo_getpatchindices( regions(ireg),patch,ilev, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )
        IF      (ic<ipcbeg .AND. jc<jpcbeg .AND. kc<kpcbeg) THEN   ! corner 1
          IF ((lbound==1 .AND. jbeg==jpcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==3 .AND. ibeg==ipcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. ibeg==ipcbeg .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc<jpcbeg .AND. kc>kpcend) THEN   ! corner 2
          IF ((lbound==1 .AND. jbeg==jpcbeg .AND. kend==kpcend) .OR. &
              (lbound==3 .AND. ibeg==ipcbeg .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. ibeg==ipcbeg .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc>jpcend .AND. kc>kpcend) THEN   ! corner 3
          IF ((lbound==1 .AND. jend==jpcend .AND. kend==kpcend) .OR. &
              (lbound==4 .AND. ibeg==ipcbeg .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. ibeg==ipcbeg .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic<ipcbeg .AND. jc>jpcend .AND. kc<kpcbeg) THEN   ! corner 4
          IF ((lbound==1 .AND. jend==jpcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==4 .AND. ibeg==ipcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. ibeg==ipcbeg .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc<jpcbeg .AND. kc<kpcbeg) THEN   ! corner 5
          IF ((lbound==2 .AND. jbeg==jpcbeg .AND. kbeg==kpcbeg) .OR. &
              (lbound==3 .AND. iend==ipcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. iend==ipcend .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc<jpcbeg .AND. kc>kpcend) THEN   ! corner 6
          IF ((lbound==2 .AND. jbeg==jpcbeg .AND. kend==kpcend) .OR. &
              (lbound==3 .AND. iend==ipcend .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. iend==ipcend .AND. jbeg==jpcbeg)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc>jpcend .AND. kc>kpcend) THEN   ! corner 7
          IF ((lbound==2 .AND. jend==jpcend .AND. kend==kpcend) .OR. &
              (lbound==4 .AND. iend==ipcend .AND. kend==kpcend) .OR. &
              (lbound==6 .AND. iend==ipcend .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ELSE IF (ic>ipcend .AND. jc>jpcend .AND. kc<kpcbeg) THEN   ! corner 8
          IF ((lbound==2 .AND. jend==jpcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==4 .AND. iend==ipcend .AND. kbeg==kpcbeg) .OR. &
              (lbound==5 .AND. iend==ipcend .AND. jend==jpcend)) THEN
            hit = .true.
            EXIT
          ENDIF
        ENDIF
      ENDIF  ! bcType
    ENDDO    ! iPatch
  ENDIF      ! .NOT. hit

! if patch was found, do the transformation -----------------------------------

  IF (hit) THEN
    bctype    = patch%bcType
    iregsrc   = patch%srcRegion
    ipatchsrc = patch%srcPatch
    patchsrc => regions(iregsrc)%levels(ilev)%patches(ipatchsrc)
    CALL plag_rflo_sourcecell( regions(ireg),regions(iregsrc),patch,patchsrc, &
                               ilev,ic,jc,kc,found,indexmapmat )
  ELSE
    iregsrc = ireg
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflo_findsourcecell

! #############################################################################
! #############################################################################

SUBROUTINE plag_rflo_sourcecell( region,regionSrc,patch,patchSrc, &
                                  ilev,ic,jc,kc,found,indexmapmat )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modindexing, ONLY   : indijkmap, getijk
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getpatchmapping, rflo_getdimensphys
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  INTEGER, INTENT(IN)    :: ilev
  INTEGER, INTENT(INOUT) :: ic,jc,kc
  INTEGER, INTENT(OUT)   :: indexmapmat(3,4)

  LOGICAL, INTENT(INOUT) :: found

  TYPE(t_region)          :: region, regionsrc
  TYPE(t_patch), POINTER  :: patch, patchsrc

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, icoffsrc, ijcoffsrc, ijkcsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: icell
  INTEGER :: icsrc, jcsrc, kcsrc

  LOGICAL :: align

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_SourceCell',&
  'PLAG_RFLO_FindGridMapping.F90' )

! Get dimensions --------------------------------------------------------------

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindices( regionsrc,patchsrc,ilev,ibegsrc,iendsrc, &
                             jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getcelloffset( regionsrc,ilev,icoffsrc,ijcoffsrc )

! Determine mapping between patches -------------------------------------------

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  lbs   = patch%srcLbound
  align = patch%align

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! Get cell indices on source patch --------------------------------------------

  icell = indijkmap( ic,jc,kc,mapmat,icoffsrc,ijcoffsrc )
  CALL getijk( icell,icoffsrc,ijcoffsrc,regionsrc%nDumCells,ic,jc,kc )

! Check if ic,jc,kc within physical domain ------------------------------------

  CALL rflo_getdimensphys( regionsrc,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )

  IF ((ic>=ipcbeg .AND. ic<=ipcend) .AND. &
      (jc>=jpcbeg .AND. jc<=jpcend) .AND. &
      (kc>=kpcbeg .AND. kc<=kpcend)) THEN
    found = .true.
    indexmapmat = mapmat
  ELSE
    found = .false.
    indexmapmat = -999999
  ENDIF

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflo_sourcecell

! #############################################################################
! #############################################################################

SUBROUTINE plag_rflo_getfacemapping( mapMat,srcDir,srcFace )

  USE moddatatypes
  USE moderror
  IMPLICIT NONE

! ... parameters
  INTEGER, INTENT(IN)  :: mapmat(3,4)
  INTEGER, INTENT(OUT) :: srcdir(3)
  INTEGER, INTENT(OUT) :: srcface(6)

! ... local variables
  INTEGER :: idir, jdir, kdir
  INTEGER :: idirsrc, jdirsrc,kdirsrc 
  INTEGER :: iface,jface,kface
  INTEGER :: ifacesrc,jfacesrc,kfacesrc
  INTEGER :: ifacesrcflip,jfacesrcflip,kfacesrcflip
  INTEGER :: ifacepsrcflip,jfacepsrcflip,kfacepsrcflip

!******************************************************************************

! Set dimensions --------------------------------------------------------------
  
  idir=1;jdir=2;kdir=3;
  iface =1; jface=3; kface=5;
  
! Determine grid mapping of source region -------------------------------------
!  use absolute value since negative value is meaningless ---------------------

  idirsrc = abs( idir*mapmat(1,1) + jdir*mapmat(1,2) + kdir*mapmat(1,3) )
  jdirsrc = abs( idir*mapmat(2,1) + jdir*mapmat(2,2) + kdir*mapmat(2,3) )
  kdirsrc = abs( idir*mapmat(3,1) + jdir*mapmat(3,2) + kdir*mapmat(3,3) ) 

! determine face mapping of source region -------------------------------------
           
  ifacesrc = iface*mapmat(1,1) + jface*mapmat(1,2) + kface*mapmat(1,3) 
  jfacesrc = iface*mapmat(2,1) + jface*mapmat(2,2) + kface*mapmat(2,3) 
  kfacesrc = iface*mapmat(3,1) + jface*mapmat(3,2) + kface*mapmat(3,3)     

! Swap face indices for negative values ---------------------------------------

  ifacesrcflip  = ifacesrc
  ifacepsrcflip = ifacesrc+1

  jfacesrcflip  = jfacesrc
  jfacepsrcflip = jfacesrc+1
           
  kfacesrcflip =  kfacesrc
  kfacepsrcflip = kfacesrc+1       
           
  IF ( ifacesrc < 0 ) THEN
    ifacesrcflip  = abs(ifacesrc)+1 
    ifacepsrcflip = abs(ifacesrc)
  ENDIF
           
  IF ( jfacesrc < 0 ) THEN
    jfacesrcflip  = abs(jfacesrc)+1 
    jfacepsrcflip = abs(jfacesrc)
  ENDIF
           
  IF ( kfacesrc < 0 ) THEN
    kfacesrcflip  = abs(kfacesrc)+1 
    kfacepsrcflip = abs(kfacesrc)
  ENDIF

! Load face indices of source region ------------------------------------------

  srcdir(1:3) = (/idirsrc,jdirsrc,kdirsrc/)
           
  srcface(1:6)=(/ifacesrcflip,ifacepsrcflip,jfacesrcflip,jfacepsrcflip, &
                 kfacesrcflip,kfacepsrcflip/)

END SUBROUTINE plag_rflo_getfacemapping

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLO_FindGridMapping.F90,v $
! Revision 1.4  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:58:10  fnajjar
! Initial revision after changing case
!
! Revision 1.1  2004/02/10 21:24:06  fnajjar
! Initial import of index mapping capability for corner-edge regions
!
!******************************************************************************