main.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!*******************************************************************************
!
! Purpose: Driver to extract special cells for postprocessor.
!
! Description: None.
!
! Input: None.
!
! Output: None.
!
! Notes: 
!   1. This utility is needed because rflupost_charm cannot accept input
!      from the command-line. Hence extract the information here and write to 
!      text file.
!
!*******************************************************************************
!
! $Id: main.F90,v 1.5 2008/12/06 08:44:54 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!*******************************************************************************

PROGRAM rflucells

  USE moddatatypes
  USE modglobal, ONLY: t_global 
  USE moderror
  USE moddatastruct, ONLY: t_level,t_region
  USE modparameters
  
  USE rflu_modcellmapping
  USE rflu_modfacelist
  USE rflu_modfem  
  
  USE modinterfaces, ONLY: rflu_allocatememorywrapper, & 
                           rflu_assignregionmapping,rflu_builddatastruct, &
                           rflu_closespecialcellsfile, &
                           rflu_computedimensions, &
                           rflu_deallocatememorywrapper,rflu_getspecialcells, &                       
                           rflu_getuserinput,rflu_imposeserialmapping, & 
                           rflu_initglobal,rflu_openspecialcellsfile, &
                           rflu_printgridinfo,rflu_printheader, &
                           rflu_readdimensions,rflu_readgridwrapper, &
                           rflu_readinputfile,rflu_readmappingfile, &
                           rflu_writespecialcells,rflu_writeversionstring                                                     
  
  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************

! ==============================================================================
! Local variables
! ==============================================================================

  LOGICAL :: specialcellfileexists
  CHARACTER(CHRLEN) :: casename,nregions,rcsidentstring,stampstr,verbosity
  INTEGER :: errorflag,ireg,verblevel
  TYPE(t_region), POINTER :: pregion
  TYPE(t_global), POINTER :: global
  TYPE(t_level), POINTER :: levels(:)

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: main.F90,v $ $Revision: 1.5 $'

! ******************************************************************************
! Get command-line options
! ******************************************************************************

  CALL getarg(1,casename)
  CALL getarg(2,stampstr)  
  CALL getarg(3,verbosity)

  IF ( len_trim(casename)  == 0 .OR. & 
       len_trim(stampstr)  == 0 .OR. & 
       len_trim(verbosity) == 0         ) THEN
    WRITE(stdout,'(A     )') solver_name
    WRITE(stdout,'(A,1X,A)') solver_name,'Usage: rflucells <casename> <stamp> <verb>'
    WRITE(stdout,'(A,1X,A)') solver_name,'       stamp = iteration (steady flow)'
    WRITE(stdout,'(A,1X,A)') solver_name,'               time (unsteady flow)'    
    WRITE(stdout,'(A,1X,A)') solver_name,'       verb  = 0 - no verbose output'
    WRITE(stdout,'(A,1X,A)') solver_name,'               1 - some verbose output'
    WRITE(stdout,'(A,1X,A)') solver_name,'               2 - a lot of verbose output'        
    WRITE(stdout,'(A     )') solver_name
    stop
  END IF ! LEN_TRIM

  READ(verbosity,*) verblevel

! ******************************************************************************
! Initialize global data
! ******************************************************************************
  
  ALLOCATE(global,stat=errorflag)
  IF ( errorflag /= err_none ) THEN 
    WRITE(stderr,'(A,1X,A)') solver_name,'ERROR - Pointer allocation failed.'
    stop
  END IF ! errorFlag   
  
  CALL rflu_initglobal(casename,verblevel,global)

  CALL registerfunction(global,'driver', &
                        'main.F90')

! ******************************************************************************
! Print header and write version string
! ******************************************************************************

  IF ( global%myProcid == masterproc ) THEN
    CALL rflu_writeversionstring(global)     
    IF ( global%verbLevel /= verbose_none ) THEN
      CALL rflu_printheader(global)
    END IF ! global%verbLevel
  END IF ! global%myProcid

! ******************************************************************************
! Read mapping file and impose serial mapping
! ******************************************************************************

  CALL rflu_readmappingfile(global,mapfile_readmode_peek)
  CALL rflu_imposeserialmapping(global)

! ******************************************************************************
! Prepare data structure
! ******************************************************************************
  
  CALL rflu_builddatastruct(global,levels)
  CALL rflu_assignregionmapping(global,levels)
  
! ******************************************************************************  
! Read input file
! ******************************************************************************

  CALL rflu_getuserinput(levels(1)%regions)  

  IF ( global%flowType == flow_steady ) THEN
    READ(stampstr,*) global%currentIter
  ELSE
    READ(stampstr,*) global%currentTime
  END IF ! global%flowType  

! ******************************************************************************  
! Read dimensions file, allocate memory, and read bc file
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    
    CALL rflu_readdimensions(pregion)         
    CALL rflu_allocatememorywrapper(pregion,alloc_mode_all)      
    
    CALL rflu_createcellmapping(pregion)
    CALL rflu_createfacelist(pregion)
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)
      
      CALL rflu_readdimensions(pregion) 
      CALL rflu_allocatememorywrapper(pregion,alloc_mode_all)
           
      CALL rflu_createcellmapping(pregion)
      CALL rflu_createfacelist(pregion)                                       
    END DO ! iReg    
  END IF ! global%nRegions
  
! ******************************************************************************  
! Read grid
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    CALL rflu_readgridwrapper(pregion)  
    
    IF ( global%verbLevel > verbose_none ) THEN 
      CALL rflu_printgridinfo(pregion)
    END IF ! global%verbLevel    
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)
      CALL rflu_readgridwrapper(pregion)  

      IF ( global%verbLevel > verbose_none ) THEN 
        CALL rflu_printgridinfo(pregion)
      END IF ! global%verbLevel     
    END DO ! iReg            
  END IF ! global%nRegions

! ******************************************************************************
! Build data structure 
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    CALL rflu_buildcellmapping(pregion)     
    CALL rflu_buildfacelist(pregion)  
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)
      CALL rflu_buildcellmapping(pregion)     
      CALL rflu_buildfacelist(pregion)      
    END DO ! iReg            
  END IF ! global%nRegions 

! ******************************************************************************
! Get special cells and write to file
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    CALL rflu_getspecialcells(pregion)    
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)
      CALL rflu_getspecialcells(pregion)            
    END DO ! iReg            
  END IF ! global%nRegions   

  CALL rflu_openspecialcellsfile(global,file_status_unknown, &
                                 specialcellfileexists)
  
  IF ( global%nRegions == 1 ) THEN ! single region
    pregion => levels(1)%regions(0)
    CALL rflu_writespecialcells(pregion)     
  ELSE ! multiple regions
    DO ireg = 1,global%nRegionsLocal
      pregion => levels(1)%regions(ireg)
      CALL rflu_writespecialcells(pregion)            
    END DO ! iReg            
  END IF ! global%nRegions   
  
  CALL rflu_closespecialcellsfile(global)

! ******************************************************************************
! Deallocate memory
! ******************************************************************************

  IF ( global%nRegions == 1 ) THEN 
    pregion => levels(1)%regions(0)  
    CALL rflu_deallocatememorywrapper(pregion)
  ELSE 
    DO ireg = 1,global%nRegions
      pregion => levels(1)%regions(ireg)          
      CALL rflu_deallocatememorywrapper(pregion)   
    END DO ! iReg
  END IF ! global%nRegions
  
! ******************************************************************************
! End
! ******************************************************************************

  WRITE(stdout,'(A)')      solver_name
  WRITE(stdout,'(A,1X,A)') solver_name,'Finished.'
  WRITE(stdout,'(A)')      solver_name

  CALL deregisterfunction(global)

END PROGRAM rflucells

!*******************************************************************************
!
! RCS Revision history:
!
! $Log: main.F90,v $
! Revision 1.5  2008/12/06 08:44:54  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:18:04  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2003/04/07 14:28:34  haselbac
! Fixed bug: Deleted superfluous call
!
! Revision 1.2  2003/04/01 19:39:20  haselbac
! Changed call to open special cells file
!
! Revision 1.1  2003/04/01 17:02:46  haselbac
! Initial revision
!
!*******************************************************************************