TURB_floExtrapolCellVec.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Extrapolate vector variable defined at cells to outer dummy cells.
!
! Description: The values are already available up to first dummy cells.
!              Here the values are extrapolated to second up to nDum cells.
!
! Input: region  = data of current region
!        idBeg,idEnd = begin and end variable index of the vector variable
!        fVec        = vector variable to be extrapolated
!
! Output: fVec = values of fVec at the remaining dummy cells are defined.
!
! Notes: This routine is used by LesUniFiltCC and LesGenFiltCC.
!
!******************************************************************************
!
! $Id: TURB_floExtrapolCellVec.F90,v 1.4 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floextrapolcellvec( region,idBeg,idEnd,fVec )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummy,rflo_getcelloffset
  USE modturbulence
  USE moderror
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region)        :: region
  INTEGER               :: idbeg,idend
  REAL(RFREAL), POINTER :: fvec(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, m, ijkc, ijkc0, ijkc1, ijkc2
  INTEGER :: indxc, indxc0, indxc1, indxc2

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ibeg,iend,jbeg,jend,kbeg,kend
  INTEGER :: idcbeg,idcend,jdcbeg,jdcend,kdcbeg,kdcend
  INTEGER :: ilev,icoff,ijcoff,ndum,nadd,sign(2),indx(2)
  INTEGER :: idum

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floExtrapolCellVec.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloExtrapolCellVec',&
  'TURB_floExtrapolCellVec.F90' )

! get indices ---------------------------------------------------------------

  sign(1)= 1
  sign(2)=-1
  ndum   = region%nDumCells
  nadd   = -ndum
  ilev   = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  ibeg = idcbeg
  iend = idcend
  jbeg = jdcbeg
  jend = jdcend
  kbeg = kdcbeg
  kend = kdcend

! extrapolation to outerst layers, first in I direction

  indx(1)=ibeg
  indx(2)=iend
  DO m=1,2
    DO idum=2,ndum 
      indxc2 = indx(m)-sign(m)*(nadd-idum+1)
      indxc1 = indx(m)-sign(m)*nadd 
      indxc0 = indx(m)-sign(m)*nadd-sign(m)
      indxc  = indx(m)-sign(m)*(nadd+idum)
      DO k=kbeg,kend
        DO j=jbeg,jend
          ijkc  = indijk(indxc   ,j  ,k  ,icoff,ijcoff)
          ijkc0 = ijkc + indxc0-indxc
          ijkc1 = ijkc + indxc1-indxc
          ijkc2 = ijkc + indxc2-indxc

          DO l=idbeg,idend
            fvec(l,ijkc)=fvec(l,ijkc0)+fvec(l,ijkc1)-fvec(l,ijkc2) 
          ENDDO ! l
        ENDDO   ! j
      ENDDO     ! k
    ENDDO       ! iDum
  ENDDO         ! m

! then in J direction

  indx(1)=jbeg
  indx(2)=jend
  DO m=1,2
    DO idum=2,ndum 
      indxc2 = indx(m)-sign(m)*(nadd-idum+1)
      indxc1 = indx(m)-sign(m)*nadd 
      indxc0 = indx(m)-sign(m)*nadd-sign(m)
      indxc  = indx(m)-sign(m)*(nadd+idum)
      DO k=kbeg,kend
        DO i=ibeg,iend
          ijkc  = indijk(i  ,indxc   ,k  ,icoff,ijcoff)
          ijkc0 = ijkc + (indxc0-indxc)*icoff
          ijkc1 = ijkc + (indxc1-indxc)*icoff
          ijkc2 = ijkc + (indxc2-indxc)*icoff

          DO l=idbeg,idend
            fvec(l,ijkc)=fvec(l,ijkc0)+fvec(l,ijkc1)-fvec(l,ijkc2) 
          ENDDO ! l
        ENDDO   ! i
      ENDDO     ! k
    ENDDO       ! iDum
  ENDDO         ! m

! then in K direction

  indx(1)=kbeg
  indx(2)=kend
  DO m=1,2
    DO idum=2,ndum 
      indxc2 = indx(m)-sign(m)*(nadd-idum+1)
      indxc1 = indx(m)-sign(m)*nadd 
      indxc0 = indx(m)-sign(m)*nadd-sign(m)
      indxc  = indx(m)-sign(m)*(nadd+idum)
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkc  = indijk(i  ,j  ,indxc   ,icoff,ijcoff)
          ijkc0 = ijkc + (indxc0-indxc)*ijcoff
          ijkc1 = ijkc + (indxc1-indxc)*ijcoff
          ijkc2 = ijkc + (indxc2-indxc)*ijcoff

          DO l=idbeg,idend
            fvec(l,ijkc)=fvec(l,ijkc0)+fvec(l,ijkc1)-fvec(l,ijkc2) 
          ENDDO ! l
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! iDum
  ENDDO         ! m

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_floextrapolcellvec

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floExtrapolCellVec.F90,v $
! Revision 1.4  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!
!******************************************************************************