RFLU_ModGridSpeedUtils.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
! ******************************************************************************
!
! Purpose: Collection of utility routines for manipulating grid speeds.
!
! Description: None
!
! Notes: None.
!
! ******************************************************************************
!
! $Id: RFLU_ModGridSpeedUtils.F90,v 1.7 2008/12/06 08:44:22 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
! ******************************************************************************

MODULE rflu_modgridspeedutils

  USE moddatatypes
  USE modparameters
  USE moddatastruct, ONLY: t_region
  USE modglobal, ONLY: t_global
  USE modgrid, ONLY: t_grid
  USE modbndpatch, ONLY: t_patch
  USE moderror

  IMPLICIT NONE
    
  PRIVATE
  PUBLIC :: rflu_decideneedgridspeeds, & 
            rflu_descalegridspeed, &
            rflu_descalegridspeeds, &
            rflu_initgridspeedscalefactor, &
            rflu_scalegridspeed, &
            rflu_scalegridspeeds, &     
            rflu_setgridspeedscalefactor
                
  CONTAINS
  






! ******************************************************************************
!
! Purpose: Decide whether need grid speeds.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  LOGICAL FUNCTION rflu_decideneedgridspeeds(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion
  
! ******************************************************************************
!   Decide whether need grid speeds
! ******************************************************************************

    rflu_decideneedgridspeeds = .false. 
    
    IF ( pregion%mixtInput%moveGrid .EQV. .true. ) THEN 
      rflu_decideneedgridspeeds = .true.
    END IF ! pRegion%mixtInput%moveGrid
 
! ******************************************************************************
!   End
! ******************************************************************************

  END FUNCTION rflu_decideneedgridspeeds









! ******************************************************************************
!
! Purpose: Descale grid speed for single face.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!   fs                  Scaled grid speed
!
! Output: 
!   fs                  Descaled grid speed
!
! Notes: None.
!
! ******************************************************************************

  FUNCTION rflu_descalegridspeed(pRegion,fs)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

    REAL(RFREAL) :: rflu_descalegridspeed

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    REAL(RFREAL), INTENT(INOUT) :: fs
    TYPE(t_region), POINTER :: pregion
  
! ******************************************************************************
!   Scale grid speed
! ******************************************************************************

    rflu_descalegridspeed = fs/pregion%grid%fsScaleFactor
 
! ******************************************************************************
!   End
! ******************************************************************************

  END FUNCTION rflu_descalegridspeed






! ******************************************************************************
!
! Purpose: Descale grid speeds for faces and boundary patches.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_descalegridspeeds(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  

    INTEGER :: ifg,ifl,ipatch
    REAL(RFREAL) :: scalefactor
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! *****************************************************************************
!   Set pointers and variables
! *****************************************************************************

    pgrid => pregion%grid

    scalefactor = 1.0_rfreal/pgrid%fsScaleFactor
  
! ******************************************************************************
!   Scale grid speeds
! ******************************************************************************

    DO ifg = lbound(pgrid%gs,1),ubound(pgrid%gs,1)
      pgrid%gs(ifg) = scalefactor*pgrid%gs(ifg)
    END DO ! ifg
 
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

      DO ifl = lbound(ppatch%gs,1),ubound(ppatch%gs,1)
        ppatch%gs(ifl) = scalefactor*ppatch%gs(ifl)
      END DO ! ifl
    END DO ! iPatch
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_descalegridspeeds






! ******************************************************************************
!
! Purpose: Initialize grid speed scale factor.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: 
!   1. Needed for steady flows without grid motion so that calls to scaling 
!      routines work properly.
!
! ******************************************************************************

  SUBROUTINE rflu_initgridspeedscalefactor(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

          
! ******************************************************************************
!   Initialize scaling factor
! ******************************************************************************

    pregion%grid%fsScaleFactor = 1.0_rfreal
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_initgridspeedscalefactor







! ******************************************************************************
!
! Purpose: Scale grid speed for single face.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!   fs                  Descaled grid speed
!
! Output: 
!   fs                  Scaled grid speed
!
! Notes: None.
!
! ******************************************************************************

  FUNCTION rflu_scalegridspeed(pRegion,fs)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

    REAL(RFREAL) :: rflu_scalegridspeed

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    REAL(RFREAL), INTENT(INOUT) :: fs
    TYPE(t_region), POINTER :: pregion
  
! ******************************************************************************
!   Scale grid speed
! ******************************************************************************

    rflu_scalegridspeed = pregion%grid%fsScaleFactor*fs
 
! ******************************************************************************
!   End
! ******************************************************************************

  END FUNCTION rflu_scalegridspeed






! ******************************************************************************
!
! Purpose: Scale grid speeds for faces and boundary patches.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_scalegridspeeds(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  

    INTEGER :: ifg,ifl,ipatch
    REAL(RFREAL) :: scalefactor
    TYPE(t_grid), POINTER :: pgrid
    TYPE(t_patch), POINTER :: ppatch
    
! *****************************************************************************
!   Set pointers and variables
! *****************************************************************************

    pgrid => pregion%grid

    scalefactor = pgrid%fsScaleFactor
  
! ******************************************************************************
!   Scale grid speeds
! ******************************************************************************

    DO ifg = lbound(pgrid%gs,1),ubound(pgrid%gs,1) 
      pgrid%gs(ifg) = scalefactor*pgrid%gs(ifg)
    END DO ! ifg
 
    DO ipatch = 1,pgrid%nPatches
      ppatch => pregion%patches(ipatch)

      DO ifl = lbound(ppatch%gs,1),ubound(ppatch%gs,1) 
        ppatch%gs(ifl) = scalefactor*ppatch%gs(ifl)
      END DO ! ifl
    END DO ! iPatch
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_scalegridspeeds






! ******************************************************************************
!
! Purpose: Set grid speed scale factor.
!
! Description: None.
!
! Input:
!   pRegion             Pointer to region data
!
! Output: None.
!
! Notes: None.
!
! ******************************************************************************

  SUBROUTINE rflu_setgridspeedscalefactor(pRegion)
 
    IMPLICIT NONE

! ******************************************************************************
!   Declarations and definitions
! ******************************************************************************

! ==============================================================================  
!   Arguments 
! ==============================================================================  

    TYPE(t_region), POINTER :: pregion

! ==============================================================================  
!   Locals 
! ==============================================================================  

    INTEGER :: irk,irkstep,nrksteps
    REAL(RFREAL) :: term
    REAL(RFREAL) :: ark(5),grk(5)
    TYPE(t_global), POINTER :: global
    TYPE(t_grid), POINTER :: pgrid
        
! *****************************************************************************
!   Set pointers and variables
! *****************************************************************************

    global => pregion%global
    pgrid  => pregion%grid

    irkstep  = pregion%irkStep
    nrksteps = pregion%global%nrkSteps

    ark(:) = pregion%mixtInput%ark(:)
    grk(:) = pregion%mixtInput%grk(:)
  
! ******************************************************************************
!   Determine scaling factor
! ******************************************************************************

    IF ( irkstep > 1 .AND. irkstep < nrksteps ) THEN 
      pgrid%fsScaleFactor   = ark(irkstep-1)/ark(irkstep)
    ELSE IF ( irkstep == 1 ) THEN
      pgrid%fsScaleFactor   = 1.0_rfreal/ark(irkstep)
    ELSE IF ( irkstep == nrksteps ) THEN
      term = 0.0_rfreal

      DO irk = 1,nrksteps-1
        term = term + grk(irk)/ark(irk)
      END DO ! iRk

      pgrid%fsScaleFactor   = (1.0_rfreal/ark(nrksteps) - term)/ark(irkstep-1)
    ELSE ! Defensive programming
      CALL errorstop(global,err_reached_default,__line__)
    END IF ! iRkStep
 
! ******************************************************************************
!   End
! ******************************************************************************

  END SUBROUTINE rflu_setgridspeedscalefactor




END MODULE rflu_modgridspeedutils

! ******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ModGridSpeedUtils.F90,v $
! Revision 1.7  2008/12/06 08:44:22  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:33  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/04/07 15:19:19  haselbac
! Removed tabs
!
! Revision 1.4  2004/10/19 19:28:03  haselbac
! Added routine to decide whether need grid speeds
!
! Revision 1.3  2004/06/16 20:01:02  haselbac
! Modification of loop limits to increase efficiency
!
! Revision 1.2  2004/04/19 20:21:07  haselbac
! Bug fix: Missing indGs added
!
! Revision 1.1  2004/04/14 02:05:11  haselbac
! Initial revision
!
! ******************************************************************************