PEUL_ExchangeCornerEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy smoke values to edge and corner cells of an adjacent region.
!
! Description: this is for the case if the other region is located
!              on the same processor.
!
! Input: regions = data of all regions
!        iReg    = current region.
!
! Output: region%levels%peul%cv = cv variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_ExchangeCornerEdgeCells.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_exchangecorneredgecells( regions,iReg )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region, t_level
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getedgecellsindices, &
                            rflo_getcornercellsindices
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER    :: regions(:)
  INTEGER,        INTENT(IN) :: ireg

! ... loop variables
  INTEGER :: iedge, icorner, ijk, i, j, k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: icell, iregsrc, ilev, icoff, ijcoff, ijkd
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend

  REAL(RFREAL), POINTER :: cv(:,:), cvsrc(:,:)

  TYPE(t_global), POINTER :: global
  TYPE(t_level),  POINTER :: level

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PEUL_ExchangeCornerEdgeCells.F90,v $ $Revision: 1.3 $'

  global => regions(ireg)%global

  CALL registerfunction( global,'PEUL_ExchangeCornerEdgeCells',&
  'PEUL_ExchangeCornerEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = regions(ireg)%currLevel

  CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )

  level => regions(ireg)%levels(ilev)
  cv    => level%peul%cv

! edge cells

  DO iedge=1,12
    IF (level%edgeCells(iedge)%interact) THEN
      CALL rflo_getedgecellsindices( regions(ireg),ilev,iedge, &
                                     ibeg,iend,jbeg,jend,kbeg,kend )
      ijk = 0
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijk     = ijk + 1
            ijkd    = indijk(i,j,k,icoff,ijcoff)
            icell   = level%edgeCells(iedge)%cells(ijk)%srcCell
            iregsrc = level%edgeCells(iedge)%cells(ijk)%srcRegion
            IF (iregsrc > 0) THEN
              IF (regions(iregsrc)%procid == global%myProcid) THEN
                cvsrc => regions(iregsrc)%levels(ilev)%peul%cv

                IF (level%edgeCells(iedge)%cells(ijk)%rotate) THEN
                  ! rotational periodicity
                ELSE
                  cv(:,ijkd) = cvsrc(:,icell)
                ENDIF

              ENDIF
            ENDIF
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDIF        ! interact
  ENDDO          ! iedge

! corner cells

  DO icorner=1,8
    IF (level%cornerCells(icorner)%interact) THEN
      CALL rflo_getcornercellsindices( regions(ireg),ilev,icorner, &
                                       ibeg,iend,jbeg,jend,kbeg,kend )
      ijk = 0
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijk     = ijk + 1
            ijkd    = indijk(i,j,k,icoff,ijcoff)
            icell   = level%cornerCells(icorner)%cells(ijk)%srcCell
            iregsrc = level%cornerCells(icorner)%cells(ijk)%srcRegion
            IF (iregsrc > 0) THEN
              IF (regions(iregsrc)%procid == global%myProcid) THEN
                cvsrc => regions(iregsrc)%levels(ilev)%peul%cv

                IF (level%cornerCells(icorner)%cells(ijk)%rotate) THEN
                  ! rotational periodicity
                ELSE
                  cv(:,ijkd) = cvsrc(:,icell)
                ENDIF

              ENDIF
            ENDIF
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDIF        ! interact
  ENDDO          ! icorner

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_exchangecorneredgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ExchangeCornerEdgeCells.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:34  haselbac
! Initial revision after changing case
!
! Revision 1.1  2004/03/02 21:44:07  jferry
! Added corner and edge cell data structures and routines
!
!******************************************************************************