PEUL_ReceiveCornerEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receives values for edge and corner cells from an adjacent
!          region.
!
! Description: this is for the case if the other region is located
!              on a different processor.
!
! Input: regions = data of all regions
!        iReg    = current region.
!
! Output: region%levels%peul%cv = cv variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_ReceiveCornerEdgeCells.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_receivecorneredgecells( regions,iReg )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE modglobal,     ONLY : t_global
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getedgecellsindices, &
                            rflo_getcornercellsindices
  USE moderror
  USE modmpi
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER    :: regions(:)
  INTEGER,        INTENT(IN) :: ireg

! ... loop variables
  INTEGER :: ir, iedge, icorner, i, j, k, ijk, icv

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregsrc, ibuff, ncv, ndim, source, tag
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff, ijkc

  REAL(RFREAL), POINTER :: cv(:,:)

  TYPE(t_global),      POINTER :: global
  TYPE(t_level),       POINTER :: level
  TYPE(t_dcelltransf), POINTER :: rcvpeuleccell

!******************************************************************************

  rcsidentstring = &
    '$RCSfile: PEUL_ReceiveCornerEdgeCells.F90,v $ $Revision: 1.3 $'

  global => regions(ireg)%global

  CALL registerfunction( global,'PEUL_ReceiveCornerEdgeCells',&
  'PEUL_ReceiveCornerEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev  =  regions(ireg)%currLevel
  level => regions(ireg)%levels(ilev)
  cv    => level%peul%cv
  ncv   =  level%peul%nCv

  CALL rflo_getcelloffset( regions(ireg),ilev,icoff,ijcoff )

! copy data from buffer to dummy cells

  DO ir=1,global%nRegions
    IF (regions(ir)%procid /= global%myProcid) THEN
    IF (level%rcvPeulEcCells(ir)%nCells > 0) THEN

      rcvpeuleccell => level%rcvPeulEcCells(ir)
      ndim       =  rcvpeuleccell%nCells
      ibuff      =  0

#ifdef MPI
      source = regions(ir)%procid
      tag    = regions(ireg)%localNumber + peul_tag_shift
      CALL mpi_recv( rcvpeuleccell%buff,ncv*ndim,mpi_rfreal, &
                     source,tag,global%mpiComm,status,global%mpierr )
      IF (global%mpierr /= 0) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! --- edges

      DO iedge=1,12
        IF (level%edgeCells(iedge)%interact) THEN
          CALL rflo_getedgecellsindices( regions(ireg),ilev,iedge, &
                                         ibeg,iend,jbeg,jend,kbeg,kend )

          ijk = 0
          DO k=kbeg,kend
            DO j=jbeg,jend
              DO i=ibeg,iend
                ijk     = ijk + 1
                ijkc    = indijk(i,j,k,icoff,ijcoff)
                iregsrc = level%edgeCells(iedge)%cells(ijk)%srcRegion
                IF (iregsrc == ir) THEN
                  ibuff = ibuff + 1
                  IF (level%edgeCells(iedge)%cells(ijk)%rotate) THEN
                    ! rotational periodicity
                  ELSE
                    DO icv=1,ncv
                      cv(icv,ijkc) = rcvpeuleccell%buff(ibuff+(icv-1)*ndim)
                    ENDDO ! iCv
                  ENDIF
                ENDIF
              ENDDO
            ENDDO
          ENDDO

        ENDIF  ! interact
      ENDDO    ! iedge

! --- corners

      DO icorner=1,8
        IF (level%cornerCells(icorner)%interact) THEN
          CALL rflo_getcornercellsindices( regions(ireg),ilev,icorner, &
                                           ibeg,iend,jbeg,jend,kbeg,kend )

          ijk = 0
          DO k=kbeg,kend
            DO j=jbeg,jend
              DO i=ibeg,iend
                ijk     = ijk + 1
                ijkc    = indijk(i,j,k,icoff,ijcoff)
                iregsrc = level%cornerCells(icorner)%cells(ijk)%srcRegion
                IF (iregsrc == ir) THEN
                  ibuff = ibuff + 1
                  IF (level%cornerCells(icorner)%cells(ijk)%rotate) THEN
                    ! rotational periodicity
                  ELSE
                    DO icv=1,ncv
                      cv(icv,ijkc) = rcvpeuleccell%buff(ibuff+(icv-1)*ndim)
                    ENDDO ! iCv
                  ENDIF
                ENDIF
              ENDDO
            ENDDO
          ENDDO

        ENDIF  ! interact
      ENDDO    ! icorner

    ENDIF      ! some cells to receive
    ENDIF      ! not my processor
  ENDDO        ! ir

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_receivecorneredgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ReceiveCornerEdgeCells.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:50  haselbac
! Initial revision after changing case
!
! Revision 1.1  2004/03/02 21:44:07  jferry
! Added corner and edge cell data structures and routines
!
!******************************************************************************