RFLU_ComputeIntegral3OLES.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Compute integral 3 of optimal LES approach.
!
! Description: None.
!
! Input: 
!   region      Current region
!
! Output: None.
!
! Notes: 
!  1. At present, assume that velocity components are stored in positions 2-4.
!  2. Note normalization of integrals - because of use of dissipation, must 
!     compute integral after computation of dissipation.
!  3. IMPORTANT: Note that since an average over prototype faces is made, need 
!     to divide by a third of nFaces, and NOT nFaces!
!
!******************************************************************************
!
! $Id: RFLU_ComputeIntegral3OLES.F90,v 1.5 2008/12/06 08:44:29 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflu_computeintegral3oles(region)

  USE moddatatypes
  USE moddatastruct, ONLY: t_region
  USE modgrid, ONLY: t_grid
  USE moderror
  USE modglobal, ONLY: t_global
  USE modparameters
  USE modtools, ONLY: makenonzero

  USE rflu_modoles

  IMPLICIT NONE

! parameters      

  TYPE(t_region) :: region

! local variables

  CHARACTER(CHRLEN) :: rcsidentstring
  INTEGER :: a,b,c1g,c2g,c3g,d,e,g,hloc1,hloc2,ic1l,ic2l,ic3l,ifc,ifcp, & 
             iv1,iv2,iv3,j,k,l,m,ncells,nfaces,vloc1,vloc2
  INTEGER, DIMENSION(:), POINTER :: f2fpoles
  INTEGER, DIMENSION(:,:), POINTER :: fsoles
  REAL(RFREAL) :: avgfac,corr,term
  REAL(RFREAL), DIMENSION(:), POINTER :: vol
  REAL(RFREAL), DIMENSION(:,:), POINTER :: cv
  REAL(RFREAL), DIMENSION(:,:,:), POINTER :: int31oles,int32oles             
  TYPE(t_global), POINTER :: global

! ******************************************************************************
! Start, check that have primitive variables
! ******************************************************************************

  rcsidentstring = '$RCSfile: RFLU_ComputeIntegral3OLES.F90,v $ $Revision: 1.5 $'

  global => region%global

  CALL registerfunction(global,'RFLU_ComputeIntegral3OLES',&
  'RFLU_ComputeIntegral3OLES.F90')

  IF ( region%mixt%cvState == cv_mixt_state_cons ) THEN 
    CALL errorstop(global,err_cv_state_invalid,__line__)
  END IF ! region

! ******************************************************************************
! Set pointers and variables
! ******************************************************************************

  fsoles   => region%grid%fsOLES
  f2fpoles => region%grid%f2fpOLES

  int31oles => region%grid%int31OLES
  int32oles => region%grid%int32OLES

  vol => region%grid%vol
  cv  => region%mixt%cv

  ncells = SIZE(region%grid%fsOLES,1)
  nfaces = region%grid%nFaces
  avgfac = 3.0_rfreal/REAL(nFaces,KIND=RFREAL) ! NOTE factor of 3

! ******************************************************************************
! Initialize integrals
! ******************************************************************************

  int31oles(:,:,:) = 0.0_rfreal
  int32oles(:,:,:) = 0.0_rfreal  

! ******************************************************************************
! Compute integrals through loop over faces
! ******************************************************************************

  DO ifc = 1,nfaces
    ifcp = f2fpoles(ifc) ! get prototype face

! ==============================================================================
!   Loop over cells
! ==============================================================================
 
    DO ic1l = 1,ncells
      c1g = fsoles(ic1l,ifc)
      d = ic1l
    
      DO ic2l = 1,ncells
        c2g = fsoles(ic2l,ifc)      
        b = ic2l
        e = ic2l
      
        DO ic3l = 1,ncells
          c3g = fsoles(ic3l,ifc)         
          g = ic3l
          a = ic3l
          
          term = vol(c1g)*vol(c2g)*vol(c3g)       
          
! ------------------------------------------------------------------------------
!         Loop over velocity components
! ------------------------------------------------------------------------------          
          
          DO iv1 = 1,3
            l = iv1
          
            DO iv2 = 1,3
              DO iv3 = 1,3
              
! ------------- Compute correlation              
              
                corr = term*cv(iv1+1,c1g)*cv(iv2+1,c2g)*cv(iv3+1,c3g)
              
! ------------- Determine storage location for correlation              
              
                j = iv2
                k = iv3
              
                vloc1 = rflu_geti1posoles(l,d)              
                hloc1 = rflu_getqposoles(j,k,b,g,ncells)
                
                m = iv2
                j = iv3
                
                vloc2 = rflu_geti4posoles(l,m,d,e,ncells)                
                hloc2 = rflu_getlposoles(j,a)

! ------------- Store correlation              
              
                int31oles(ifcp,vloc1,hloc1) = int31oles(ifcp,vloc1,hloc1) & 
                                            + corr
                int32oles(ifcp,vloc2,hloc2) = int32oles(ifcp,vloc2,hloc2) & 
                                            + corr                                            
              END DO ! iv3
            END DO ! iv2
          END DO ! iv1
        
        END DO ! icl3
      END DO ! icl2
    END DO ! icl1

  END DO ! ifcp  

! ******************************************************************************
! Normalize and average integrals
! ******************************************************************************

  term = avgfac/(makenonzero(global%dissOLES)*region%grid%deltaOLES**10)

  int31oles(:,:,:) = term*int31oles(:,:,:)
  int32oles(:,:,:) = term*int32oles(:,:,:)
    
  
! ******************************************************************************
! End
! ******************************************************************************

  CALL deregisterfunction(global)

END SUBROUTINE rflu_computeintegral3oles

!*******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLU_ComputeIntegral3OLES.F90,v $
! Revision 1.5  2008/12/06 08:44:29  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:42  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2003/03/15 18:31:27  haselbac
! Added footer
!
!*******************************************************************************