TURB_CalcVortic.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute vorticity components at cells.
!
! Description: Velocity gradients at faces first averaged into cells.
!              The resulting cell gradients are then used to compute vorticity
!              components.
!
! Input: region  = data of current region
!
! Output: x,y,z-vorticity, stored in turb%vort(XCOORD:ZCOORD,:)
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_CalcVortic.F90,v 1.7 2009/08/26 12:28:52 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_calcvortic( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE moderror
  USE modparameters
  USE turb_modparameters
#ifdef RFLO
  USE modinterfaces, ONLY : rflo_getdimensdummy, &
                            rflo_getcelloffset, rflo_getnodeoffset
#include "Indexing.h"
#endif
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k, ic, idgr

! ... local variables
  TYPE(t_global), POINTER :: global
  
  INTEGER :: errorflag
  REAL(RFREAL), POINTER :: vort(:,:)

#ifdef RFLO
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff
  INTEGER :: ijkc, ijkn, ijkni, ijknj, ijknk
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  REAL(RFREAL) :: oo6, grvel(gr_mixt_ux:gr_mixt_tz)
  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)
#endif
#ifdef RFLU
  REAL(RFREAL) :: grvel(xcoord:zcoord, grc_mixt_xvel:grc_mixt_zvel)
  REAL(RFREAL), POINTER :: gradc(:,:,:)
#endif

!******************************************************************************

  global => region%global
  CALL registerfunction( global,'TURB_CalcVortic',&
  'TURB_CalcVortic.F90' )

#ifdef RFLO
! get RFLO dimensions, pointers and parameters --------------------------------
  ilev  =  region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  gradi => region%levels(ilev)%mixt%gradi
  gradj => region%levels(ilev)%mixt%gradj
  gradk => region%levels(ilev)%mixt%gradk
  vort  => region%levels(ilev)%turb%vort

  oo6 = 1._rfreal/6._rfreal

! compute vorticities

  DO k = kdcbeg,kdcend
    DO j = jdcbeg,jdcend
      DO i = idcbeg,idcend
        ijkc = indijk(i     ,j     ,k     ,icoff,ijcoff)
        ijkn = indijk(i     ,j     ,k     ,inoff,ijnoff)
        ijkni= indijk(i+1   ,j     ,k     ,inoff,ijnoff)
        ijknj= indijk(i     ,j+1   ,k     ,inoff,ijnoff)
        ijknk= indijk(i     ,j     ,k+1   ,inoff,ijnoff)

        DO idgr = gr_mixt_ux, gr_mixt_tz
          grvel(idgr) = gradi(idgr,ijkn) + gradi(idgr,ijkni) + &
                        gradj(idgr,ijkn) + gradj(idgr,ijknj) + &
                        gradk(idgr,ijkn) + gradk(idgr,ijknk) 
        ENDDO

        vort(xcoord,ijkc) = oo6*(grvel(gr_mixt_wy) - grvel(gr_mixt_vz))
        vort(ycoord,ijkc) = oo6*(grvel(gr_mixt_uz) - grvel(gr_mixt_wx))
        vort(zcoord,ijkc) = oo6*(grvel(gr_mixt_vx) - grvel(gr_mixt_uy))
      ENDDO ! i
    ENDDO   ! j
  ENDDO     ! k
#endif

#ifdef RFLU
! get RFLU dimensions, pointers and parameters --------------------------------

  IF (ASSOCIATED( region%mixt%gradCell ) .eqv. .true.) THEN
    gradc => region%mixt%gradCell
    vort  => region%turb%vort

! - compute vorticities

    DO ic = 1,region%grid%nCellsTot
      vort(xcoord,ic) = gradc(ycoord,grc_mixt_zvel,ic) - &
                        gradc(zcoord,grc_mixt_yvel,ic)
      vort(ycoord,ic) = gradc(zcoord,grc_mixt_xvel,ic) - &
                        gradc(xcoord,grc_mixt_zvel,ic)
      vort(zcoord,ic) = gradc(xcoord,grc_mixt_yvel,ic) - &
                        gradc(ycoord,grc_mixt_xvel,ic)
    ENDDO ! ic
  ENDIF   ! gradCell allocated?
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_calcvortic

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_CalcVortic.F90,v $
! Revision 1.7  2009/08/26 12:28:52  mtcampbe
! Ported to Hera.   Fixed logical expression syntax errors.  Replaced all
! IF (logical_variable)  with IF (logical_variable .eqv. .true.) as
! consistent with the specification.  Also changed: IF( ASSOCIATED(expr) )
! to IF ( ASSOCIATED(expr) .eqv. .true. ).   Intel compilers produce code
! which silently fails for some mal-formed expressions, so these changes
! are a net which should ensure that they are evaluated as intended.
!
! Revision 1.6  2008/12/06 08:44:41  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:53  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/03/16 01:04:49  wasistho
! compute RFLU vorticity only if gradCell allocated
!
! Revision 1.3  2004/03/27 02:16:42  wasistho
! compiled with Rocflu
!
! Revision 1.2  2004/03/19 02:45:02  wasistho
! prepared for RFLU
!
! Revision 1.1  2004/03/05 04:37:00  wasistho
! changed nomenclature
!
! Revision 1.2  2004/02/12 22:16:55  wasistho
! changed RFLO_GetDimensPhys to RFLO_GetDimensDummy
!
! Revision 1.1  2003/08/06 15:58:41  wasistho
! added vorticities computation
!
!
!
!******************************************************************************