RFLO_CopyMatrixDummy.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: copy a matrix from the boundary cells to the dummy cells.
!
! Description: file contains the following subroutines:
!
!  - RFLO_copyMatrixPatches = copy for patches
!  - RFLO_copyMatrixEdges   = copy for edge cells
!  - RFLO_copyMatrixCorners = copy for corner cells
!
! Input: iLev   = grid level
!        region = dimensions of current region
!        mat    = data to be copied
!
! Output: mat = data copied to dummy cells.
!
! Notes: it is assumed that the first dimension of the matrix is to be
!        copied completely. No averaging is done. Thus, these routines are
!        primarily intended to copy geometrical quantities rather than
!        flow variables. All edge and corner cells are copied, regardless
!        of their connection to other regions. Routines are used now to copy
!        the spectral radii.
!
!******************************************************************************
!
! $Id: RFLO_CopyMatrixDummy.F90,v 1.3 2008/12/06 08:44:26 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_copymatrixpatches( iLev,region,mat )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getpatchindices, &
                            rflo_getpatchdirection
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

  INTEGER :: ilev

  REAL(RFREAL), POINTER :: mat(:,:)

! ... loop variables
  INTEGER :: ipatch, i, j, k, idum

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: icoff, ijcoff, ijkcell, ijkdum, bctype

  TYPE(t_patch), POINTER :: patch

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_copyMatrixPatches',&
  'RFLO_CopyMatrixDummy.F90' )

! loop over patches (all but inter-region and periodic boundaries)

  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  DO ipatch=1,region%nPatches
    patch  => region%levels(ilev)%patches(ipatch)
    bctype = patch%bcType
    IF ((bctype<bc_regionconf .OR. bctype>bc_regionconf+bc_range) .AND.&
        (bctype<bc_regionint  .OR. bctype>bc_regionint +bc_range) .AND.&
        (bctype<bc_regnonconf .OR. bctype>bc_regnonconf+bc_range) .AND.&
        (bctype<bc_tra_peri   .OR. bctype>bc_tra_peri  +bc_range) .AND.&
        (bctype<bc_rot_peri   .OR. bctype>bc_rot_peri  +bc_range)) THEN
      CALL rflo_getpatchindices( region,patch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
      DO idum=1,region%nDumCells
        DO k=kbeg,kend
          DO j=jbeg,jend
            DO i=ibeg,iend
              ijkcell = indijk(i,j,k,icoff,ijcoff)
              ijkdum  = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)
              mat(:,ijkdum) = mat(:,ijkcell)
            ENDDO  ! i
          ENDDO    ! j
        ENDDO      ! k
      ENDDO        ! idum
    ENDIF          ! bcType
  ENDDO            ! iPatch

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_copymatrixpatches

! #############################################################################
! #############################################################################

SUBROUTINE rflo_copymatrixedges( iLev,region,mat )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                            rflo_getedgecellsindices
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

  INTEGER :: ilev

  REAL(RFREAL), POINTER :: mat(:,:)

! ... loop variables
  INTEGER :: i, j, k, iedge

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: icoff, ijcoff, ijkcell, ijkdum

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_copyMatrixEdges',&
  'RFLO_CopyMatrixDummy.F90' )

! loop over edge cells without source region
! or with multiple source regions

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  DO iedge=1,12
    CALL rflo_getedgecellsindices( region,ilev,iedge, &
                                   ibeg,iend,jbeg,jend,kbeg,kend )
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          IF (iedge ==  1) ijkcell = indijk(ipcbeg,jpcbeg,k,icoff,ijcoff)
          IF (iedge ==  2) ijkcell = indijk(ipcbeg,j,kpcend,icoff,ijcoff)
          IF (iedge ==  3) ijkcell = indijk(ipcbeg,jpcend,k,icoff,ijcoff)
          IF (iedge ==  4) ijkcell = indijk(ipcbeg,j,kpcbeg,icoff,ijcoff)
          IF (iedge ==  5) ijkcell = indijk(ipcend,jpcbeg,k,icoff,ijcoff)
          IF (iedge ==  6) ijkcell = indijk(ipcend,j,kpcend,icoff,ijcoff)
          IF (iedge ==  7) ijkcell = indijk(ipcend,jpcend,k,icoff,ijcoff)
          IF (iedge ==  8) ijkcell = indijk(ipcend,j,kpcbeg,icoff,ijcoff)
          IF (iedge ==  9) ijkcell = indijk(i,jpcbeg,kpcbeg,icoff,ijcoff)
          IF (iedge == 10) ijkcell = indijk(i,jpcbeg,kpcend,icoff,ijcoff)
          IF (iedge == 11) ijkcell = indijk(i,jpcend,kpcbeg,icoff,ijcoff)
          IF (iedge == 12) ijkcell = indijk(i,jpcend,kpcend,icoff,ijcoff)
          ijkdum        = indijk(i,j,k,icoff,ijcoff)
          mat(:,ijkdum) = mat(:,ijkcell)
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO          ! iedge

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_copymatrixedges

! #############################################################################
! #############################################################################

SUBROUTINE rflo_copymatrixcorners( iLev,region,mat )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys, &
        rflo_getcelloffset, rflo_getnodeoffset, volumehexa, &
        rflo_getpatchindices, rflo_getpatchdirection, rflo_getedgecellsindices,&
        rflo_getcornercellsindices
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

  INTEGER :: ilev

  REAL(RFREAL), POINTER :: mat(:,:)

! ... loop variables
  INTEGER :: i, j, k, icorn

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: icoff, ijcoff, ijkcell, ijkdum

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_copyMatrixCorners',&
  'RFLO_CopyMatrixDummy.F90' )

! loop over corner cells without source region
! or with multiple source regions

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  DO icorn=1,8
    CALL rflo_getcornercellsindices( region,ilev,icorn, &
                                     ibeg,iend,jbeg,jend,kbeg,kend )
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          IF (icorn == 1) ijkcell = indijk(ipcbeg,jpcbeg,kpcbeg,icoff,ijcoff)
          IF (icorn == 2) ijkcell = indijk(ipcbeg,jpcbeg,kpcend,icoff,ijcoff)
          IF (icorn == 3) ijkcell = indijk(ipcbeg,jpcend,kpcend,icoff,ijcoff)
          IF (icorn == 4) ijkcell = indijk(ipcbeg,jpcend,kpcbeg,icoff,ijcoff)
          IF (icorn == 5) ijkcell = indijk(ipcend,jpcbeg,kpcbeg,icoff,ijcoff)
          IF (icorn == 6) ijkcell = indijk(ipcend,jpcbeg,kpcend,icoff,ijcoff)
          IF (icorn == 7) ijkcell = indijk(ipcend,jpcend,kpcend,icoff,ijcoff)
          IF (icorn == 8) ijkcell = indijk(ipcend,jpcend,kpcbeg,icoff,ijcoff)
          ijkdum        = indijk(i,j,k,icoff,ijcoff)
          mat(:,ijkdum) = mat(:,ijkcell)
        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO          ! icorn

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_copymatrixcorners

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_CopyMatrixDummy.F90,v $
! Revision 1.3  2008/12/06 08:44:26  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:37  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:38  wasistho
! lower to upper case
!
! Revision 1.16  2003/11/20 16:40:39  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.12  2003/05/15 02:57:03  jblazek
! Inlined index function.
!
! Revision 1.11  2003/02/03 19:20:47  jblazek
! Added treatment of edge and corner cells for one processor.
!
! Revision 1.10  2002/09/27 00:57:10  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.9  2002/09/05 17:40:21  jblazek
! Variable global moved into regions().
!
! Revision 1.8  2002/07/12 21:50:07  jblazek
! Added tool to split single grid into multiple regions.
!
! Revision 1.7  2002/07/05 23:20:46  jblazek
! Corrected bug in perfgasDependentVars.F90; did some cosmetics.
!
! Revision 1.6  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.5  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.4  2002/02/01 00:00:24  jblazek
! Edge and corner cells defined for each level.
!
! Revision 1.3  2002/01/31 20:56:30  jblazek
! Added basic boundary conditions.
!
! Revision 1.2  2002/01/28 23:55:22  jblazek
! Added flux computation (central scheme).
!
! Revision 1.1  2002/01/23 03:51:25  jblazek
! Added low-level time-stepping routines.
!
!******************************************************************************