PERI_coCnlInitSolutionFlo.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Initialisation of channel flow solution
!
! Description: initial solution is laminar channel flow
!
! Input: region = data of current region
!
! Output: channel solution to start simulation
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PERI_coCnlInitSolutionFlo.F90,v 1.4 2008/12/06 08:44:36 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peri_cocnlinitsolution( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : mixtperf_eo_dgpvm
  USE moderror
  USE modparameters
  USE peri_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE (t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, n

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER  :: ilev, ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER  :: icoff, ijcoff, inoff, ijnoff, ijkc, ijkcr, ijkn, ijkn1
  INTEGER  :: icorner(8)
  REAL(RFREAL), POINTER :: xyz(:,:), cv(:,:), dv(:,:)
  REAL(RFREAL) :: rgas, yp, ym, yc, dy, muel, refmeanpgrad, delta
  REAL(RFREAL) :: rho, pres, vm, eo, xyzcell(3), twopi
  REAL(RFREAL) :: lambda,ampl,umax,nxwav,nywav,nzwav,span,extn,fy,yscale,ywaves

!******************************************************************************

  rcsidentstring = '$RCSfile: PERI_coCnlInitSolutionFlo.F90,v $ $Revision: 1.4 $'

  global => region%global
  CALL registerfunction( global,'PERI_CoCnlInitSolution',&
  'PERI_coCnlInitSolutionFlo.F90' )

! get parameters and pointers ----------------------------------------------

  ilev   =  region%currLevel
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  xyz    => region%levels(ilev)%grid%xyz
  cv     => region%levels(ilev)%mixt%cv
  dv     => region%levels(ilev)%mixt%dv

  IF ((global%flowType==flow_unsteady .AND. &
       global%currentTime < peri_real_small) .OR. &
      (global%flowType==flow_steady .AND. global%currentIter==0)) THEN

! - get parameters and set conservative variables
    
    delta = global%refLength
    muel  = global%refVisc
    rho   = global%refDensity
    pres  = global%refPressure
    refmeanpgrad = region%periInput%meanPgrad
    cv(cv_mixt_dens,:) = rho
    cv(cv_mixt_ymom,:) = 0._rfreal
    cv(cv_mixt_zmom,:) = 0._rfreal

    DO k = kpcbeg, kpcbeg
      DO i = ipcbeg, ipcbeg
        DO j = jpcbeg-region%nDumCells, jpcend+region%nDumCells
          ijkc  = indijk( i , j  , k ,icoff,ijcoff) 
          ijkn  = indijk( i , j  , k ,inoff,ijnoff) 
          ijkn1 = indijk( i , j+1, k ,inoff,ijnoff) 
          dy    = xyz(ycoord,ijkn1)-xyz(ycoord,ijkn)
          yp    = xyz(ycoord,ijkn1)
          ym    = xyz(ycoord,ijkn) 
          yc    = 0.5_rfreal*(xyz(ycoord,ijkn1)+xyz(ycoord,ijkn))
          IF (dy < 0._rfreal) THEN
            CALL errorstop( region%global,err_peri_geo,__line__, &
                            'grid contains negative spacing' )
          ENDIF

          dv(dv_mixt_uvel,ijkc) = -0.5_rfreal/muel*refmeanpgrad* &
                                   (delta*delta - yc*yc)

          cv(cv_mixt_xmom,ijkc) = dv(dv_mixt_uvel,ijkc)*rho

          vm = sqrt( cv(cv_mixt_xmom,ijkc)*cv(cv_mixt_xmom,ijkc) + &
                     cv(cv_mixt_ymom,ijkc)*cv(cv_mixt_ymom,ijkc) + &    
                     cv(cv_mixt_zmom,ijkc)*cv(cv_mixt_zmom,ijkc))/rho
          eo = mixtperf_eo_dgpvm(rho,global%refGamma,pres,vm)
          cv(cv_mixt_ener,ijkc) = rho*eo
        END DO
        DO j = 1, region%nDumCells 
          ijkn  = indijk( i , jpcbeg    , k ,inoff,ijnoff) 
          ijkn1 = indijk( i , jpcend+1  , k ,inoff,ijnoff) 
          yp    = xyz(ycoord,ijkn1)
          ym    = xyz(ycoord,ijkn) 
          ijkcr = indijk( i , jpcbeg+j-1, k ,icoff,ijcoff) 
          ijkc  = indijk( i , jpcbeg-j  , k ,icoff,ijcoff) 
          IF (ym == region%periInput%minmax(1)) THEN
            cv(cv_mixt_xmom,ijkc) = -cv(cv_mixt_xmom,ijkcr)
          ENDIF
          ijkcr = indijk( i , jpcend-j+1, k ,icoff,ijcoff) 
          ijkc  = indijk( i , jpcend+j  , k ,icoff,ijcoff) 
          IF (yp == region%periInput%minmax(2)) THEN
            cv(cv_mixt_xmom,ijkc) = -cv(cv_mixt_xmom,ijkcr)
          ENDIF
        END DO
      END DO
    END DO 

    DO k = kpcbeg-region%nDumCells, kpcend+region%nDumCells
      DO j = jpcbeg-region%nDumCells, jpcend+region%nDumCells 
        DO i = ipcbeg-region%nDumCells, ipcend+region%nDumCells 
          ijkc  = indijk( i    , j , k     ,icoff,ijcoff) 
          ijkcr = indijk(ipcbeg, j ,kpcbeg ,icoff,ijcoff) 
          cv(cv_mixt_dens,ijkc) = cv(cv_mixt_dens,ijkcr)
          cv(cv_mixt_xmom,ijkc) = cv(cv_mixt_xmom,ijkcr)
          cv(cv_mixt_ymom,ijkc) = cv(cv_mixt_ymom,ijkcr)
          cv(cv_mixt_zmom,ijkc) = cv(cv_mixt_zmom,ijkcr)
          cv(cv_mixt_ener,ijkc) = cv(cv_mixt_ener,ijkcr)
        END DO
      END DO
    END DO 

! - add perturbations

    lambda = 5._rfreal
    ampl   = 0.3_rfreal
    umax   = -0.5_rfreal/muel*refmeanpgrad*delta*delta
    nxwav  = 3._rfreal
    nywav  = 2._rfreal
    nzwav  = 2._rfreal
    span   = xyz(zcoord,indijk( ipcbeg,jpcbeg,kpcend+1,inoff,ijnoff ))- & 
             xyz(zcoord,indijk( ipcbeg,jpcbeg,kpcbeg  ,inoff,ijnoff ))
    extn   = xyz(xcoord,indijk( ipcend+1,jpcbeg,kpcbeg,inoff,ijnoff ))- & 
             xyz(xcoord,indijk( ipcbeg  ,jpcbeg,kpcbeg,inoff,ijnoff ))
    twopi  = 2._rfreal*global%pi

    DO k = kpcbeg-region%nDumCells, kpcend+region%nDumCells
      DO j = jpcbeg                 , jpcend
        DO i = ipcbeg-region%nDumCells, ipcend+region%nDumCells 
          ijkc        = indijk( i   , j   , k   ,icoff,ijcoff) 
          icorner(1)  = indijk( i   , j   , k   ,inoff,ijnoff) 
          icorner(2)  = indijk( i+1 , j   , k   ,inoff,ijnoff) 
          icorner(3)  = indijk( i   , j+1 , k   ,inoff,ijnoff) 
          icorner(4)  = indijk( i+1 , j+1 , k   ,inoff,ijnoff) 
          icorner(5)  = indijk( i   , j   , k+1 ,inoff,ijnoff) 
          icorner(6)  = indijk( i+1 , j   , k+1 ,inoff,ijnoff) 
          icorner(7)  = indijk( i   , j+1 , k+1 ,inoff,ijnoff) 
          icorner(8)  = indijk( i+1 , j+1 , k+1 ,inoff,ijnoff) 

          xyzcell(:) = 0._rfreal
          DO n=1,8
            xyzcell(1) = xyzcell(1) + xyz(xcoord,icorner(n))
            xyzcell(2) = xyzcell(2) + xyz(ycoord,icorner(n))
            xyzcell(3) = xyzcell(3) + xyz(zcoord,icorner(n))
          ENDDO
          xyzcell(1) = 0.125_rfreal*xyzcell(1)
          xyzcell(2) = 0.125_rfreal*xyzcell(2)
          xyzcell(3) = 0.125_rfreal*xyzcell(3)

! ------- X and Z momentum components

          yscale = (delta - abs( xyzcell(2) ))/delta
          ywaves = sin( nywav*yscale*twopi )
          fy     = ampl*(lambda*yscale)**2/ &
                   (1._rfreal + (lambda*yscale)**4)  ! normal envelope
          fy     = ywaves*fy                         ! normal oscillations

          cv(cv_mixt_xmom,ijkc) = cv(cv_mixt_xmom,ijkc) + &
                                  cv(cv_mixt_dens,ijkc)*umax* &
                                ( fy*sin( nxwav*xyzcell(1)/extn*twopi )+ &
                                  fy*cos( nzwav*xyzcell(3)/span*twopi ) ) 
!          cv(CV_MIXT_ZMOM,ijkC) = cv(CV_MIXT_ZMOM,ijkC) + &
!                                  cv(CV_MIXT_DENS,ijkC)*umax* &
!                                ( fy*SIN( nXwav*xyzCell(1)/extn*twopi )+ &
!                                  fy*COS( nZwav*xyzCell(3)/span*twopi ) ) 

! ------- Y momentum component

          yscale = xyzcell(2)/delta
          ywaves = sin( nywav/2*yscale*twopi )
          yscale = (delta - abs( xyzcell(2) ))/delta
          fy     = ampl*(lambda*yscale)**2/ &
                   (1._rfreal + (lambda*yscale)**4)  ! normal envelope
          fy     = ywaves*fy                         ! normal oscillations

          cv(cv_mixt_ymom,ijkc) = cv(cv_mixt_ymom,ijkc) + &
                                  cv(cv_mixt_dens,ijkc)*umax* &
                                ( fy*cos( nxwav*xyzcell(1)/extn*twopi )+ &
                                  fy*cos( nzwav*xyzcell(3)/span*twopi ) ) 

        END DO
      END DO
    END DO 

  ELSE

! - previous pressure gradient is read from main solution file

    region%periInput%meanPgrad = global%moduleVar(1)
    write(*,*) region%procId,' channel MeanPgrad ', region%periInput%meanPgrad

  ENDIF       

! finalize --------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peri_cocnlinitsolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PERI_coCnlInitSolutionFlo.F90,v $
! Revision 1.4  2008/12/06 08:44:36  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:49  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/04/27 19:42:11  wasistho
! modified cnl initial sinusoidal perturbations
!
! Revision 1.1  2004/06/08 23:56:56  wasistho
! changed nomenclature
!
! Revision 1.5  2004/04/01 03:38:23  wasistho
! modified channel initial perturbations
!
! Revision 1.4  2004/03/31 00:43:21  wasistho
! corrected variable extn
!
! Revision 1.3  2004/03/30 21:22:18  wasistho
! add perturbation on initial laminar channel flow
!
! Revision 1.2  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.1.1.1  2003/03/29 03:36:30  wasistho
! install ROCPERI
!
!
!
!******************************************************************************