TURB_floRansSACentFlux.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective flux of SA eq. by average of variables.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%turb%rhs = convective fluxes added to SA residual.
!
! Notes: grid speeds si,j,kVel already contain face area
!
!******************************************************************************
!
! $Id: TURB_floRansSACentFlux.F90,v 1.5 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floranssacentflux( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                            rflo_getnodeoffset
  USE turb_modinterfaces, ONLY : turb_floranssacentfluxpatch
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ipatch

! ... local variables
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc0, ijkc1, ijkn, indsvel

  REAL(RFREAL)          :: rnutila, ua, va, wa, vcont, svel, fc
  REAL(RFREAL), POINTER :: dv(:,:), tcv(:,:), trhs(:,:)
  REAL(RFREAL), POINTER :: aci(:,:), acj(:,:), ack(:,:)
  REAL(RFREAL), POINTER :: si(:,:), sj(:,:), sk(:,:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansSACentFlux',&
  'TURB_floRansSACentFlux.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  dv     => region%levels(ilev)%mixt%dv
  tcv    => region%levels(ilev)%turb%cv
  trhs   => region%levels(ilev)%turb%rhs
  aci    => region%levels(ilev)%grid%c2fCoI
  acj    => region%levels(ilev)%grid%c2fCoJ
  ack    => region%levels(ilev)%grid%c2fCoK
  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        rnutila= aci(2,ijkn)*tcv(cv_sa_nutil,ijkc0)+ &
                 aci(1,ijkn)*tcv(cv_sa_nutil,ijkc1)
        ua     = aci(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = aci(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = aci(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 aci(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = sivel(ijkn*indsvel)
        vcont  = ua*si(xcoord,ijkn)+va*si(ycoord,ijkn)+wa*si(zcoord,ijkn)-svel

        fc = vcont*rnutila

        trhs(cv_sa_nutil,ijkc0) = trhs(cv_sa_nutil,ijkc0) + fc
        trhs(cv_sa_nutil,ijkc1) = trhs(cv_sa_nutil,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        rnutila= acj(2,ijkn)*tcv(cv_sa_nutil,ijkc0)+ &
                 acj(1,ijkn)*tcv(cv_sa_nutil,ijkc1)
        ua     = acj(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = acj(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = acj(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 acj(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = sjvel(ijkn*indsvel)
        vcont  = ua*sj(xcoord,ijkn)+va*sj(ycoord,ijkn)+wa*sj(zcoord,ijkn)-svel

        fc = vcont*rnutila

        trhs(cv_sa_nutil,ijkc0) = trhs(cv_sa_nutil,ijkc0) + fc
        trhs(cv_sa_nutil,ijkc1) = trhs(cv_sa_nutil,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        rnutila= ack(2,ijkn)*tcv(cv_sa_nutil,ijkc0)+ &
                 ack(1,ijkn)*tcv(cv_sa_nutil,ijkc1)
        ua     = ack(2,ijkn)*dv(dv_mixt_uvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_uvel,ijkc1)
        va     = ack(2,ijkn)*dv(dv_mixt_vvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_vvel,ijkc1)
        wa     = ack(2,ijkn)*dv(dv_mixt_wvel,ijkc0)+ &
                 ack(1,ijkn)*dv(dv_mixt_wvel,ijkc1)

        svel   = skvel(ijkn*indsvel)
        vcont  = ua*sk(xcoord,ijkn)+va*sk(ycoord,ijkn)+wa*sk(zcoord,ijkn)-svel

        fc = vcont*rnutila

        trhs(cv_sa_nutil,ijkc0) = trhs(cv_sa_nutil,ijkc0) + fc
        trhs(cv_sa_nutil,ijkc1) = trhs(cv_sa_nutil,ijkc1) - fc
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL turb_floranssacentfluxpatch( region, &
                                      region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floranssacentflux

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansSACentFlux.F90,v $
! Revision 1.5  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/08/02 21:55:07  wasistho
! replaced cell2face midpoint by linear averaging
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.3  2003/10/21 22:08:41  wasistho
! modified grid speed as it already contain face area
!
! Revision 1.2  2003/10/20 20:27:30  wasistho
! made consistent with compressible SA formulation
!
! Revision 1.1  2003/10/07 02:17:03  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************