RFLU_ModRindStates.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of routines for setting rind states.
!
! Description: None
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModRindStates.F90,v 1.6 2008/12/06 08:44:24 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modrindstates

  USE moddatatypes
  USE modparameters
  USE modglobal, ONLY: t_global

  USE modinterfaces, ONLY: mixtperf_c_dgp, &
                           mixtperf_c_grt, &  
                           mixtperf_d_prt, & 
                           mixtperf_eo_dgpuvw, &
                           mixtperf_eo_dgpvm, &  
                           mixtperf_ho_cptuvw, & 
                           mixtperf_g_cpr, &                           
                           mixtperf_p_deogvm2, &
                           mixtperf_r_m 

  IMPLICIT NONE
    
! ******************************************************************************
! Declarations and definitions
! ******************************************************************************  

! ==============================================================================  
! Procedures
! ==============================================================================  

  PUBLIC :: rflu_setrindstatefarfieldperf, & 
            rflu_setrindstateslipwallperf, & 
            rflu_setrindstateinjectperf

! ==============================================================================  
! Data
! ==============================================================================  

  CHARACTER(CHRLEN), PRIVATE :: & 
    RCSIdentString = '$RCSfile: RFLU_ModRindStates.F90,v $ $Revision: 1.6 $'        
       
! ******************************************************************************
! Procedures
! ******************************************************************************
                
  CONTAINS
  







! ******************************************************************************
!
! Purpose: Set rind state for farfield boundaries and perfect gas.
!
! Description: None.
!
! Input:
!   global      Pointer to global data
!   cpGas       Specific heat at constant pressure
!   mmGas       Molecular mass
!   nx,ny,nz    Components of unit normal vector
!   machInf     Mach number at infinity
!   pInf        Pressure at infinity
!   tInf        Temperature at infinity
!   alphaInf    Angle of attack
!   betaInf     Sideslip angle
!   corrFlag    Flag for vortex-correction
!   liftCoef    Lift coefficient
!   xc          x-coordinate 
!   yc          y-coordinate
!   zc          z-coordinate
!   rl          Density at boundary
!   rul         x-momentum component at boundary
!   rvl         y-momentum component at boundary
!   rwl         z-momentum component at boundary
!   rel         Total internal energy at boundary
!
! Output: 
!   rr          Density 
!   rur         x-momentum component 
!   rvr         y-momentum component 
!   rwr         z-momentum component 
!   rer         Total internal energy 
!   pr          Pressure 
!
! Notes: 
!   1. Valid only for thermally and calorically perfect gas.
!   2. Valid only for two-dimensional flows.
!
! ******************************************************************************

  SUBROUTINE rflu_setrindstatefarfieldperf(global,cpGas,mmGas,nx,ny,nz, &
                                           machinf,pinf,tinf,alphainf, &
                                           betainf,corrflag,liftcoef,xc,yc, &
                                           zc,rl,rul,rvl,rwl,rel,rr,rur,rvr, &
                                           rwr,rer,pr)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    LOGICAL, INTENT(IN) :: corrflag
    REAL(RFREAL), INTENT(IN) :: alphainf,betainf,cpgas,liftcoef,machinf, &
                                mmgas,nx,ny,nz,pinf,rl,rel,rul,rvl,rwl, & 
                                tinf,xc,yc,zc
    REAL(RFREAL), INTENT(OUT) :: pr,rer,rr,rur,rvr,rwr 
    TYPE(t_global), POINTER :: global

! ==============================================================================  
!   Locals 
! ==============================================================================  

    REAL(RFREAL) :: al,corr,corrterm,denom,dist,dq2,dx,dy,el,ggas,gm1og, & 
                    gogm1,ggasterm3,numer,pb,pi,pl,qi,ql,rb,rgas,ri,sl2, &
                    term,theta,ub,ui,ul,vb,vi,vl,wb,wi,wl    

! ******************************************************************************
!   Compute gas properties
! ******************************************************************************

    rgas = mixtperf_r_m(mmgas)
    ggas = mixtperf_g_cpr(cpgas,rgas)
          
    gm1og = (ggas-1.0_rfreal)/ggas
    gogm1 = 1.0_rfreal/gm1og  
          
    corrterm = global%forceRefLength/(4.0_rfreal*global%pi)
          
! ******************************************************************************
!   Interior state at boundary
! ******************************************************************************
        
    ul = rul/rl
    vl = rvl/rl
    wl = rwl/rl
    ql = ul*nx + vl*ny + wl*nz
 
    el  = rel/rl   
    sl2 = ul*ul + vl*vl + wl*wl
    pl  = mixtperf_p_deogvm2(rl,el,ggas,sl2)
          
! ******************************************************************************
!   Compute state at infinity without vortex correction
! ******************************************************************************
 
    ri = mixtperf_d_prt(pinf,rgas,tinf)
    pi = pinf    
    
    qi = machinf*mixtperf_c_grt(ggas,rgas,tinf)
    ui = qi*cos(alphainf)*cos(betainf)
    vi = qi*sin(alphainf)*cos(betainf)
    wi = qi*              sin(betainf)    

! ******************************************************************************
!   Compute state at infinity with vortex correction. NOTE the correction is 
!   assumed to be two-dimensional and the aerofoil center of pressure is assumed
!   to be located at (x,y) = (0.25,0.0).
! ******************************************************************************
 
    IF ( corrflag .EQV. .true. ) THEN 
      dx = xc - 0.25_rfreal
      dy = yc
      
      dist  = sqrt(dx**2 + dy**2)
      theta = atan2(dy,dx)
      
      numer = liftcoef*qi*sqrt(1.0_rfreal-machinf**2)
      denom = dist*(1.0_rfreal - (machinf*sin(theta-alphainf))**2)
      corr  = corrterm*numer/denom
      
      ui = ui + corr*sin(theta)
      vi = vi - corr*cos(theta)
            
      dq2 = qi*qi - (ui*ui + vi*vi)            
      pi  = (pi**gm1og + 0.5_rfreal*gm1og*ri/pi**(1.0_rfreal/ggas)*dq2)**gogm1         
      ri  = ri*(pi/pinf)**ggas
    END IF ! corrFlag

! ******************************************************************************
!   Compute right state at boundary
! ******************************************************************************

! ==============================================================================  
!   Subsonic flow
! ==============================================================================  
   
    IF ( machinf < 1.0_rfreal ) THEN
      al = mixtperf_c_dgp(rl,ggas,pl)

! ------------------------------------------------------------------------------
!     Subsonic inflow
! ------------------------------------------------------------------------------

      IF ( ql < 0.0_rfreal ) THEN
        pb = 0.5_rfreal*(pi+pl-rl*al*((ui-ul)*nx+(vi-vl)*ny+(wi-wl)*nz))

        rb = ri -    (pi - pb)/(al*al)        
        ub = ui - nx*(pi - pb)/(rl*al)
        vb = vi - ny*(pi - pb)/(rl*al)
        wb = wi - nz*(pi - pb)/(rl*al)

! ------------------------------------------------------------------------------
!     Subsonic outflow
! ------------------------------------------------------------------------------

      ELSE
        pb = pi
      
        rb = rl -    (pl-pi)/(al*al)
        ub = ul + nx*(pl-pi)/(rl*al)
        vb = vl + ny*(pl-pi)/(rl*al)
        wb = wl + nz*(pl-pi)/(rl*al)
      END IF ! ql

      rr  = rb
      rur = rb*ub
      rvr = rb*vb
      rwr = rb*wb
      rer = rb*mixtperf_eo_dgpuvw(rb,ggas,pb,ub,vb,wb)
      pr  = pb

! ==============================================================================  
!   Supersonic flow
! ==============================================================================  

    ELSE

! ------------------------------------------------------------------------------
!     Supersonic inflow
! ------------------------------------------------------------------------------

      IF ( ql < 0.0_rfreal ) THEN
        rr  = ri
        rur = ri*ui
        rvr = ri*vi
        rwr = ri*wi
        rer = ri*mixtperf_eo_dgpvm(ri,ggas,pi,qi)
        pr  = pi

! ------------------------------------------------------------------------------
!     Supersonic outflow
! ------------------------------------------------------------------------------

      ELSE
        rr  = rl
        rur = rul
        rvr = rvl
        rwr = rwl
        rer = rel
        pr  = pl
      END IF ! ql
    END IF ! machInf
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_setrindstatefarfieldperf











! ******************************************************************************
!
! Purpose: Set rind state for injection boundaries and perfect gas.
!
! Description: None.
!
! Input:
!   cpGas       Specific heat at constant pressure
!   mmGas       Molecular mass
!   nx,ny,nz    Components of unit normal vector
!   mInj        Injection mass flux
!   tInj        Injection temperature
!   pl          Pressure
!   fs          Grid speed
!
! Output: 
!   rl          Density
!   ul          x-velocity component
!   vl          y-velocity component
!   wl          z-velocity component
!   Hl          Stagnation enthalpy per unit mass
!
! Notes: 
!   1. Valid only for thermally and calorically perfect gas.
!
! ******************************************************************************

  SUBROUTINE rflu_setrindstateinjectperf(cpGas,mmGas,nx,ny,nz,mInj,tInj,pl, &
                                         fs,rl,ul,vl,wl,hl)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    REAL(RFREAL), INTENT(IN) :: cpgas,fs,minj,mmgas,nx,ny,nz,pl,tinj
    REAL(RFREAL), INTENT(OUT) :: hl,rl,ul,vl,wl 

! ==============================================================================  
!   Locals 
! ==============================================================================  

    REAL(RFREAL) :: ggas,ql,rgas    
          
! ******************************************************************************
!   Compute wall pressure
! ******************************************************************************

    rgas = mixtperf_r_m(mmgas)
    ggas = mixtperf_g_cpr(cpgas,rgas)
 
    rl = mixtperf_d_prt(pl,rgas,tinj)
 
    ql = -minj/rl + fs
    ul = ql*nx
    vl = ql*ny
    wl = ql*nz
     
    hl = mixtperf_ho_cptuvw(cpgas,tinj,ul,vl,wl)
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_setrindstateinjectperf








! ******************************************************************************
!
! Purpose: Set rind state for slip-wall boundaries and perfect gas.
!
! Description: None.
!
! Input:
!   cpGas       Specific heat at constant pressure
!   mmGas       Molecular mass
!   nx,ny,nz    Components of unit normal vector
!   rl          Density
!   rul         x-momentum component
!   rvl         y-momentum component
!   rwl         z-momentum component
!   fs          Grid speed
!   pl          Pressure
!
! Output: 
!   pl          Pressure
!
! Notes: 
!   1. Valid only for thermally and calorically perfect gas.
!
! ******************************************************************************

  SUBROUTINE rflu_setrindstateslipwallperf(cpGas,mmGas,nx,ny,nz,rl,rul,rvl, &
                                           rwl,fs,pl)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    REAL(RFREAL), INTENT(IN) :: cpgas,fs,mmgas,nx,ny,nz,rl,rul,rvl,rwl
    REAL(RFREAL), INTENT(INOUT) :: pl

! ==============================================================================  
!   Locals 
! ==============================================================================  

    REAL(RFREAL) :: al,ggas,irl,ql,rgas,term,ul,vl,wl    
          
! ******************************************************************************
!   Compute wall pressure
! ******************************************************************************

    rgas = mixtperf_r_m(mmgas)
    ggas = mixtperf_g_cpr(cpgas,rgas)
 
    irl = 1.0_rfreal/rl          
    ul  = irl*rul
    vl  = irl*rvl
    wl  = irl*rwl 
    ql  = ul*nx + vl*ny + wl*nz - fs
 
    al  = mixtperf_c_dgp(rl,ggas,pl)

    IF ( ql < 0.0_rfreal ) THEN           
      term = 1.0_rfreal + 0.5_rfreal*(ggas-1.0_rfreal)*ql/al          
      pl   = pl*term**(2.0_rfreal*ggas/(ggas-1.0_rfreal))
    ELSE 
      term = (ggas+1.0_rfreal)/4.0_rfreal
      pl   = pl + term*rl*ql*(ql + sqrt(al*al + term*term*ql*ql)/term)
    END IF ! ql
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_setrindstateslipwallperf





END MODULE rflu_modrindstates

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModRindStates.F90,v $
! Revision 1.6  2008/12/06 08:44:24  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:35  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/04/07 15:19:20  haselbac
! Removed tabs
!
! Revision 1.3  2004/12/27 23:29:50  haselbac
! Added setting of rind state for farf bc
!
! Revision 1.2  2004/10/19 19:28:31  haselbac
! Added procedure to set rind state for injecting boundaries
!
! Revision 1.1  2004/04/14 02:05:11  haselbac
! Initial revision
!
! ******************************************************************************