rfluconv.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Driver routine for rfluconv.
!
! Description: None.
!
! Input: 
!   caseString  String with casename
!   stampString String with iteration or time stamp
!   verbLevel   Verbosity level
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: rfluconv.F90,v 1.6 2008/12/06 08:44:55 mtcampbe Exp $
!
! Copyright: (c) 2003-2005 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rfluconv(caseString,stampString,verbLevel)

  USE modglobal, ONLY: t_global
  USE moderror
  USE moddatatypes
  USE moddatastruct, ONLY: t_level,t_region
  USE modparameters
           
  USE rflu_modboundlists             
  USE rflu_modcellmapping
  USE rflu_moddimensions
  USE rflu_modfacelist 
  USE rflu_modgeometry 
  USE rflu_modreadbcinputfile 
  USE rflu_modreadwriteflow 
  USE rflu_modreadwritegrid 
  USE rflu_modregionmapping        
  USE rflu_modstl
  USE rflu_modtetmesh
               
  USE modinterfaces, ONLY: rflu_allocmemsolwrapper, & 
                           rflu_builddatastruct, &
                           rflu_creategrid, &
                           rflu_deallocmemsolwrapper, &
                           rflu_destroygrid, &
                           rflu_getuserinput, &
                           rflu_initglobal, &
                           rflu_printflowinfo, &
                           rflu_printgridinfo, &
                           rflu_printheader, &
                           rflu_printwarninfo, &
                           rflu_setvarinfowrapper, &   
                           rflu_writeversionstring
                              
  IMPLICIT NONE

! ******************************************************************************
! Definitions and declarations
! ******************************************************************************

! ==============================================================================
! Arguments
! ==============================================================================

  CHARACTER(*) :: casestring,stampstring
  INTEGER, INTENT(IN) :: verblevel

! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER(CHRLEN) :: casename,nregions,rcsidentstring,stamp
  INTEGER, PARAMETER :: conv_rflu2rflu_asc2bin_grid     = 10, & 
                        conv_rflu2rflu_asc2bin_gridflow = 11, & 
                        conv_rflu2rflu_bin2asc_grid     = 20, & 
                        conv_rflu2rflu_bin2asc_gridflow = 21, & 
                        conv_rflu2tetm_grid             = 40, & 
                        conv_rflu2stl_grid              = 50                        
  INTEGER :: convoption,errorflag,ireg
  TYPE(t_region), POINTER :: pregion
  TYPE(t_global), POINTER :: global
  TYPE(t_level), POINTER :: levels(:)

!******************************************************************************

  rcsidentstring = '$RCSfile: rfluconv.F90,v $ $Revision: 1.6 $'

! ******************************************************************************
! Start, initialize global data
! ******************************************************************************

  ALLOCATE(global,stat=errorflag)
  IF ( errorflag /= err_none ) THEN 
    WRITE(stderr,'(A,1X,A)') solver_name,'ERROR - Pointer allocation failed.'
    stop
  END IF ! errorFlag 

  casename = casestring(1:len(casestring))
  stamp    = stampstring(1:len(stampstring))
  
  CALL rflu_initglobal(casename,verblevel,crazy_value_int,global)

  CALL registerfunction(global,'main', &
                        'rfluconv.F90')

! ******************************************************************************
! Print header
! ******************************************************************************

  CALL rflu_writeversionstring(global)
  CALL rflu_printheader(global)

! ******************************************************************************
! Get conversion option
! ******************************************************************************

  WRITE(stdout,'(A,1X,A)')    solver_name,'Options:'
  WRITE(stdout,'(A,3X,A)')    solver_name, &
                              'Convert Rocflu files from ASCII to binary format:'
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2rflu_asc2bin_grid, &
                              ': Grid file only'
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2rflu_asc2bin_gridflow, &
                              ': Grid and flow file'   
  WRITE(stdout,'(A,3X,A)')    solver_name, &
                              'Convert Rocflu files from binary to ASCII format:'
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2rflu_bin2asc_grid, &
                              ': Grid file only'
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2rflu_bin2asc_gridflow, &
                              ': Grid and flow file' 
  WRITE(stdout,'(A,3X,A)')    solver_name, &                                  
                              'Convert Rocflu grid file to surface grid:'
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2tetm_grid, &
                              ': Tetmesh/YAMS surface grid (msh2 format)' 
  WRITE(stdout,'(A,5X,I2,A)') solver_name,conv_rflu2stl_grid, &
                              ': STL surface grid'                                                                                       
  WRITE(stdout,'(A,1X,A)')    solver_name,'Enter selection:'

  READ(stdin,*) convoption

! ******************************************************************************
! Read mapping file and impose serial mapping
! ******************************************************************************

  CALL rflu_readregionmappingfile(global,mapfile_readmode_peek,global%myProcId)
  CALL rflu_setregionmappingserial(global)
  CALL rflu_createregionmapping(global,maptype_reg)
  CALL rflu_imposeregionmappingserial(global)
  
! ******************************************************************************
! Prepare data structure
! ******************************************************************************

  CALL rflu_builddatastruct(global,levels) 
  CALL rflu_applyregionmapping(global,levels)
  CALL rflu_destroyregionmapping(global,maptype_reg)

! ******************************************************************************
! Read input file
! ******************************************************************************

  CALL rflu_getuserinput(levels(1)%regions,.true.) 

  IF ( global%flowType == flow_steady ) THEN
    READ(stamp,*) global%currentIter
  ELSE
    READ(stamp,*) global%currentTime
  END IF ! global%flowType  

! ******************************************************************************
! Read dimensions and allocate memory
! ****************************************************************************** 

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    
    CALL rflu_readdimensions(pregion)      
    CALL rflu_creategrid(pregion)       
 
    IF ( pregion%grid%nPatches > 0 ) THEN      
      CALL rflu_readbcinputfilewrapper(pregion)    
    END IF ! pRegion%grid%nPatches     

    CALL rflu_allocmemsolwrapper(pregion)
    CALL rflu_setvarinfowrapper(pregion)    
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)

      CALL rflu_readdimensions(pregion)         
      CALL rflu_creategrid(pregion)

      IF ( pregion%grid%nPatches > 0 ) THEN      
        CALL rflu_readbcinputfilewrapper(pregion)    
      END IF ! pRegion%grid%nPatches
      
      CALL rflu_allocmemsolwrapper(pregion)
      CALL rflu_setvarinfowrapper(pregion)             
    END DO ! iReg  
  END IF ! global%nRegions

! ******************************************************************************
! Convert
! ******************************************************************************

  SELECT CASE ( convoption )

! ==============================================================================
!   Rocflu files from ASCII to binary - NOTE that the gridFormat and solutFormat 
!   variables are overridden.
! ==============================================================================  
  
! ------------------------------------------------------------------------------
!   Grid file only
! ------------------------------------------------------------------------------
  
    CASE (conv_rflu2rflu_asc2bin_grid)        
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)          
      
        pregion%global%gridFormat = format_ascii           
        CALL rflu_readgridwrapper(pregion)  
      
        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)
        END IF ! global%verbLevel 

        pregion%global%gridFormat = format_binary
        CALL rflu_writegridwrapper(pregion) 
      ELSE ! multiple regions
        DO ireg = 1,global%nRegionsLocal
          pregion => levels(1)%regions(ireg) 
         
          pregion%global%gridFormat = format_ascii              
          CALL rflu_readgridwrapper(pregion)  
      
          IF ( global%verbLevel > verbose_none ) THEN 
            CALL rflu_printgridinfo(pregion)
          END IF ! global%verbLevel 

          pregion%global%gridFormat = format_binary
          CALL rflu_writegridwrapper(pregion)                
        END DO ! iReg       
      END IF ! global%nRegions 

! ------------------------------------------------------------------------------
!   Grid and solution files
! ------------------------------------------------------------------------------

    CASE (conv_rflu2rflu_asc2bin_gridflow)
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)          

        pregion%global%gridFormat  = format_ascii
        pregion%global%solutFormat = format_ascii   
        CALL rflu_readgridwrapper(pregion)  
        CALL rflu_readflowwrapper(pregion)      

        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)
          CALL rflu_printflowinfo(pregion)          
        END IF ! global%verbLevel 

        pregion%global%gridFormat  = format_binary      
        pregion%global%solutFormat = format_binary      

        CALL rflu_writegridwrapper(pregion) 
        CALL rflu_writeflowwrapper(pregion) 
      ELSE ! multiple regions
        DO ireg = 1,global%nRegionsLocal
          pregion => levels(1)%regions(ireg) 

          pregion%global%gridFormat  = format_ascii
          pregion%global%solutFormat = format_ascii   
          CALL rflu_readgridwrapper(pregion)  
          CALL rflu_readflowwrapper(pregion)      

          IF ( global%verbLevel > verbose_none ) THEN 
            CALL rflu_printgridinfo(pregion)
            CALL rflu_printflowinfo(pregion)          
          END IF ! global%verbLevel 

          pregion%global%gridFormat  = format_binary      
          pregion%global%solutFormat = format_binary      

          CALL rflu_writegridwrapper(pregion) 
          CALL rflu_writeflowwrapper(pregion)                 
        END DO ! iReg       
      END IF ! global%nRegions    
      
! ==============================================================================
!   Rocflu files from binary to ASCII - NOTE that the gridFormat and solutFormat 
!   variables are overridden.
! ==============================================================================        

! ------------------------------------------------------------------------------
!   Grid file only
! ------------------------------------------------------------------------------
      
    CASE (conv_rflu2rflu_bin2asc_grid)
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)          
      
        pregion%global%gridFormat = format_binary          
        CALL rflu_readgridwrapper(pregion)  
      
        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)
        END IF ! global%verbLevel 

        pregion%global%gridFormat = format_ascii
        CALL rflu_writegridwrapper(pregion) 
      ELSE ! multiple regions
        DO ireg = 1,global%nRegionsLocal
          pregion => levels(1)%regions(ireg) 
         
          pregion%global%gridFormat = format_binary             
          CALL rflu_readgridwrapper(pregion)  
      
          IF ( global%verbLevel > verbose_none ) THEN 
            CALL rflu_printgridinfo(pregion)
          END IF ! global%verbLevel 

          pregion%global%gridFormat = format_ascii
          CALL rflu_writegridwrapper(pregion)                
        END DO ! iReg       
      END IF ! global%nRegions 
      
! ------------------------------------------------------------------------------
!   Grid and solution files
! ------------------------------------------------------------------------------

    CASE (conv_rflu2rflu_bin2asc_gridflow) 
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)          

        pregion%global%gridFormat  = format_binary
        pregion%global%solutFormat = format_binary  
        CALL rflu_readgridwrapper(pregion)  
        CALL rflu_readflowwrapper(pregion)      

        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)
          CALL rflu_printflowinfo(pregion)          
        END IF ! global%verbLevel 

        pregion%global%gridFormat  = format_ascii      
        pregion%global%solutFormat = format_ascii      

        CALL rflu_writegridwrapper(pregion) 
        CALL rflu_writeflowwrapper(pregion) 
      ELSE ! multiple regions
        DO ireg = 1,global%nRegionsLocal
          pregion => levels(1)%regions(ireg) 

          pregion%global%gridFormat  = format_binary
          pregion%global%solutFormat = format_binary  
          CALL rflu_readgridwrapper(pregion)  
          CALL rflu_readflowwrapper(pregion)      

          IF ( global%verbLevel > verbose_none ) THEN 
            CALL rflu_printgridinfo(pregion)
            CALL rflu_printflowinfo(pregion)          
          END IF ! global%verbLevel 

          pregion%global%gridFormat  = format_ascii     
          pregion%global%solutFormat = format_ascii     

          CALL rflu_writegridwrapper(pregion) 
          CALL rflu_writeflowwrapper(pregion)                 
        END DO ! iReg       
      END IF ! global%nRegions    

! ==============================================================================
!   Convert Rocflu grid to surface grid
! ==============================================================================

! ------------------------------------------------------------------------------
!   Tetmesh/YAMS .msh2 format
! ------------------------------------------------------------------------------

    CASE (conv_rflu2tetm_grid) 
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)

        CALL rflu_readgridwrapper(pregion) 

        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)         
        END IF ! global%verbLevel         

        CALL rflu_createcellmapping(pregion)
        CALL rflu_readloc2globcellmapping(pregion)
        CALL rflu_buildglob2loccellmapping(pregion)    

        CALL rflu_createbvertexlists(pregion)
        CALL rflu_buildbvertexlists(pregion)

        CALL rflu_createfacelist(pregion)                               
        CALL rflu_buildfacelist(pregion)                                         
        CALL rflu_renumberbfacelists(pregion)                  

        CALL rflu_convrocflu2tetmesh(pregion)       
        CALL rflu_writesurfgridtetmesh(pregion)                

        CALL rflu_destroyfacelist(pregion)                    
        CALL rflu_destroybvertexlists(pregion)  
        CALL rflu_destroycellmapping(pregion)                            
      ELSE ! multiple regions, must not happen
        CALL errorstop(global,err_reached_default,__line__)       
      END IF ! global%nRegions  

! ------------------------------------------------------------------------------
!   STL format
! ------------------------------------------------------------------------------

    CASE (conv_rflu2stl_grid) 
      IF ( global%nRegions == 1 ) THEN ! single region
        pregion => levels(1)%regions(0)

        CALL rflu_readgridwrapper(pregion) 

        IF ( global%verbLevel > verbose_none ) THEN 
          CALL rflu_printgridinfo(pregion)         
        END IF ! global%verbLevel         

        CALL rflu_createcellmapping(pregion)
        CALL rflu_readloc2globcellmapping(pregion)
        CALL rflu_buildglob2loccellmapping(pregion)    

        CALL rflu_createbvertexlists(pregion)
        CALL rflu_buildbvertexlists(pregion)

        CALL rflu_createfacelist(pregion)                               
        CALL rflu_buildfacelist(pregion)                                         
        CALL rflu_renumberbfacelists(pregion)                  

        CALL rflu_creategeometry(pregion)
        CALL rflu_buildgeometry(pregion)                           

        CALL rflu_stl_writesurfgridascii(pregion)                

        CALL rflu_destroygeometry(pregion)
        CALL rflu_destroyfacelist(pregion)
        CALL rflu_destroybvertexlists(pregion)                      
        CALL rflu_destroycellmapping(pregion)                            
      ELSE ! multiple regions, must not happen
        CALL errorstop(global,err_reached_default,__line__)       
      END IF ! global%nRegions  

! ==============================================================================
!   Default
! ==============================================================================        

    CASE default 
      CALL errorstop(global,err_reached_default,__line__)
  END SELECT ! convOption

! ******************************************************************************
! Deallocate memory for solution and grid
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    
    CALL rflu_deallocmemsolwrapper(pregion) 
    CALL rflu_destroygrid(pregion)
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)

      CALL rflu_deallocmemsolwrapper(pregion) 
      CALL rflu_destroygrid(pregion)
    END DO ! iReg  
  END IF ! global%nRegions

! *****************************************************************************
! Print info about warnings
! *****************************************************************************

  CALL rflu_printwarninfo(global)

! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rfluconv

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: rfluconv.F90,v $
! Revision 1.6  2008/12/06 08:44:55  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:18:05  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/02/06 23:55:54  haselbac
! Added comm argument to RFLU_InitGlobal
!
! Revision 1.3  2005/07/07 03:51:09  haselbac
! Added STL conversion, some clean-up
!
! Revision 1.2  2005/05/03 03:09:09  haselbac
! Converted to C++ reading of command-line, fixed bug in formats
!
! Revision 1.1  2005/04/18 14:57:56  haselbac
! Initial revision
!
! ******************************************************************************