RFLU_ModSTL.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines to write grids in STL format.
!
! Description: None.
!
! Notes: None. 
!
! ******************************************************************************
!
! $Id: RFLU_ModSTL.F90,v 1.4 2008/12/06 08:44:55 mtcampbe Exp $
!
! Copyright: (c) 2005 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modstl

  USE modparameters
  USE moddatatypes  
  USE moderror  
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch  
  USE moddatastruct, ONLY: t_region
  USE modmpi

  USE modbuildfilenames, ONLY: buildfilenameplain

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

  PRIVATE

! ==============================================================================
! Data
! ==============================================================================

  CHARACTER(CHRLEN) :: & 
    RCSIdentString = '$RCSfile: RFLU_ModSTL.F90,v $ $Revision: 1.4 $'        

! ==============================================================================
! Public procedures
! ==============================================================================

  PUBLIC :: rflu_stl_writesurfgridascii

! ******************************************************************************
! Routines
! ******************************************************************************

  CONTAINS
  
  



! ******************************************************************************
!
! Purpose: Write surface grid in ASCII STL format.
!
! Description: None.
!
! Input:
!   pRegion     Pointer to region
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_stl_writesurfgridascii(pRegion)

    IMPLICIT NONE
  
! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************  

! ==============================================================================
!   Arguments
! ==============================================================================

    TYPE(t_region), POINTER :: pregion  
   
! ==============================================================================
!   Local variables
! ==============================================================================

    LOGICAL :: writepatchflag
    CHARACTER(1) :: writepatchchar 
    CHARACTER(CHRLEN) :: ifilename
    INTEGER :: errorflag,ifl,ifile,ipatch,ivg,ivl,ivl2
    TYPE(t_grid), POINTER :: pgrid  
    TYPE(t_global), POINTER :: global
    TYPE(t_patch), POINTER :: ppatch
    
! ******************************************************************************
!   Start
! ******************************************************************************

    global => pregion%global

    CALL registerfunction(global,'RFLU_STL_WriteSurfGridASCII', &
                          'RFLU_ModSTL.F90')

    IF ( global%verbLevel > verbose_none ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name, & 
                               'Writing surface grid in ASCII STL format...'
    END IF ! global%verbLevel

! ==============================================================================
!   Set pointers and variables
! ==============================================================================

    pgrid => pregion%grid

! ******************************************************************************
!   Writing file
! ******************************************************************************

! ==============================================================================
!   Open file
! ==============================================================================

    ifile = if_grid

    CALL buildfilenameplain(global,filedest_indir,'.stl',ifilename)  

    OPEN(ifile,file=ifilename,form="FORMATTED",status="UNKNOWN", & 
         iostat=errorflag)   
    global%error = errorflag        
    IF ( global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_open,__line__,ifilename)
    END IF ! global%error

! ==============================================================================
!   Write file by looping over patches
! ==============================================================================

    WRITE(ifile,'(A)') 'solid'

    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

! ------------------------------------------------------------------------------
!     Determine whether patch is to be written
! ------------------------------------------------------------------------------      
      
      WRITE(stdout,'(A,3X,A,1X,I2,1X,A)') solver_name,'Write patch', & 
                                          ipatch,'to STL file? (y/n)'
      READ(stdin,'(A)',iostat=errorflag) writepatchchar 
      
      IF ( errorflag == err_none ) THEN 
        IF ( writepatchchar == 'y' ) THEN 
          writepatchflag = .true.
        ELSE
          writepatchflag = .false. 
        END IF ! choice
      ELSE 
        writepatchflag = .false.
      END IF ! errorFlag

! ------------------------------------------------------------------------------
!     Write patch. NOTE quadrilateral faces written as two triangles.
! ------------------------------------------------------------------------------      
      
      IF ( writepatchflag .EQV. .true. ) THEN 
        IF ( global%verbLevel > verbose_none ) THEN 
          WRITE(stdout,'(A,5X,A,1X,I2,1X,A)') solver_name,'Writing patch', & 
                                              ipatch,'to STL file...'      
        END IF ! global%verbLevel 
      
! ----- Triangles --------------------------------------------------------------
      
        DO ifl = 1,ppatch%nBTris
          WRITE(ifile,'(A,3(1X,E13.6))') 'facet normal', & 
                                         ppatch%fn(xcoord:zcoord,ifl)                                       
          WRITE(ifile,'(A)') 'outer loop'                                         

          DO ivl = 1,3          
            ivg = ppatch%bTri2v(ivl,ifl)

            WRITE(ifile,'(A,3(1X,E13.6))') 'vertex',pgrid%xyz(xcoord:zcoord,ivg)
          END DO ! ivl   

          WRITE(ifile,'(A)') 'endloop'          
          WRITE(ifile,'(A)') 'endfacet'                                                                                
        END DO ! ifl  

! ----  Quadrilaterals ---------------------------------------------------------
      
        DO ifl = 1,ppatch%nBQuads

! ------- Triangle 1       

          WRITE(ifile,'(A,3(1X,E13.6))') 'facet normal', & 
                                         ppatch%fn(xcoord:zcoord,ifl)                                       
          WRITE(ifile,'(A)') 'outer loop'                                         

          DO ivl = 1,3          
            ivg = ppatch%bQuad2v(ivl,ifl)

            WRITE(ifile,'(A,3(1X,E13.6))') 'vertex',pgrid%xyz(xcoord:zcoord,ivg)
          END DO ! ivl   

          WRITE(ifile,'(A)') 'endloop'          
          WRITE(ifile,'(A)') 'endfacet'                  

! ------- Triangle 2       

          WRITE(ifile,'(A,3(1X,E13.6))') 'facet normal', & 
                                         ppatch%fn(xcoord:zcoord,ifl)                                       
          WRITE(ifile,'(A)') 'outer loop'         

          DO ivl = 3,5
            IF ( ivl == 5 ) THEN 
              ivl2 = 1
            ELSE 
              ivl2 = ivl
            END IF ! ivl 

            ivg = ppatch%bQuad2v(ivl2,ifl)

            WRITE(ifile,'(A,3(1X,E13.6))') 'vertex',pgrid%xyz(xcoord:zcoord,ivg)
          END DO ! ivl         

          WRITE(ifile,'(A)') 'endloop'          
          WRITE(ifile,'(A)') 'endfacet'                                                                                
        END DO ! ifl
        
        IF ( global%verbLevel > verbose_none ) THEN 
          WRITE(stdout,'(A,5X,A,1X,I2,1X,A)') solver_name,'Writing patch', & 
                                              ipatch,'to STL file done.'      
        END IF ! global%verbLevel       
      END IF ! writePatchFlag          
    END DO ! iPatch

    WRITE(ifile,'(A)') 'endsolid'

! ==============================================================================
!   Close file
! ==============================================================================

    CLOSE(ifile,iostat=errorflag)
    global%error = errorflag      
    IF ( global%myProcid == masterproc .AND. &
         global%error /= err_none ) THEN 
      CALL errorstop(global,err_file_close,__line__,ifilename)
    END IF ! global%error

! ******************************************************************************
!   End
! ******************************************************************************

    IF ( global%verbLevel > verbose_none ) THEN 
      WRITE(stdout,'(A,1X,A)') solver_name, & 
                               'Writing surface grid in ASCII STL format done.'
    END IF ! global%verbLevel

    CALL deregisterfunction(global)

  END SUBROUTINE rflu_stl_writesurfgridascii
  
  
  
  
  
  
! ******************************************************************************
! End
! ******************************************************************************


END MODULE rflu_modstl

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModSTL.F90,v $
! Revision 1.4  2008/12/06 08:44:55  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:05  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/07/07 18:01:14  haselbac
! Bug fix (found on alc) for loop index
!
! Revision 1.1  2005/07/07 03:51:55  haselbac
! Initial revision
!
! ******************************************************************************