TURB_RansSASourceTerms.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: added source terms of SA/DES to the rhs.
!
! Description: see formulation of SA (La Recherche Aerospatiale 1, 5 (1994))
!
! Input: region = data of current region,
!
! Output: region%levels%turb%rhs , source terms added to rhs
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_RansSASourceTerms.F90,v 1.5 2008/12/06 08:44:42 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_ranssasourceterms( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
  USE turb_modinterfaces, ONLY : turb_calcvortic
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset

#include "Indexing.h"
#endif

  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ijkc
  
! ... local variables
  TYPE(t_global), POINTER :: global

  INTEGER :: ibc, iec
  REAL(RFREAL), POINTER :: cv(:,:), tv(:,:), vol(:), wdist(:)
  REAL(RFREAL), POINTER :: tcv(:,:), trhs(:,:), vort(:,:), dsterm(:,:)
  REAL(RFREAL) :: one6th, cv1, cw1, cw2, cw3, cb1, rkappa, rsigma
  REAL(RFREAL) :: rnuet, nuet, xi, fv1, fv2, rwdist, stilde, ro, go, fw
  REAL(RFREAL) :: vortmag, prod, destr, sterm

#ifdef RFLO
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ilev, icoff,ijcoff
#endif

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'TURB_RansSASourceTerms',&
  'TURB_RansSASourceTerms.F90' )

! get coefficients and parameters ---------------------------------------------

  one6th = 1._rfreal/6._rfreal  
  cv1    = region%turbInput%const(mc_sa_cv1)
  cw1    = region%turbInput%const(mc_sa_cw1)
  cw2    = region%turbInput%const(mc_sa_cw2)
  cw3    = region%turbInput%const(mc_sa_cw3)
  cb1    = region%turbInput%const(mc_sa_cb1)
  rkappa = region%turbInput%const(mc_sa_rkap)
  rsigma = region%turbInput%const(mc_sa_rsig)

! compute vorticities to be used below ----------------------------------------

  CALL turb_calcvortic( region )

! get dimensions and pointers -------------------------------------------------

#ifdef RFLO
  ilev  = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  cv      => region%levels(ilev)%mixt%cv
  tv      => region%levels(ilev)%mixt%tv
  tcv     => region%levels(ilev)%turb%cv
  trhs    => region%levels(ilev)%turb%rhs
  vort    => region%levels(ilev)%turb%vort
  wdist   => region%levels(ilev)%turb%lens
  dsterm  => region%levels(ilev)%turb%dsterm
  vol     => region%levels(ilev)%grid%vol

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        ijkc  = indijk(i     ,j     ,k     ,icoff,ijcoff)
#endif
#ifdef RFLU
  ibc = 1
  iec = region%grid%nCellsTot        

  cv      => region%mixt%cv
  tv      => region%mixt%tv
  tcv     => region%turb%cv
  trhs    => region%turb%rhs
  vort    => region%turb%vort
  wdist   => region%turb%lens
  dsterm  => region%turb%dsterm
  vol     => region%grid%vol

  DO ijkc = ibc,iec
#endif
        vortmag = sqrt( vort(xcoord,ijkc)*vort(xcoord,ijkc) + &
                        vort(ycoord,ijkc)*vort(ycoord,ijkc) + &
                        vort(zcoord,ijkc)*vort(zcoord,ijkc) )

        rnuet  = tcv(cv_sa_nutil,ijkc)
        nuet   = rnuet/cv(cv_mixt_dens,ijkc)
        xi     = rnuet/tv(tv_mixt_muel,ijkc)
        fv1    = xi**3/(xi**3 + cv1**3)
        fv2    = 1._rfreal - xi/(1._rfreal + fv1*xi)
        rwdist = 1._rfreal/wdist(ijkc)
        stilde = vortmag + nuet*rkappa*rkappa*rwdist*rwdist*fv2
        stilde = stilde + real_small 
        ro     = nuet*rkappa*rkappa*rwdist*rwdist/stilde
!        ro     = MIN( ro, 10._RFREAL )
        go     = ro + cw2*(ro**6 - ro)
        fw     = go*((1._rfreal+cw3**6)/(go**6+cw3**6))**one6th

        prod   = cb1*stilde*rnuet
        destr  = cv(cv_mixt_dens,ijkc)*cw1*fw*(nuet*rwdist)**2
        sterm  = destr - prod

        trhs(cv_sa_nutil,ijkc)   = trhs(cv_sa_nutil,ijkc) + vol(ijkc)*sterm
        dsterm(cv_sa_nutil,ijkc) = cb1*(2._rfreal*stilde-vortmag) - &
                                   2._rfreal*cw1*fw*nuet*rwdist*rwdist
#ifdef RFLO
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k
#endif
#ifdef RFLU
  ENDDO       ! ijkC
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_ranssasourceterms

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_RansSASourceTerms.F90,v $
! Revision 1.5  2008/12/06 08:44:42  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:54  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.2  2004/03/20 03:28:29  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.8  2004/01/22 03:57:53  wasistho
! fixed dsterm
!
! Revision 1.7  2003/10/25 22:05:43  wasistho
! deactivated (outcommented) clipping on ro
!
! Revision 1.6  2003/10/21 20:31:13  wasistho
! added dt relaxation in steady flow due to RANS source term
!
! Revision 1.5  2003/10/20 20:28:08  wasistho
! made consistent with compressible SA formulation
!
! Revision 1.4  2003/10/16 20:17:38  wasistho
! installed RaNS in steady state flow (Exp.Mult.Stg)
!
! Revision 1.3  2003/10/14 21:24:54  wasistho
! get minimum of ro and 10.
!
! Revision 1.2  2003/10/07 20:33:46  wasistho
! bug fixed missing nodeOffsets
!
!
!******************************************************************************