PERI_InitSolution.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calls routines for initialisation of PERI solutions
!
! Description: initial solution depends on the periodic flow case selected
!
! Input: iReg   = index of current region
!        region = data of current region
!
! Output: solution to start simulation
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_InitSolution.F90,v 1.5 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_initsolution( regions,iReg ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY      : t_region
  USE modglobal, ONLY          : t_global
  USE modperiodic, ONLY        : t_peri_input
#ifdef RFLO
  USE modinterfaces, ONLY      : rflo_getdimensphysnodes, rflo_getnodeoffset

#include "Indexing.h"
#endif
  USE peri_modinterfaces, ONLY : peri_cocprinitsolution, peri_cocnlinitsolution
  USE moderror
  USE modmpi
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)
  INTEGER      :: ireg

! ... loop variables
  INTEGER      :: ir, j, k

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER     :: global
  TYPE(t_peri_input), POINTER :: input

  INTEGER      :: ilev, ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend 
  INTEGER      :: inoff, ijnoff, ijkn
  REAL(RFREAL) :: maxy, miny, maxz, minz, sndmax, rcvmax, sndmin, rcvmin
  REAL(RFREAL) :: delta, pidel
  REAL(RFREAL), POINTER :: xyz(:,:)

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_InitSolution.F90,v $'

  global => regions(ireg)%global
  CALL registerfunction( global,'PERI_InitSolution',&
  'PERI_InitSolution.F90' )

! get initial solution depending on kind of periodic flow ---------------------

  IF ((regions(ireg)%periInput%flowKind == peri_flow_cpr) .OR. &
      (regions(ireg)%periInput%flowKind == peri_flow_channel)) THEN

! - compute channel halfwidth

    maxy = -1000000._rfreal
    miny =  1000000._rfreal
    maxz = -1000000._rfreal
    minz =  1000000._rfreal

#ifdef RFLO
    DO ir = 1,global%nRegions
      IF (regions(ir)%procid==global%myProcid .AND. & ! region active and
          regions(ir)%active==active) THEN            ! on my processor

        ilev = regions(ir)%currLevel
        CALL rflo_getdimensphysnodes( regions(ir),ilev,ipnbeg,ipnend, &
                                      jpnbeg,jpnend,kpnbeg,kpnend )
        CALL rflo_getnodeoffset( regions(ir),ilev,inoff,ijnoff )

        xyz  => regions(ir)%levels(ilev)%grid%xyz
#endif
#ifdef RFLU
  DO ireg = lbound(regions,1),ubound(regions,1)

        xyz  => regions(ir)%grid%xyz
#endif

        input => regions(ir)%periInput

        IF (input%flowKind==peri_flow_cpr .OR. &
            input%flowKind==peri_flow_channel) THEN
#ifdef RFLO
          DO j = jpnbeg, jpnend
            ijkn = indijk(1 ,j ,1 ,inoff,ijnoff)
            maxy = max( maxy, xyz(ycoord,ijkn) ) 
            miny = min( miny, xyz(ycoord,ijkn) ) 
          ENDDO

          DO k = kpnbeg, kpnend
            ijkn = indijk(1 ,1 ,k ,inoff,ijnoff)
            maxz = max( maxz, xyz(zcoord,ijkn) ) 
            minz = min( minz, xyz(zcoord,ijkn) ) 
          ENDDO
#endif
#ifdef RFLU
          DO ijkn = 1, regions(ir)%grid%nVert
            maxy = max( maxy, xyz(ycoord,ijkn) ) 
            miny = min( miny, xyz(ycoord,ijkn) ) 
            maxz = max( maxz, xyz(zcoord,ijkn) ) 
            minz = min( minz, xyz(zcoord,ijkn) ) 
          ENDDO
#endif
        ENDIF ! flowKind
#ifdef RFLO
      ENDIF  ! region active and my processor
#endif
    ENDDO   ! ir

#ifndef MPI
    delta = 0.5_rfreal*(maxy - miny)  ! channel half width
    IF (abs( global%refLength - delta ) > &
        max( global%refLength,1._rfreal )*peri_real_small) THEN
      CALL errorstop( global,err_peri_input,__line__, &
           'maxY-minY in the region /= length scale delta' )
    ENDIF
#endif 
#ifdef MPI
    sndmax = maxy
    sndmin = miny
    CALL mpi_allreduce( sndmax,rcvmax,1,mpi_double_precision,mpi_max, &
                      global%mpiComm, global%mpierr )
    CALL mpi_allreduce( sndmin,rcvmin,1,mpi_double_precision,mpi_min, &
                      global%mpiComm, global%mpierr )
    maxy = rcvmax
    miny = rcvmin

    sndmax = maxz
    sndmin = minz
    CALL mpi_allreduce( sndmax,rcvmax,1,mpi_double_precision,mpi_max, &
                      global%mpiComm, global%mpierr )
    CALL mpi_allreduce( sndmin,rcvmin,1,mpi_double_precision,mpi_min, &
                      global%mpiComm, global%mpierr )
    maxz = rcvmax
    minz = rcvmin
#endif

! - save minY and maxY in permanent data and get y and z dimensions
    input => regions(ireg)%periInput
    input%minmax(1) = miny    
    input%minmax(2) = maxy    
    delta = 0.5_rfreal*(maxy - miny)  ! channel half width
    pidel = maxz - minz               ! channel span 

! - check delta
    IF (abs(global%refLength - delta) > &
            global%refLength*peri_real_small) THEN
      CALL errorstop( global,err_peri_input,__line__, &
      'length scale delta is not consistent with the grid' )
    ENDIF 

  ENDIF

  IF (regions(ireg)%periInput%flowKind == peri_flow_cpr) THEN

! - check span dimension
    IF (abs( global%pi*global%refLength - pidel ) > &
        max( global%refLength,1._rfreal )*peri_real_small) THEN
      CALL errorstop( global,err_peri_input,__line__, &
                     'spanwise dimension is not consistent with the grid' )
    ENDIF 

    CALL peri_cocprinitsolution( regions(ireg) )

  ELSEIF (regions(ireg)%periInput%flowKind == peri_flow_channel) THEN

! - check span dimension
    IF (abs( global%pi*global%refLength - pidel ) > &
        max( global%refLength,1._rfreal )*peri_real_small) THEN
      CALL errorstop( global,err_peri_input,__line__, &
                     'spanwise dimension is not consistent with the grid' )
    ENDIF 

    CALL peri_cocnlinitsolution( regions(ireg) )

  ELSEIF (regions(ireg)%periInput%flowKind == peri_flow_bola) THEN

!    CALL PERI_BolaInitSolution( regions(iReg) )

  ENDIF
  
  global%moduleVar(1) = regions(ireg)%periInput%meanPgrad

! finalize --------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peri_initsolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_InitSolution.F90,v $
! Revision 1.5  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/06/11 21:49:40  wasistho
! prepared for RFLU
!
! Revision 1.2  2004/06/09 01:09:24  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/06/08 23:56:56  wasistho
! changed nomenclature
!
! Revision 1.6  2003/10/20 00:42:06  wasistho
! modified dimension check
!
! Revision 1.5  2003/10/17 20:27:26  wasistho
! fixed the computation of delta
!
! Revision 1.4  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.3  2003/04/03 20:58:54  wasistho
! normal extent in one region ifnot MPI
!
! Revision 1.2  2003/04/03 00:35:17  wasistho
! include channel grid check
!
! Revision 1.1.1.1  2003/03/29 03:36:30  wasistho
! install ROCPERI
!
!
!
!******************************************************************************