RFLU_PutBoundaryValuesAlpha.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Put outgoing data into buffers for GENX.
!
! Description: None.
!
! Input: 
!   region      Dimensions of patches, types of BCs, flow variables
!
! Output: None.
!
! Notes: 
!   1. The normal depends also on the fractional time alpha, but Rocflu does 
!      not move the mesh inside the Runge-Kutta stages, so copying the normal
!      vector here is not necessary.
!
! ******************************************************************************
!
! $Id: RFLU_PutBoundaryValuesAlpha.F90,v 1.17 2008/12/06 08:44:01 mtcampbe Exp $
!
! Copyright: (c) 2002-2004 by the University of Illinois
!
! ******************************************************************************

SUBROUTINE rflu_putboundaryvaluesalpha(region)

  USE moddatatypes
  USE moderror
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moddatastruct, ONLY: t_region
  USE modparameters
  USE modmpi  

  USE rflu_modgridspeedutils, ONLY: rflu_descalegridspeed
  USE rflu_modrindstates, ONLY: rflu_setrindstateinjectperf
  
  IMPLICIT NONE

! *****************************************************************************
! Definitions and declarations
! *****************************************************************************

! =============================================================================
! Arguments
! =============================================================================

  TYPE(t_region), TARGET :: region
  LOGICAL :: initialize

! =============================================================================
! Locals
! =============================================================================

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: c1,distrib,gasmodel,ifl,indcp,indgs,indmol,ipatch
  REAL(RFREAL) :: cp,dummyreal,fs,fsu,minj,mm,nx,ny,nz,pl,rl,tinj
  REAL(RFREAL), DIMENSION(:,:), POINTER :: pcv,pdv,pgv,pmixtvals
  TYPE(t_global), POINTER :: global
  TYPE(t_grid), POINTER :: pgrid
  TYPE(t_patch), POINTER :: ppatch
  TYPE(t_region), POINTER :: pregion

! *****************************************************************************
! Start
! *****************************************************************************

  rcsidentstring = & 
   '$RCSfile: RFLU_PutBoundaryValuesAlpha.F90,v $ $Revision: 1.17 $'

  global => region%global

  CALL registerfunction(global,'RFLU_PutBoundaryValuesAlpha',&
  'RFLU_PutBoundaryValuesAlpha.F90')

! *****************************************************************************
! Set pointers
! *****************************************************************************

  pregion => region
  pgrid   => pregion%grid
  pcv     => pregion%mixt%cv
  pdv     => pregion%mixt%dv
  pgv     => pregion%mixt%gv

  indgs    = region%grid%indGs
  indcp    = region%mixtInput%indCp
  indmol   = region%mixtInput%indMol
  gasmodel = region%mixtInput%gasModel

! *****************************************************************************
! Loop over ALL interacting boundaries 
! *****************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A,1X,I3)') solver_name,'Putting alpha-dependent '// & 
                                   'values into GENX buffers...'
  END IF ! global%myProcid

  DO ipatch=1,pgrid%nPatches
    ppatch => region%patches(ipatch)

    distrib = ppatch%mixt%distrib

    IF ( global%myProcid == masterproc .AND. & 
         global%checkLevel == check_high .AND. & 
         global%verbLevel >= verbose_high ) THEN 
      IF ( ppatch%bcCoupled == bc_not_coupled ) THEN
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(not interacting)'
      ELSE IF ( ppatch%bcCoupled == bc_not_burning ) THEN 
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(interacting)'      
      ELSE IF ( ppatch%bcCoupled == bc_burning ) THEN
        WRITE(stdout,'(A,3X,A,1X,I3,1X,A)') solver_name,'Patch:',ipatch, & 
                                            '(interacting and burning)'          
      END IF ! pPatch%bcCoupled                 
    END IF ! global%myProcid 

! =============================================================================
!   Outgoing data (initialized in RFLU_InitGENXInterface)
! =============================================================================

! -----------------------------------------------------------------------------
!   Interacting non-burning boundary
! -----------------------------------------------------------------------------

    IF ( ppatch%bcCoupled == bc_not_burning ) THEN
      DO ifl = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifl)

        ppatch%rhofAlp(ifl) = pcv(cv_mixt_dens,c1)  
        
        ppatch%nfAlp(xcoord,ifl) = ppatch%fn(xcoord,ifl)
        ppatch%nfAlp(ycoord,ifl) = ppatch%fn(ycoord,ifl)
        ppatch%nfAlp(zcoord,ifl) = ppatch%fn(zcoord,ifl)          
      END DO ! ifl 

      DO ifl = ppatch%nBFaces+1,ppatch%nBFacesTot
        ppatch%rhofAlp(ifl) = REAL(crazy_value_int,kind=rfreal)
        
        ppatch%nfAlp(xcoord,ifl) = REAL(crazy_value_int,kind=rfreal)
        ppatch%nfAlp(ycoord,ifl) = REAL(crazy_value_int,kind=rfreal)
        ppatch%nfAlp(zcoord,ifl) = REAL(crazy_value_int,kind=rfreal)
      END DO ! ifl 

      IF ( global%myProcid == masterproc .AND. & 
           global%checkLevel == check_high .AND. & 
           global%verbLevel >= verbose_high ) THEN 
        IF ( ppatch%nBFaces > 0 .AND. global%verbLevel >= verbose_high) THEN
          WRITE(stdout,'(A,5X,A)') solver_name,'Minimum/maximum values:'     
          WRITE(stdout,'(A,7X,A,2(1X,E15.8))') solver_name,'rhofAlp: ', & 
                minval(ppatch%rhofAlp(1:ppatch%nBFaces)), & 
                maxval(ppatch%rhofAlp(1:ppatch%nBFaces))
        END IF ! pPatch%nBFaces
      END IF ! global%myProcid
    END IF ! pPatch%bcCoupled

! -----------------------------------------------------------------------------
!   Interacting burning boundary - NOTE call to BcondInjectionPerf only done to
!   set rhofAlp, other quantities are not used or set, hence set rhoVrel to
!   crazy values and use dummyRealOut
! -----------------------------------------------------------------------------

    IF ( ppatch%bcCoupled == bc_burning ) THEN
      pmixtvals => ppatch%mixt%vals

      DO ifl = 1,ppatch%nBFaces
        c1 = ppatch%bf2c(ifl)

        nx = ppatch%fn(xcoord,ifl)
        ny = ppatch%fn(ycoord,ifl)
        nz = ppatch%fn(zcoord,ifl)        
        
        fs  = ppatch%gs(indgs*ifl)
        fsu = rflu_descalegridspeed(pregion,fs)
                
        IF ( gasmodel == gas_model_tcperf ) THEN
          cp = pgv(gv_mixt_cp ,indcp *c1)
          mm = pgv(gv_mixt_mol,indmol*c1)

          minj = pmixtvals(bcdat_inject_mfrate,distrib*ifl)
        
          IF ( minj > 0.0_rfreal ) THEN ! Surface burning
            tinj = pmixtvals(bcdat_inject_temp,distrib*ifl)

            pl = pdv(dv_mixt_pres,c1)

            CALL rflu_setrindstateinjectperf(cp,mm,nx,ny,nz,minj,tinj,pl, &
                                             fsu,rl,dummyreal,dummyreal, &
                                             dummyreal,dummyreal)                                                                            
          ELSE ! Surface NOT burning
            rl = pcv(cv_mixt_dens,c1)                                                        
          END IF ! minj
        ELSE 
          CALL errorstop(global,err_reached_default,__line__)
        END IF ! gasModel

        ppatch%rhofAlp(ifl) = rl
        
        ppatch%nfAlp(xcoord,ifl) = nx
        ppatch%nfAlp(ycoord,ifl) = ny
        ppatch%nfAlp(zcoord,ifl) = nz         
      END DO ! ifl 

      DO ifl = ppatch%nBFaces+1,ppatch%nBFacesTot
        ppatch%rhofAlp(ifl) = REAL(crazy_value_int,kind=rfreal)
        
        ppatch%nfAlp(xcoord,ifl) = REAL(crazy_value_int,kind=rfreal)
        ppatch%nfAlp(ycoord,ifl) = REAL(crazy_value_int,kind=rfreal)
        ppatch%nfAlp(zcoord,ifl) = REAL(crazy_value_int,kind=rfreal)
      END DO ! ifl

      IF ( global%myProcid == masterproc .AND. & 
           global%checkLevel == check_high .AND. & 
           global%verbLevel >= verbose_high ) THEN 
        IF ( ppatch%nBFaces > 0 .AND. global%verbLevel >= verbose_high) THEN
          WRITE(stdout,'(A,5X,A)') solver_name,'Minimum/maximum values:'     
          WRITE(stdout,'(A,7X,A,2(1X,E15.8))') solver_name,'rhofAlp: ', & 
                minval(ppatch%rhofAlp(1:ppatch%nBFaces)), & 
                maxval(ppatch%rhofAlp(1:ppatch%nBFaces))                                
        END IF ! pPatch%nBFaces
      END IF ! global%myProcid     
    END IF ! pPatch%bcCoupled    
  END DO ! iPatch

! *****************************************************************************
! End
! *****************************************************************************

  IF ( global%myProcid == masterproc .AND. & 
       global%verbLevel >= verbose_high ) THEN 
    WRITE(stdout,'(A,1X,A,1X,I3)') solver_name,'Putting alpha-dependent '// & 
                                   'values into GENX buffers done.'
  END IF ! global%myProcid

  CALL deregisterfunction(global)

END SUBROUTINE rflu_putboundaryvaluesalpha

! *****************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_PutBoundaryValuesAlpha.F90,v $
! Revision 1.17  2008/12/06 08:44:01  mtcampbe
! Updated license.
!
! Revision 1.16  2008/11/19 22:17:15  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.15  2006/08/19 15:37:56  mparmar
! Renamed patch variables
!
! Revision 1.14  2005/10/31 21:09:33  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.13  2004/10/19 19:35:59  haselbac
! Changed setting of quantities on burning boundaries, cosmetics
!
! Revision 1.12  2004/08/13 22:35:03  haselbac
! Bug fix: pMixtVals only set for burning patches
!
! Revision 1.11  2003/09/04 20:19:36  haselbac
! Removed temporary fix for Rocburn problem in GENx
!
! Revision 1.10  2003/08/23 21:41:31  haselbac
! Fixed comment
!
! Revision 1.9  2003/08/22 20:31:55  haselbac
! Added temporary fix for ignition problems
!
! Revision 1.8  2003/08/20 02:09:58  haselbac
! Changed verbosity conditions to reduce solver output in GENx runs
!
! Revision 1.7  2003/05/13 23:44:30  haselbac
! Added init of dummy faces
!
! Revision 1.6  2003/04/12 21:34:12  haselbac
! Made parallel: Added MASTERPROC checks
!
! Revision 1.5  2003/03/05 20:37:16  jiao
! ACH: Changed call to BcondInjectionPerf, see comment
!
! Revision 1.4  2003/02/24 23:42:40  haselbac
! Added setting of nfAlp at request of Jim for PC iterations
!
! Revision 1.3  2003/01/28 18:27:30  haselbac
! Cosmetics only
!
! Revision 1.2  2002/11/27 20:23:30  haselbac
! Fixed bug in setting of variables on burning boundaries
!
! Revision 1.1  2002/10/12 19:06:13  haselbac
! Initial revision
!
! *****************************************************************************