RFLU_GetSpecialCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!*******************************************************************************
!
! Purpose: Get special cells.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
! 
! Output: None.
!
! Notes: None.
!
!*******************************************************************************
!
! $Id: RFLU_GetSpecialCells.F90,v 1.3 2008/12/06 08:44:54 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!*******************************************************************************

SUBROUTINE rflu_getspecialcells(pRegion)

  USE modglobal, ONLY: t_global
  USE moddatatypes
  USE modparameters
  USE moderror  
  USE modbndpatch, ONLY: t_patch
  USE modgrid, ONLY: t_grid
  USE moddatastruct, ONLY: t_region
  USE modsortsearch

  USE rflu_modgrid

  IMPLICIT NONE

! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================
! Arguments
! ==============================================================================

  TYPE(t_region), POINTER :: pregion
 
! ==============================================================================
! Locals
! ==============================================================================

  CHARACTER :: infotype
  CHARACTER(CHRLEN) :: rcsidentstring  
  INTEGER :: cellindx,errorflag,faceindx,icellsspecial,icl,iloc, & 
             nvertpercell,patchindx,vertindx
  INTEGER :: v(8)
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch

! ******************************************************************************
! Start
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_GetSpecialCells.F90,v $'

  global => pregion%global

  CALL registerfunction(global,'RFLU_GetSpecialCells', &
                        'RFLU_GetSpecialCells.F90')

  IF ( global%verbLevel > verbose_none ) THEN
    WRITE(stdout,'(A,1X,A)') solver_name,'Getting special cells...'
    WRITE(stdout,'(A,3X,A,1X,I5.5)') solver_name,'Global region:', & 
                                     pregion%iRegionGlobal  
  END IF ! global%verbLevel

! ******************************************************************************
! Set pointers and initialize
! ******************************************************************************

  pgrid => pregion%grid

  icellsspecial = 0 
  pgrid%cellsSpecial(1:ncells_special_max) = 0

! ******************************************************************************
! Get information from user
! ******************************************************************************

  WRITE(stdout,'(A,5X,A)') solver_name,'Enter information on special cells:' 
  WRITE(stdout,'(A,7X,A)') solver_name,'b  - cell adjacent to boundary face'   
  WRITE(stdout,'(A,7X,A)') solver_name,'c  - single cell'
  WRITE(stdout,'(A,7X,A)') solver_name,'f  - cells adjacent to interior face'
  WRITE(stdout,'(A,7X,A)') solver_name,'v  - cells meeting at vertex'      
  WRITE(stdout,'(A,7X,A)') solver_name,'q  - quit'

! ==============================================================================
! Set up infinite loop
! ==============================================================================

  DO
  
! ------------------------------------------------------------------------------
!   Enter information type
! ------------------------------------------------------------------------------  
   
    WRITE(stdout,'(A,3X,A)') solver_name,'Enter information type:'
    READ(stdin,'(A)') infotype
  
    SELECT CASE ( infotype )
    
! --- cell adjacent to boundary face -------------------------------------------

      CASE ( 'b' ) 
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter patch index:'
        READ(stdin,*,iostat=errorflag) patchindx

        IF ( errorflag /= err_none ) THEN 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag        
          
        IF ( patchindx > 0 .AND. patchindx <= pgrid%nPatches ) THEN
          ppatch => pregion%patches(patchindx)
         
          WRITE(stdout,'(A,5X,A)') solver_name,'Enter face index:'
          READ(stdin,*,iostat=errorflag) faceindx           

          IF ( errorflag /= err_none ) THEN 
            WRITE(stdout,'(A,5X,A)') solver_name, & 
                                     '*** WARNING *** Invalid input.'
            cycle
          END IF ! errorFlag 

          IF ( faceindx > 0 .AND. faceindx <= ppatch%nBFacesTot ) THEN
            IF ( icellsspecial == ncells_special_max ) THEN 
              CALL errorstop(global,err_ncells_special_max,__line__)
            END IF ! iCellsSpecial          
           
            icellsspecial = icellsspecial + 1          
            pgrid%cellsSpecial(icellsspecial) = ppatch%bf2c(faceindx)
  
            WRITE(stdout,'(A,5X,A,1X,I8)') solver_name,'Added cell:', & 
                                           ppatch%bf2c(faceindx)        
          ELSE 
            WRITE(stdout,'(A,5X,A)') solver_name, & 
                                     '*** WARNING *** Invalid input.' 
            cycle 
          END IF ! faceIndx        
        ELSE 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! patchIndx
    
! --- single cell --------------------------------------------------------------    
    
      CASE ( 'c' )
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter cell index:'
        READ(stdin,*,iostat=errorflag) cellindx
        
        IF ( errorflag /= err_none ) THEN 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag        
        
        IF ( cellindx > 0 .AND. cellindx <= pgrid%nCellsTot ) THEN 
          IF ( icellsspecial == ncells_special_max ) THEN 
            CALL errorstop(global,err_ncells_special_max,__line__)
          END IF ! iCellsSpecial         
        
          icellsspecial = icellsspecial + 1          
          pgrid%cellsSpecial(icellsspecial) = cellindx
        ELSE 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! cellIndx

! --- cells adjacent to interior face ------------------------------------------    

      CASE ( 'f' ) 
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter interior face index:'
        READ(stdin,*,iostat=errorflag) faceindx
 
        IF ( errorflag /= err_none ) THEN 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag         
        
        IF ( faceindx > 0 .AND. faceindx <= pgrid%nFacesTot ) THEN
          IF ( icellsspecial == ncells_special_max-1 ) THEN 
            CALL errorstop(global,err_ncells_special_max,__line__)
          END IF ! iCellsSpecial         
         
          icellsspecial = icellsspecial + 1          
          pgrid%cellsSpecial(icellsspecial) = pgrid%f2c(1,faceindx)
                              
          icellsspecial = icellsspecial + 1          
          pgrid%cellsSpecial(icellsspecial) = pgrid%f2c(2,faceindx) 
          
          WRITE(stdout,'(A,5X,A,1X,I8,1X,A,1X,I8)') solver_name, & 
                'Added cells:',pgrid%f2c(1,faceindx),'and', & 
                pgrid%f2c(2,faceindx)         
        ELSE 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! faceIndx        
      
! --- cells meeting at vertex --------------------------------------------------
 
      CASE ( 'v' ) 
        WRITE(stdout,'(A,5X,A)') solver_name,'Enter vertex index:'
        READ(stdin,*,iostat=errorflag) vertindx        
      
        IF ( errorflag /= err_none ) THEN 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.'
          cycle
        END IF ! errorFlag               
      
        IF ( vertindx > 0 .AND. vertindx <= pgrid%nVertTot ) THEN 

! ------- Tetrahedra

          IF ( pgrid%nTetsTot > 0 ) THEN 
            WRITE(stdout,'(A,5X,A)') solver_name,'Tetrahedra...'            

            nvertpercell = 4

            DO icl = 1,pgrid%nTetsTot
              v(1:nvertpercell) = pgrid%tet2v(1:nvertpercell,icl)

              CALL quicksortinteger(v,nvertpercell)
              CALL binarysearchinteger(v,nvertpercell,vertindx,iloc)

              IF ( iloc /= element_not_found ) THEN 
                IF ( icellsspecial == ncells_special_max ) THEN 
                  CALL errorstop(global,err_ncells_special_max,__line__)
                END IF ! iCellsSpecial              
              
                icellsspecial = icellsspecial + 1          
                pgrid%cellsSpecial(icellsspecial) = pgrid%tet2CellGlob(icl)

                WRITE(stdout,'(A,7X,A,1X,I8)') solver_name,'Added cell:', & 
                                               pgrid%tet2CellGlob(icl)                                 
              END IF ! iloc            
            END DO ! icl        
          END IF ! pGrid%nTetsTot
        
! ------- Hexahedra        
        
          IF ( pgrid%nHexsTot > 0 ) THEN 
            WRITE(stdout,'(A,5X,A)') solver_name,'Hexahedra...'             
        
            nvertpercell = 8        
        
            DO icl = 1,pgrid%nHexsTot
              v(1:nvertpercell) = pgrid%hex2v(1:nvertpercell,icl)

              CALL quicksortinteger(v,nvertpercell)
              CALL binarysearchinteger(v,nvertpercell,vertindx,iloc)

              IF ( iloc /= element_not_found ) THEN 
                IF ( icellsspecial == ncells_special_max ) THEN 
                  CALL errorstop(global,err_ncells_special_max,__line__)
                END IF ! iCellsSpecial              

                icellsspecial = icellsspecial + 1          
                pgrid%cellsSpecial(icellsspecial) = pgrid%hex2CellGlob(icl)

                WRITE(stdout,'(A,7X,A,1X,I8)') solver_name,'Added cell:', & 
                                               pgrid%hex2CellGlob(icl)                                 
              END IF ! iloc            
            END DO ! icl  
          END IF ! pGrid%nPyrsTot                
        
! ------- Prisms        
        
          IF ( pgrid%nPrisTot > 0 ) THEN 
            WRITE(stdout,'(A,5X,A)') solver_name,'Prisms...'          

            nvertpercell = 6

            DO icl = 1,pgrid%nPrisTot
              v(1:nvertpercell) = pgrid%pri2v(1:nvertpercell,icl)

              CALL quicksortinteger(v,nvertpercell)
              CALL binarysearchinteger(v,nvertpercell,vertindx,iloc)

              IF ( iloc /= element_not_found ) THEN 
                IF ( icellsspecial == ncells_special_max ) THEN 
                  CALL errorstop(global,err_ncells_special_max,__line__)
                END IF ! iCellsSpecial              

                icellsspecial = icellsspecial + 1          
                pgrid%cellsSpecial(icellsspecial) = pgrid%pri2CellGlob(icl)

                WRITE(stdout,'(A,7X,A,1X,I8)') solver_name,'Added cell:', & 
                                               pgrid%pri2CellGlob(icl)                                 
              END IF ! iloc            
            END DO ! icl      
          END IF ! pGrid%nPyrsTot                 
        
! ------- Pyramids        
        
          IF ( pgrid%nPyrsTot > 0 ) THEN 
            WRITE(stdout,'(A,5X,A)') solver_name,'Pyramids...'          
        
            nvertpercell = 5        
        
            DO icl = 1,pgrid%nPyrsTot
              v(1:nvertpercell) = pgrid%pyr2v(1:nvertpercell,icl)

              CALL quicksortinteger(v,nvertpercell)
              CALL binarysearchinteger(v,nvertpercell,vertindx,iloc)

              IF ( iloc /= element_not_found ) THEN 
                IF ( icellsspecial == ncells_special_max ) THEN 
                  CALL errorstop(global,err_ncells_special_max,__line__)
                END IF ! iCellsSpecial              

                icellsspecial = icellsspecial + 1          
                pgrid%cellsSpecial(icellsspecial) = pgrid%pyr2CellGlob(icl)

                WRITE(stdout,'(A,7X,A,1X,I8)') solver_name,'Added cell:', & 
                                               pgrid%pyr2CellGlob(icl)                                 
              END IF ! iloc            
            END DO ! icl         
          END IF ! pGrid%nPyrsTot
        
        ELSE 
          WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
          cycle 
        END IF ! vertIndx          
      
! --- quit ---------------------------------------------------------------------      
      
      CASE ( 'q' )
        EXIT
        
! --- default ------------------------------------------------------------------        
        
      CASE default 
        WRITE(stdout,'(A,5X,A)') solver_name,'*** WARNING *** Invalid input.' 
        cycle 
    END SELECT  
  END DO ! <empty> 

! ==============================================================================
! Set number of special cells
! ==============================================================================

  pgrid%nCellsSpecial = icellsspecial

! ******************************************************************************
! End
! ******************************************************************************

  IF ( global%verbLevel > verbose_none ) THEN 
    WRITE(stdout,'(A,1X,A)') solver_name,'Getting special cells done.'
  END IF ! global%verbLevel

  CALL deregisterfunction(global)

END SUBROUTINE rflu_getspecialcells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_GetSpecialCells.F90,v $
! Revision 1.3  2008/12/06 08:44:54  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:18:04  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2003/04/01 17:02:46  haselbac
! Initial revision
!
! Revision 1.2  2003/03/20 20:07:19  haselbac
! Modified RegFun call to avoid probs with
! long 'RFLU_GetSpecialCells.F90' names
!
! Revision 1.1  2003/03/15 19:16:54  haselbac
! Initial revision
!
!******************************************************************************