RVAV_ReadFileStream1.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: read File for Stream 1 Data.
!
! Description: none.
!
! Input:
!
! Output: Memory location with data for Stream 1
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RVAV_ReadFileStream1.F90,v 1.4 2008/12/06 08:45:08 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rvav_readfilestream1 ( regionsS1 )

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modgrid, ONLY       : t_grid
  USE modmixture, ONLY    : t_mixt
  USE modinterfaces, ONLY : rflo_readregiontopology, rflo_initinputvalues, &
        readinputfile, rflo_derivedinputvalues, rflo_getdimensdummynodes, &
        rflo_getdimensdummy, rflo_getnodeoffset, rflo_getcelloffset, &
        rflo_readgridregion, rflo_readsolutionregion, mixtureproperties
  USE modmpi
  USE modparameters
  USE rvav_modparameters
  USE rvav_modglobal
  USE rvav_moddatastruct
  IMPLICIT NONE

#include "Indexing.h"

! ... parameter
  TYPE (t_region), POINTER :: regionss1(:)

! ... loop variables
  INTEGER :: ireg, ilev
  INTEGER :: i, j, k, ijkn0

! ... local variables
  CHARACTER(CHRLEN) :: msg

  INTEGER :: ipc, jpc, kpc, ibc, iec, ibn, ien
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: idnbeg, idnend, jdnbeg, jdnend, kdnbeg, kdnend
  INTEGER :: icoff, ijcoff, inoff, ijnoff, errorflag

  REAL(RFREAL), DIMENSION(3) :: xyzmin, xyzmax
  REAL(RFREAL), DIMENSION(5) :: cvmin , cvmax

  TYPE(t_grid),   POINTER  :: grid
  TYPE(t_mixt),   POINTER  :: mixt
  TYPE(t_global), POINTER  :: global

!******************************************************************************

  global => regionss1(1)%global

  CALL registerfunction( global, 'RVAV_ReadFileStream1',&
  'RVAV_ReadFileStream1.F90' )

! load case name

  globalrvav%casename = trim(global%casename)

! modify all global data pertinent to Rocflo for code reuse

  global%casename = trim(globalrvav%casename)//'_s1'

  global%flowType    = globalrvav%flowTypeS1
  global%gridFormat  = globalrvav%gridFormatS1
  global%solutFormat = globalrvav%solutFormatS1

  IF ( global%verbLevel/=verbose_none ) THEN
    WRITE(stdout,'(/,A,I5)')'FileTypeS1    = ', globalrvav%fileTypeS1
    WRITE(stdout,'(A,I5)')'FlowTypeS1    = ', globalrvav%flowTypeS1
    WRITE(stdout,'(A,I5)')'gridFormatS1  = ', globalrvav%gridFormatS1
    WRITE(stdout,'(A,I5)')'solutFormatS1 = ', globalrvav%solutFormatS1
  END IF ! verbLevel

  IF ( globalrvav%fileTypeS1 == file_computed ) THEN

! loop over regions -----------------------------------------------------------

    IF ( global%verbLevel/=verbose_none ) &
      WRITE(stdout,'(/,A)') 'Reading grid and solution from Stream1 ...'

    DO ireg=1,global%nRegions

      IF (global%verbLevel /= verbose_none) THEN
        WRITE(stdout,'(A,I5.5)') '  - region ',ireg
        WRITE(stdout,'(A,I5.5)') '     global_startLevel ',global%startLevel
      ENDIF

      ilev =  regionss1(ireg)%currLevel
      grid => regionss1(ireg)%levels(ilev)%grid
      mixt => regionss1(ireg)%levels(ilev)%mixt

! --- allocate memory

      CALL rflo_getdimensdummy( regionss1(ireg),ilev,idcbeg,idcend, &
                                jdcbeg,jdcend,kdcbeg,kdcend )
      CALL rflo_getcelloffset( regionss1(ireg),ilev,icoff,ijcoff )
      ibc = indijk(idcbeg,jdcbeg,kdcbeg,icoff,ijcoff)
      iec = indijk(idcend,jdcend,kdcend,icoff,ijcoff)

      CALL rflo_getdimensdummynodes( regionss1(ireg),ilev,idnbeg,idnend, &
                                     jdnbeg,jdnend,kdnbeg,kdnend )
      CALL rflo_getnodeoffset( regionss1(ireg),ilev,inoff,ijnoff )
      ibn = indijk(idnbeg,jdnbeg,kdnbeg,inoff,ijnoff)
      ien = indijk(idnend,jdnend,kdnend,inoff,ijnoff)

      globalrvav%iCOffS1  = icoff
      globalrvav%ijCOffS1 = ijcoff

      ALLOCATE( grid%xyz(3,ibn:ien),stat=errorflag )
      IF (regionss1(ireg)%mixtInput%moveGrid) THEN
        ALLOCATE( grid%siVel(ibn:ien),stat=errorflag )
        ALLOCATE( grid%sjVel(ibn:ien),stat=errorflag )
        ALLOCATE( grid%skVel(ibn:ien),stat=errorflag )
      ENDIF
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )

      ALLOCATE( mixt%cv(5,ibc:iec) ,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )

      ALLOCATE( mixt%dv(mixt%nDv,ibc:iec),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )

      IF (regionss1(ireg)%mixtInput%computeTv) THEN
        ALLOCATE( mixt%tv(mixt%nTv,ibc:iec),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )
      ENDIF

      IF (regionss1(ireg)%mixtInput%gasModel == gas_model_tcperf) THEN
        ALLOCATE( mixt%gv(mixt%nGv,0:1),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )
      ELSE
        ALLOCATE( mixt%gv(mixt%nGv,ibc:iec),stat=errorflag )
        global%error = errorflag
        IF (global%error /= 0) CALL errorstop( global, err_allocate,__line__ )
      ENDIF

! --- initialize variables

      grid%xyz = 0.0_rfreal
      mixt%cv  = 0.0_rfreal

! --- read grid

      CALL rflo_readgridregion( ireg,regionss1 )

! --- read solution, calc. mixture properties

      CALL rflo_readsolutionregion( ireg,regionss1 )

      CALL mixtureproperties( regionss1(ireg),ibc,iec,.true. )

! --- write min-max values

      IF (global%verbLevel /= verbose_none) THEN

       WRITE(stdout,'(/,A,2(I10,2X))')'ibn-ien ',ibn,ien
       WRITE(stdout,'(/,A,3(I8,2X))')'idnbeg,jdnbeg,kdnbeg',idnbeg,jdnbeg,kdnbeg
       WRITE(stdout,'(/,A,3(I8,2X))')'idnend,jdnend,kdnend',idnend,jdnend,kdnend

       xyzmin = +1.0e+30_rfreal
       xyzmax = -1.0e+30_rfreal

       DO i=ibn, ien
         xyzmin(1) = min(grid%xyz(1,i), xyzmin(1))
         xyzmin(2) = min(grid%xyz(2,i), xyzmin(2))
         xyzmin(3) = min(grid%xyz(3,i), xyzmin(3))

         xyzmax(1) = max(grid%xyz(1,i), xyzmax(1))
         xyzmax(2) = max(grid%xyz(2,i), xyzmax(2))
         xyzmax(3) = max(grid%xyz(3,i), xyzmax(3))
       ENDDO ! i

       WRITE(stdout,'(/,A,2(E12.5,2X))') 'Min-Max of X     ', xyzmin(1),xyzmax(1)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of Y     ', xyzmin(2),xyzmax(2)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of Z     ', xyzmin(3),xyzmax(3)

       DO k=kdnbeg+3,kdnbeg+3
         DO j=jdnbeg+3,jdnbeg+3
           DO i=idnbeg,idnend
             ijkn0  = indijk(i  ,j,k,inoff,ijnoff)
             WRITE(stdout,'(I5,3X,E12.5)') i,grid%xyz(1,ijkn0)
           ENDDO ! i
         ENDDO   ! j
       ENDDO     ! k

       WRITE(stdout,'(/,A,2(I10,2X))') 'ibc-iec ',ibc,iec
       WRITE(stdout,'(A,3(I8,2X))')   'idcbeg,jdcbeg,kdcbeg',idcbeg,jdcbeg,kdcbeg
       WRITE(stdout,'(A,3(I8,2X))')   'idcend,jdcend,kdcend',idcend,jdcend,kdcend
       WRITE(stdout,'(/,A,2(I8,2X))') 'iCOffS1,ijCOffS1 ',globalrvav%iCOffS1,globalrvav%ijCOffS1

       cvmin = +1.0e+30_rfreal
       cvmax = -1.0e+30_rfreal

       DO i=ibc,iec
         cvmin(1) = min(mixt%cv(1,i), cvmin(1))
         cvmin(2) = min(mixt%cv(2,i), cvmin(2))
         cvmin(3) = min(mixt%cv(3,i), cvmin(3))
         cvmin(4) = min(mixt%cv(4,i), cvmin(4))
         cvmin(5) = min(mixt%cv(5,i), cvmin(5))

         cvmax(1) = max(mixt%cv(1,i), cvmax(1))
         cvmax(2) = max(mixt%cv(2,i), cvmax(2))
         cvmax(3) = max(mixt%cv(3,i), cvmax(3))
         cvmax(4) = max(mixt%cv(4,i), cvmax(4))
         cvmax(5) = max(mixt%cv(5,i), cvmax(5))
       ENDDO ! i

       WRITE(stdout,'(/,A,2(E12.5,2X))') 'Min-Max of CV(1) ', cvmin(1),cvmax(1)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of CV(2) ', cvmin(2),cvmax(2)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of CV(3) ', cvmin(3),cvmax(3)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of CV(4) ', cvmin(4),cvmax(4)
       WRITE(stdout,'(A,2(E12.5,2X))')   'Min-Max of CV(5) ', cvmin(5),cvmax(5)

      ENDIF ! verbLevel

    ENDDO   ! iReg

  ELSE

    WRITE(*,'(/,A,/)') 'Current Data Structure for Stream 1 Only supports Computed Results.'
    stop

  ENDIF     ! fileTypes1

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rvav_readfilestream1

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RVAV_ReadFileStream1.F90,v $
! Revision 1.4  2008/12/06 08:45:08  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:18:19  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/10/31 21:09:39  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/12/01 22:43:26  fnajjar
! Initial revision after changing case
!
! Revision 1.12  2004/03/03 23:55:42  jferry
! Allowed particles to be run with Euler case
!
! Revision 1.11  2003/11/20 16:40:41  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.7  2003/05/15 02:57:08  jblazek
! Inlined index function.
!
! Revision 1.6  2002/10/12 03:20:51  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.5  2002/09/10 00:01:45  f-najjar
! Variable global moved into regions()
!
! Revision 1.4  2002/08/30 01:47:58  jblazek
! Added support for moving grids.
!
! Revision 1.3  2002/08/16 21:33:48  jblazek
! Changed interface to MixtureProperties.
!
! Revision 1.2  2002/06/15 17:43:28  f-najjar
! Grid & Solution for all regions in one file
!
! Revision 1.1.1.1  2002/06/03 21:41:29  f-najjar
! Initial Import of RocVaV
!
!******************************************************************************