PERI_coCprInitSolutionFlo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Initialisation of CPR solutions
!
! Description: IF starts from t=0, set density and pressure as single values
!              as function of axial position using 1D compressible relations,
!              can be found in AIAA-86-1447 (Traineau, Hervat and Kuentsmann).
!              The remaining conservative variables are due to Taylor solution
!              which vary in injection normal direction.
!              IF restart from t/=0, read solution from main solution file
!              and cpr pressure gradient from specific cpr solution file.
!
! Input: region = data of current region
!
! Output: CPR solution to start simulation
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_coCprInitSolutionFlo.F90,v 1.3 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_cocprinitsolution( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : mixtperf_eo_dgpvm
  USE moderror
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE (t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, jr

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER     :: global

  INTEGER  :: ilev, ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER  :: icoff, ijcoff, inoff, ijnoff, ijkc, ijkcr, ijkn, ijkn1
  REAL(RFREAL), POINTER :: xyz(:,:), cv(:,:), dv(:,:)
  REAL(RFREAL) :: pi, gamma, gogampls, delta, minj, mfrat, refmassflux
  REAL(RFREAL) :: throatmflux, cpreps, headpres, headtemp, headsv, rgas
  REAL(RFREAL) :: phi, mach, yp, ym, yc, dy, denom, choklen, hvinj
  REAL(RFREAL) :: rho, pres, vm, eo

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_coCprInitSolutionFlo.F90,v $ $Revision: 1.3 $'

  global => region%global
  CALL registerfunction( global,'PERI_CoCprInitSolution',&
  'PERI_coCprInitSolutionFlo.F90' )

! get parameters and pointers ----------------------------------------------

  ilev   =  region%currLevel
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  xyz    => region%levels(ilev)%grid%xyz
  cv     => region%levels(ilev)%mixt%cv
  dv     => region%levels(ilev)%mixt%dv

  pi       = global%pi
  rgas     = 287._rfreal
  gamma    = global%refGamma
  gogampls = gamma / (gamma + 1._rfreal)
  cpreps   = region%periInput%cprEpsilon
  headpres = region%periInput%headPres
  headtemp = region%periInput%headTemp
  delta    = global%refLength
write(*,*)global%currentTime
  IF ((global%flowType==flow_unsteady .AND. &
       global%currentTime < peri_real_small) .OR. &
      (global%flowType==flow_steady .AND. global%currentIter==0)) THEN

! - first cleanup conservative variables cv     
    cv(:,:) = 0._rfreal
write(*,*)headpres,headtemp
! - refMassFlux is the mass flux at the streamwise location x/h=1/cprEpsilon
    minj        = region%periInput%minjRate 
    refmassflux = region%periInput%bulkmFlux

! - bulk averaged mass flux corresponding to CPR sonic conditions
    throatmflux = 2._rfreal*delta*gamma*headpres/ &
                  sqrt(2._rfreal*gogampls*rgas*headtemp)

! - non dimensinal distance head end to choking location L/h:
    headsv  = sqrt( gamma*rgas*headtemp )
    denom   = headsv*minj*sqrt( 2._rfreal*(gamma+1._rfreal) )
    choklen = headpres*gamma/denom

! - mfRat is ratio of bulk mass flux to mass flux corresp. to sonic conditions
    mfrat = refmassflux/throatmflux

! - or mfRat can be defined as axial coordinate normalized by choklen
    mfrat = 1._rfreal/cpreps/choklen

! - compute nondimensional axial parameter phi defined as
    phi = sqrt(1._rfreal - mfrat*mfrat)

! - pressure and density axial distribution
    rho  = 0.5_rfreal*headpres*(1._rfreal+phi)/(rgas*headtemp)
    pres = (1.d0+gamma*phi)*headpres/(1._rfreal+gamma)
    cv(cv_mixt_dens,:) = rho
    dv(dv_mixt_pres,:) = pres
    dv(dv_mixt_wvel,:) = 0._rfreal

! - mach number and head-end injection velocity
    mach = sqrt((1._rfreal-phi)/(1._rfreal+gamma*phi))
    hvinj= minj*rgas*headtemp/headpres
write(*,*)cv(cv_mixt_dens,1),dv(dv_mixt_pres,1),choklen,mach
write(*,*)mfrat,phi,mach,hvinj

    DO k = kpcbeg, kpcbeg
      DO i = ipcbeg, ipcbeg
        DO j = jpcbeg-region%nDumCells, jpcend+region%nDumCells
          ijkc  = indijk( i , j  , k ,icoff,ijcoff) 
          jr    = max( j, jpcbeg )
          jr    = min( jr,jpcend )
          ijkn  = indijk( i , jr  , k ,inoff,ijnoff) 
          ijkn1 = indijk( i , jr+1, k ,inoff,ijnoff) 
          dy    = xyz(ycoord,ijkn1)-xyz(ycoord,ijkn)
          yp    = xyz(ycoord,ijkn1)
          ym    = xyz(ycoord,ijkn) 
          yc    = 0.5_rfreal*(xyz(ycoord,ijkn1)+xyz(ycoord,ijkn))
          IF (dy < 0._rfreal) THEN
            CALL errorstop( region%global,err_peri_geo,__line__, &
                            'grid contains negative spacing' )
          ENDIF
            
!          dv(DV_MIXT_UVEL,ijkC) = 0.5_RFREAL*pi*refMassFlux* &
!                                  (SIN(0.5_RFREAL*pi*yp/delta)- &
!                                  SIN(0.5_RFREAL*pi*ym/delta))/(pi*dy*rho)
!          dv(DV_MIXT_VVEL,ijkC) = cprEps*refMassFlux*(COS(0.5_RFREAL*pi*yp/ &
!                                  delta)-COS(0.5_RFREAL*pi*ym/delta))/(pi*dy*rho)

          dv(dv_mixt_uvel,ijkc) = minj/rho*0.5_rfreal*pi/cpreps* &        
                                  cos( 0.5_rfreal*pi*yc/delta )
          dv(dv_mixt_vvel,ijkc) = -minj/rho*sin( 0.5_rfreal*pi*yc/delta )

          vm = sqrt( dv(dv_mixt_uvel,ijkc)*dv(dv_mixt_uvel,ijkc) + &
                     dv(dv_mixt_vvel,ijkc)*dv(dv_mixt_vvel,ijkc) + &    
                     dv(dv_mixt_wvel,ijkc)*dv(dv_mixt_wvel,ijkc))
          eo = mixtperf_eo_dgpvm(rho,gamma,pres,vm)
          cv(cv_mixt_xmom,ijkc) = rho*dv(dv_mixt_uvel,ijkc)
          cv(cv_mixt_ymom,ijkc) = rho*dv(dv_mixt_vvel,ijkc)
          cv(cv_mixt_zmom,ijkc) = rho*dv(dv_mixt_wvel,ijkc)
          cv(cv_mixt_ener,ijkc) = rho*eo
        END DO
        DO j = 1, region%nDumCells 
          ijkn  = indijk( i , jpcbeg    , k ,inoff,ijnoff) 
          ijkn1 = indijk( i , jpcend+1  , k ,inoff,ijnoff) 
          yp    = xyz(ycoord,ijkn1)
          ym    = xyz(ycoord,ijkn) 
          ijkcr = indijk( i , jpcbeg+j-1, k ,icoff,ijcoff) 
          ijkc  = indijk( i , jpcbeg-j  , k ,icoff,ijcoff) 
          IF (ym == region%periInput%minmax(1)) THEN
            cv(cv_mixt_xmom,ijkc) = -cv(cv_mixt_xmom,ijkcr)
          ENDIF
          ijkcr = indijk( i , jpcend-j+1, k ,icoff,ijcoff) 
          ijkc  = indijk( i , jpcend+j  , k ,icoff,ijcoff) 
          IF (yp == region%periInput%minmax(2)) THEN
            cv(cv_mixt_xmom,ijkc) = -cv(cv_mixt_xmom,ijkcr)
          ENDIF
        END DO
      END DO
    END DO 

    DO k = kpcbeg-region%nDumCells, kpcend+region%nDumCells
      DO j = jpcbeg-region%nDumCells, jpcend+region%nDumCells 
        DO i = ipcbeg-region%nDumCells, ipcend+region%nDumCells 
          ijkc  = indijk( i    , j , k     ,icoff,ijcoff) 
          ijkcr = indijk(ipcbeg, j ,kpcbeg ,icoff,ijcoff) 
          cv(cv_mixt_dens,ijkc) = cv(cv_mixt_dens,ijkcr)
          cv(cv_mixt_xmom,ijkc) = cv(cv_mixt_xmom,ijkcr)
          cv(cv_mixt_ymom,ijkc) = cv(cv_mixt_ymom,ijkcr)
          cv(cv_mixt_zmom,ijkc) = cv(cv_mixt_zmom,ijkcr)
          cv(cv_mixt_ener,ijkc) = cv(cv_mixt_ener,ijkcr)
!IF (i==ipcbeg.AND.k==kpcbeg) &
!write(*,*)j,cv(2,ijkC),cv(3,ijkC),cv(4,ijkC),cv(5,ijkC)
IF(j==1.AND.k==2) write(*,*)i,j,k,cv(1:5,ijkc)
        END DO
      END DO
    END DO 

  ELSE

! - previous pressure gradient is read from main solution file

    region%periInput%meanPgrad = global%moduleVar(1)
    write(*,*) region%procId,' cprMeanPgrad ', region%periInput%meanPgrad

  ENDIF       

! finalize --------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peri_cocprinitsolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_coCprInitSolutionFlo.F90,v $
! Revision 1.3  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/06/08 23:56:56  wasistho
! changed nomenclature
!
! Revision 1.2  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.1.1.1  2003/03/29 03:36:30  wasistho
! install ROCPERI
!
!
!
!******************************************************************************