PEUL_BoundaryConditionsRecv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receive data for dummy cells from adjacent regions being
!          on another processor specific to PEUL Module.
!
! Description: none.
!
! Input: regions = data of all regions
!        iReg    = index of current region.
!
! Output: regions(iReg)%levels%peul%cv =
!           updated smoke concentrations (cv) in dummy cells of current region.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_BoundaryConditionsRecv.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_boundaryconditionsrecv( regions,iReg ) ! PUBLIC

  USE moddatatypes
  USE modbndpatch,   ONLY : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE peul_modparameters
  USE peul_modinterfaces, ONLY : peul_receivedummyvals, &
        peul_setcorneredgecells, peul_exchangecorneredgecells, &
        peul_receivecorneredgecells, peul_correctcorneredgecells
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER    :: regions(:)
  INTEGER,        INTENT(IN) :: ireg

! ... loop variables
  INTEGER :: ipatch

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev, npatches, bctype, iregsrc, ipatchsrc

  TYPE(t_patch),  POINTER :: patch, patchsrc
  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PEUL_BoundaryConditionsRecv.F90,v $ $Revision: 1.3 $'

  global => regions(ireg)%global

  CALL registerfunction( global,'PEUL_BoundaryConditionsRecv', 'PEUL_BoundaryConditionsRecv.F90' )

! begin -----------------------------------------------------------------------

! get dimensions --------------------------------------------------------------

  ilev     = regions(ireg)%currLevel
  npatches = regions(ireg)%nPatches

! receive data (regular cells) from other processors --------------------------

  DO ipatch=1,npatches

    patch => regions(ireg)%levels(ilev)%patches(ipatch)

    bctype    = patch%bcType
    iregsrc   = patch%srcRegion
    ipatchsrc = patch%srcPatch

! - region interface, periodic boundary

    IF ((bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range) .OR. &
        (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) .OR. &
        (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) .OR. &
        (bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
        (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range)) THEN
      IF (regions(iregsrc)%procid /= regions(ireg)%global%myProcid) THEN
        patchsrc => regions(iregsrc)%levels(ilev)%patches(ipatchsrc)

        CALL peul_receivedummyvals( regions(ireg),regions(iregsrc), &
                                    patch,patchsrc )
      ENDIF
    ENDIF

  ENDDO   ! iPatch

! copy/exchange data for edge and corner cells --------------------------------

  CALL peul_setcorneredgecells( regions(ireg) )

  DO ipatch=1,npatches
    patch => regions(ireg)%levels(ilev)%patches(ipatch)
    bctype = patch%bcType
    IF (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range) THEN
      CALL peul_correctcorneredgecells( regions(ireg),patch,bctype )
    ENDIF
  ENDDO   ! iPatch

  CALL peul_exchangecorneredgecells( regions,ireg )
  CALL peul_receivecorneredgecells(  regions,ireg )

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_boundaryconditionsrecv

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_BoundaryConditionsRecv.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:20  haselbac
! Initial revision after changing case
!
! Revision 1.3  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.2  2004/03/02 21:44:07  jferry
! Added corner and edge cell data structures and routines
!
! Revision 1.1  2003/04/09 14:32:53  fnajjar
! Initial Import of MPI-based rocsmoke
!
!******************************************************************************