TURB_rFLO_RansSpectralRadii.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate spectral radii for turbulence RaNS model class
!
! Description: none.
!
! Input: regions = data of all grid regions.
!
! Output: regions%levels%turb%srad = convective spectral radii for RaNS
!
! Notes: grid speeds already contain face area
!
!******************************************************************************
!
! $Id: TURB_rFLO_RansSpectralRadii.F90,v 1.3 2008/12/06 08:44:45 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_rflo_ransspectralradii( region ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset, &
        rflo_getnodeoffset, rflo_copyvectorpatches, rflo_copyvectoredges, &
        rflo_copyvectorcorners, rflo_copymatrixpatches, rflo_copymatrixedges, &
        rflo_copymatrixcorners, rflo_getdimensphys
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables

  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc, ijkn, ijkn1, indsvel

  REAL(RFREAL) :: rrho, u, v, w, sx, sy, sz, svel, vc
  REAL(RFREAL), POINTER :: cv(:,:)
  REAL(RFREAL), POINTER :: si(:,:), sj(:,:), sk(:,:), vol(:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)
  REAL(RFREAL), POINTER :: srad(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'TURB_RFLO_RansSpectralRadii',&
  'TURB_rFLO_RansSpectralRadii.F90' )

  IF (region%turbInput%modelClass /= model_rans) goto 999

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend,jdcbeg,jdcend, &
                            kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  cv => region%levels(ilev)%mixt%cv

  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  vol    => region%levels(ilev)%grid%vol
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

  srad => region%levels(ilev)%turb%srad

! local time step, spectral radii ---------------------------------------------

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        ijkc = indijk(i,j,k,icoff,ijcoff)
        ijkn = indijk(i,j,k,inoff,ijnoff)
        rrho = 1._rfreal/cv(cv_mixt_dens,ijkc)
        u    = cv(cv_mixt_xmom,ijkc)*rrho
        v    = cv(cv_mixt_ymom,ijkc)*rrho
        w    = cv(cv_mixt_zmom,ijkc)*rrho

        ijkn1 = indijk(i+1,j,k,inoff,ijnoff)
        sx    = 0.5_rfreal*(si(xcoord,ijkn)+si(xcoord,ijkn1))
        sy    = 0.5_rfreal*(si(ycoord,ijkn)+si(ycoord,ijkn1))
        sz    = 0.5_rfreal*(si(zcoord,ijkn)+si(zcoord,ijkn1))
        svel  = 0.5_rfreal*(sivel(ijkn*indsvel)+sivel(ijkn1*indsvel))
        vc    = sx*u + sy*v + sz*w - svel
        srad(icoord,ijkc) = abs(vc)

        ijkn1 = indijk(i,j+1,k,inoff,ijnoff)
        sx    = 0.5_rfreal*(sj(xcoord,ijkn)+sj(xcoord,ijkn1))
        sy    = 0.5_rfreal*(sj(ycoord,ijkn)+sj(ycoord,ijkn1))
        sz    = 0.5_rfreal*(sj(zcoord,ijkn)+sj(zcoord,ijkn1))
        svel  = 0.5_rfreal*(sjvel(ijkn*indsvel)+sjvel(ijkn1*indsvel))
        vc    = sx*u + sy*v + sz*w - svel
        srad(jcoord,ijkc) = abs(vc)

        ijkn1 = indijk(i,j,k+1,inoff,ijnoff)
        sx    = 0.5_rfreal*(sk(xcoord,ijkn)+sk(xcoord,ijkn1))
        sy    = 0.5_rfreal*(sk(ycoord,ijkn)+sk(ycoord,ijkn1))
        sz    = 0.5_rfreal*(sk(zcoord,ijkn)+sk(zcoord,ijkn1))
        svel  = 0.5_rfreal*(skvel(ijkn*indsvel)+skvel(ijkn1*indsvel))
        vc    = sx*u + sy*v + sz*w - svel
        srad(kcoord,ijkc) = abs(vc)

      ENDDO  ! i
    ENDDO    ! j
  ENDDO      ! k

! treat dummy cells -----------------------------------------------------------

  CALL rflo_copymatrixpatches( ilev,region,srad )
  CALL rflo_copymatrixedges( ilev,region,srad )
  CALL rflo_copymatrixcorners( ilev,region,srad )

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE turb_rflo_ransspectralradii

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLO_RansSpectralRadii.F90,v $
! Revision 1.3  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/03/11 03:26:33  wasistho
! changed rocturb nomenclature
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/10/21 22:08:30  wasistho
! modified grid speed as it already contain face area
!
! Revision 1.1  2003/10/07 02:17:03  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************