PEUL_ReceiveDummyVals.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receive values to the dummy cells of the patch from neighboring
!          region / periodic boundary, which is located on a different
!          processor specific to PEUL Module.
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: region%levels%peul = flow variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_ReceiveDummyVals.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_receivedummyvals( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modparteul, ONLY    : t_buffer_peul
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  USE peul_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  TYPE(t_region), INTENT(IN)    :: regionsrc
  TYPE(t_patch),  INTENT(INOUT) :: patch
  TYPE(t_patch),  INTENT(IN)    :: patchsrc

! ... loop variables
  INTEGER :: icv, idum, i, j, k, ijkbuff

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: lb, ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff, ijkd, &
             n1, n2, ncv, ndim, ndimrecvbuff, source, tagpeul, ilev

  REAL(RFREAL), POINTER, DIMENSION(:)   :: precvbuffeul
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_ReceiveDummyVals.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_ReceiveDummyVals',&
  'PEUL_ReceiveDummyVals.F90' )

! check if the source region is active ----------------------------------------

  IF (regionsrc%active == off) THEN
    CALL errorstop( global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  pcv          => region%levels(ilev)%peul%cv
  precvbuffeul => patch%bufferPeul%recvBuff

  n1   = abs(patch%l1end-patch%l1beg) + 1   ! here, dimensions of current
  n2   = abs(patch%l2end-patch%l2beg) + 1   ! and source patch are identical
  ndim = n1*n2*region%nDumCells             ! ... but not the # of dummy cells

  ncv  =  region%levels(ilev)%peul%nCv

  IF (ncv /= region%peulInput%nPtypes) &
    CALL errorstop( region%global,err_peul_npmismatch,__line__ )

  ndimrecvbuff = ncv*ndim

! receive data ----------------------------------------------------------------

#ifdef MPI
  source  = regionsrc%procid
  tagpeul = region%localNumber + mpi_patchoff*patchsrc%srcPatch &
          * peul_tag_shift
  CALL mpi_recv( precvbuffeul,ndimrecvbuff,mpi_rfreal, &
                 source,tagpeul,global%mpiComm,status,global%mpierr )
  IF (global%mpierr /= err_none) &
    CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! copy from buffer to dummy nodes ---------------------------------------------

  lb      = patch%lbound
  ijkbuff = 0

  DO icv = 1, ncv
    DO idum=1,region%nDumCells

! - face i=const. -------------------------------------------------------------

      IF (lb==1 .OR. lb==2) THEN

        SELECT CASE(lb)
          CASE(1)
            i = ibeg - idum
          CASE(2)
            i = iend + idum
        END SELECT ! lb

        DO k=kbeg,kend
        DO j=jbeg,jend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          pcv(icv,ijkd) = precvbuffeul(ijkbuff)
        ENDDO ! j
        ENDDO ! k

! - face j=const. -------------------------------------------------------------

      ELSE IF (lb==3 .OR. lb==4) THEN

        SELECT CASE(lb)
          CASE(3)
            j = jbeg - idum
          CASE(4)
            j = jend + idum
        END SELECT ! lb

        DO i=ibeg,iend
        DO k=kbeg,kend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          pcv(icv,ijkd) = precvbuffeul(ijkbuff)
        ENDDO ! k
        ENDDO ! i

! - face k=const.

      ELSE IF (lb==5 .OR. lb==6) THEN

        SELECT CASE(lb)
          CASE(5)
            k = kbeg - idum
          CASE(6)
            k = kend + idum
        END SELECT ! lb

        DO j=jbeg,jend
        DO i=ibeg,iend
          ijkd    = indijk(i,j,k,icoff,ijcoff)
          ijkbuff = ijkbuff + 1
          pcv(icv,ijkd) = precvbuffeul(ijkbuff)
        ENDDO ! j
        ENDDO ! i
      ENDIF   ! lb

    ENDDO     ! idum
  ENDDO     ! iCv

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_receivedummyvals

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_ReceiveDummyVals.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:52  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:52  haselbac
! Initial revision after changing case
!
! Revision 1.5  2004/04/15 16:04:03  jferry
! minor formatting (removed trailing spaces)
!
! Revision 1.4  2004/03/02 21:44:07  jferry
! Added corner and edge cell data structures and routines
!
! Revision 1.3  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.2  2003/04/09 20:57:24  fnajjar
! Fixed sign error for ibeg, iend
!
! Revision 1.1  2003/04/09 14:34:25  fnajjar
! Initial Import of MPI-based rocsmoke
!
!******************************************************************************