TURB_floRansSACentFluxPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective fluxe of SA eq. through a patch
!          by using an average of variables.
!
! Description: none.
!
! Input: region = data of current region
!        patch  = current patch.
!
! Output: region%levels%turb%rhs = convective fluxes added to SA residual.
!
! Notes: grid speeds already contain face area.
!
!******************************************************************************
!
! $Id: TURB_floRansSACentFluxPatch.F90,v 1.7 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floranssacentfluxpatch( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getnodeoffset, bcondinjectionperf
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k, n1, n2

! ... local variables
  INTEGER :: ilev, lbound, bctype, distrib, gasmodel, indcp, indmol
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, i2d, noff
  INTEGER :: icoff, ijcoff, inoff, ijnoff, ijkcd, ijkcb0, ijkcb1, ijknb
  INTEGER :: inode, jnode, knode, indsvel, acid0, acid1

  REAL(RFREAL)          :: sgn, rhoa, rhoua, rhova, rhowa, rhoea, rhovrel(3)
  REAL(RFREAL)          :: rnutila, pa, mrate, tburn, ds, sf(3)
  REAL(RFREAL)          :: ua, va, wa, uinj, vinj, winj, vcont, sv, ac0, ac1
  REAL(RFREAL), POINTER :: dv(:,:), gv(:,:), tcv(:,:), trhs(:,:)
  REAL(RFREAL), POINTER :: avgco(:,:), sface(:,:), svel(:), vals(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansSACentFluxPatch',&
  'TURB_floRansSACentFluxPatch.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  bctype    = patch%bcType
  noff      = abs(patch%l1end-patch%l1beg) + 1
  distrib   = patch%mixt%distrib
  gasmodel = region%mixtInput%gasModel
  indcp     = region%levels(ilev)%mixt%indCp
  indmol    = region%levels(ilev)%mixt%indMol
  indsvel   = region%levels(ilev)%grid%indSvel

  dv   => region%levels(ilev)%mixt%dv
  gv   => region%levels(ilev)%mixt%gv
  tcv  => region%levels(ilev)%turb%cv
  trhs => region%levels(ilev)%turb%rhs
  vals => patch%mixt%vals

! to take the right face vector and make it point outwards

  sgn   = +1._rfreal
  inode = 0
  jnode = 0
  knode = 0
  acid0 = 2
  acid1 = 1
  IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
    sgn   = -1._rfreal
    inode = -idir
    jnode = -jdir
    knode = -kdir
    acid0 = 1
    acid1 = 2
  ENDIF

! get the appropriate face vector and grid speed

  IF (lbound==1 .OR. lbound==2) THEN
    avgco => region%levels(ilev)%grid%c2fCoI
    sface => region%levels(ilev)%grid%si
    svel  => region%levels(ilev)%grid%siVel
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    avgco => region%levels(ilev)%grid%c2fCoJ
    sface => region%levels(ilev)%grid%sj
    svel  => region%levels(ilev)%grid%sjVel
  ELSE IF (lbound==5 .OR. lbound==6) THEN
    avgco => region%levels(ilev)%grid%c2fCoK
    sface => region%levels(ilev)%grid%sk
    svel  => region%levels(ilev)%grid%skVel
  ENDIF

! stationary grid -------------------------------------------------------------

  IF (bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range) THEN

  ELSE IF (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) THEN

  ELSE IF (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range) THEN

  ELSE IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN

! injection boundary (as wall if mass flow rate <= 0)

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! boundary
          ijkcd  = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)  ! dummy
          ijkcb1 = indijk(i+idir ,j+jdir ,k+kdir ,icoff,ijcoff)  ! interior
          ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
          ac0    = avgco(acid0,ijknb)
          ac1    = avgco(acid1,ijknb)
          sf(1)  = sgn*sface(xcoord,ijknb)
          sf(2)  = sgn*sface(ycoord,ijknb)
          sf(3)  = sgn*sface(zcoord,ijknb)

          IF      (lbound==1 .OR. lbound==2) THEN
            n1 = j - jbeg
            n2 = k - kbeg
          ELSE IF (lbound==3 .OR. lbound==4) THEN
            n1 = k - kbeg
            n2 = i - ibeg
          ELSE IF (lbound==5 .OR. lbound==6) THEN
            n1 = i - ibeg
            n2 = j - jbeg
          ENDIF
          i2d        = distrib * indij(n1,n2,noff)
          mrate      = vals(bcdat_inject_mfrate,i2d)
          tburn      = vals(bcdat_inject_temp  ,i2d)
          rhovrel(1) = vals(bcdat_inject_rfvfu ,i2d)
          rhovrel(2) = vals(bcdat_inject_rfvfv ,i2d)
          rhovrel(3) = vals(bcdat_inject_rfvfw ,i2d)

          IF (mrate > 0._rfreal) THEN        ! surface burning
!            rnutila = ac0*tcv(CV_SA_NUTIL,ijkCB0)+ &
!                      ac1*tcv(CV_SA_NUTIL,ijkCD)
            rnutila = 0.5_rfreal*(3._rfreal*tcv(cv_sa_nutil,ijkcb0)- &
                                            tcv(cv_sa_nutil,ijkcb1))
            ds     = sqrt(sf(1)*sf(1)+sf(2)*sf(2)+sf(3)*sf(3))

            IF (gasmodel == gas_model_tcperf) THEN
              CALL bcondinjectionperf( distrib,mrate,tburn,rhovrel, &
                                       sf(1)/ds,sf(2)/ds,sf(3)/ds, &
                                       gv(gv_mixt_cp  ,ijkcb0*indcp ), &
                                       gv(gv_mixt_mol ,ijkcb0*indmol), &
                                       dv(dv_mixt_pres,ijkcb0       ), &
                                       rhoa,rhoua,rhova,rhowa,rhoea,pa, &
                                       uinj,vinj,winj )
            ELSE
              CALL errorstop( region%global,err_unknown_bc,__line__ )
            ENDIF
            vcont = uinj*sf(1) + vinj*sf(2) + winj*sf(3)

          ELSE                               ! not burning - slip/noslip wall
            rnutila = 0._rfreal
            vcont   = 0._rfreal
          ENDIF

          trhs(cv_sa_nutil,ijkcb0) = trhs(cv_sa_nutil,ijkcb0) + &
                                     vcont*rnutila

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

! non-conforming region interface

  ELSE IF (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! everything else

  ELSE

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! boundary
          ijkcd  = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)  ! dummy
          ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
          ac0    = avgco(acid0,ijknb)
          ac1    = avgco(acid1,ijknb)

          rnutila= ac0*tcv(cv_sa_nutil,ijkcb0)+ac1*tcv(cv_sa_nutil,ijkcd)
          ua     = ac0*dv(dv_mixt_uvel,ijkcb0)+ac1*dv(dv_mixt_uvel,ijkcd)
          va     = ac0*dv(dv_mixt_vvel,ijkcb0)+ac1*dv(dv_mixt_vvel,ijkcd)
          wa     = ac0*dv(dv_mixt_wvel,ijkcb0)+ac1*dv(dv_mixt_wvel,ijkcd)
          sf(1)  = sgn*sface(xcoord,ijknb)
          sf(2)  = sgn*sface(ycoord,ijknb)
          sf(3)  = sgn*sface(zcoord,ijknb)
          sv     = svel(ijknb*indsvel)
          vcont  = ua*sf(1)+va*sf(2)+wa*sf(3) - sv

          trhs(cv_sa_nutil,ijkcb0) = trhs(cv_sa_nutil,ijkcb0) + &
                                     vcont*rnutila
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  ENDIF         ! bcType

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floranssacentfluxpatch

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansSACentFluxPatch.F90,v $
! Revision 1.7  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/08/19 15:40:49  mparmar
! Renamed patch variables
!
! Revision 1.4  2005/10/31 21:09:37  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.3  2004/08/02 21:55:11  wasistho
! replaced cell2face midpoint by linear averaging
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.3  2003/10/21 22:08:47  wasistho
! modified grid speed as it already contain face area
!
! Revision 1.2  2003/10/20 20:27:40  wasistho
! made consistent with compressible SA formulation
!
! Revision 1.1  2003/10/07 02:17:03  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************