RFLO_TimeStepViscous.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate max. allowable local/global time step in the case
!          of viscous flow.
!
! Description: none.
!
! Input: regions = data of all grid regions.
!
! Output: regions%levels%dt   = local time step
!         regions%levels%srad = convective spectral radii
!         global%dtMin        = global time step for all regions on this
!                               processor(if unsteady flow).
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_TimeStepViscous.F90,v 1.3 2008/12/06 08:44:28 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_timestepviscous( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getcelloffset, &
        rflo_getnodeoffset, rflo_copyvectorpatches, rflo_copyvectoredges, &
        rflo_copyvectorcorners, rflo_copymatrixpatches, rflo_copymatrixedges, &
        rflo_copymatrixcorners, rflo_getdimensphys
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: indcp, indmol, idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend, turbmodel
  INTEGER :: ilev, icoff, ijcoff, inoff, ijnoff, ijkc, ijkn, ijkn1, indsvel

  REAL(RFREAL) :: rgas, cpgas, gamma, f1, f2, fac, fmue, dtv, prlam, prturb
  REAL(RFREAL) :: rrho, u, v, w, sx, sy, sz, svel, ds2, ds, vc, cs, sumsrad
  REAL(RFREAL) :: srvi, srvj, srvk, dtmin
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), gv(:,:), tv(:,:), dt(:)
  REAL(RFREAL), POINTER :: si(:,:), sj(:,:), sk(:,:), vol(:)
  REAL(RFREAL), POINTER :: sivel(:), sjvel(:), skvel(:)
  REAL(RFREAL), POINTER :: srad(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_TimeStepViscous',&
  'RFLO_TimeStepViscous.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend,jdcbeg,jdcend, &
                            kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,jpcbeg,jpcend, &
                           kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  cv => region%levels(ilev)%mixt%cv
  dv => region%levels(ilev)%mixt%dv
  gv => region%levels(ilev)%mixt%gv
  tv => region%levels(ilev)%mixt%tv
  dt => region%levels(ilev)%dt

  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  vol    => region%levels(ilev)%grid%vol
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

  srad => region%levels(ilev)%mixt%srad

  prlam     = region%levels(ilev)%mixt%prLam
  prturb    = region%levels(ilev)%mixt%prTurb
  indcp     = region%levels(ilev)%mixt%indCp
  indmol    = region%levels(ilev)%mixt%indMol
  turbmodel = region%mixtInput%turbModel

! local time step, spectral radii ---------------------------------------------

  DO k=kdcbeg,kdcend
    DO j=jdcbeg,jdcend
      DO i=idcbeg,idcend
        ijkc  = indijk(i,j,k,icoff,ijcoff)
        ijkn  = indijk(i,j,k,inoff,ijnoff)
        rrho  = 1._rfreal/cv(cv_mixt_dens,ijkc)
        u     = cv(cv_mixt_xmom,ijkc)*rrho
        v     = cv(cv_mixt_ymom,ijkc)*rrho
        w     = cv(cv_mixt_zmom,ijkc)*rrho
        rgas  = 8314.3_rfreal/gv(gv_mixt_mol,ijkc*indmol)
        cpgas = gv(gv_mixt_cp,ijkc*indcp)
        gamma = cpgas/(cpgas-rgas)
        f1    = 4._rfreal*rrho/3._rfreal
        f2    = gamma*rrho
        fac   = max(f1,f2)
        IF (turbmodel == turb_model_none) THEN
          fmue = tv(tv_mixt_muel,ijkc)/prlam
        ELSE
          fmue = tv(tv_mixt_muel,ijkc)/prlam + tv(tv_mixt_muet,ijkc)/prturb
        ENDIF
        dtv   = fac*fmue/vol(ijkc)

        ijkn1 = indijk(i+1,j,k,inoff,ijnoff)
        sx    = 0.5_rfreal*(si(xcoord,ijkn)+si(xcoord,ijkn1))
        sy    = 0.5_rfreal*(si(ycoord,ijkn)+si(ycoord,ijkn1))
        sz    = 0.5_rfreal*(si(zcoord,ijkn)+si(zcoord,ijkn1))
        svel  = 0.5_rfreal*(sivel(ijkn*indsvel)+sivel(ijkn1*indsvel))
        ds2   = sx*sx + sy*sy + sz*sz
        ds    = sqrt(ds2)
        vc    = sx*u + sy*v + sz*w - svel
        cs    = dv(dv_mixt_soun,ijkc)*ds
        srvi  = dtv*ds2
        srad(icoord,ijkc) = abs(vc) + cs

        ijkn1 = indijk(i,j+1,k,inoff,ijnoff)
        sx    = 0.5_rfreal*(sj(xcoord,ijkn)+sj(xcoord,ijkn1))
        sy    = 0.5_rfreal*(sj(ycoord,ijkn)+sj(ycoord,ijkn1))
        sz    = 0.5_rfreal*(sj(zcoord,ijkn)+sj(zcoord,ijkn1))
        svel  = 0.5_rfreal*(sjvel(ijkn*indsvel)+sjvel(ijkn1*indsvel))
        ds2   = sx*sx + sy*sy + sz*sz
        ds    = sqrt(ds2)
        vc    = sx*u + sy*v + sz*w - svel
        cs    = dv(dv_mixt_soun,ijkc)*ds
        srvj  = dtv*ds2
        srad(jcoord,ijkc) = abs(vc) + cs

        ijkn1 = indijk(i,j,k+1,inoff,ijnoff)
        sx    = 0.5_rfreal*(sk(xcoord,ijkn)+sk(xcoord,ijkn1))
        sy    = 0.5_rfreal*(sk(ycoord,ijkn)+sk(ycoord,ijkn1))
        sz    = 0.5_rfreal*(sk(zcoord,ijkn)+sk(zcoord,ijkn1))
        svel  = 0.5_rfreal*(skvel(ijkn*indsvel)+skvel(ijkn1*indsvel))
        ds2   = sx*sx + sy*sy + sz*sz
        ds    = sqrt(ds2)
        vc    = sx*u + sy*v + sz*w - svel
        cs    = dv(dv_mixt_soun,ijkc)*ds
        srvk  = dtv*ds2
        srad(kcoord,ijkc) = abs(vc) + cs

        sumsrad  = srad(icoord,ijkc) + srad(jcoord,ijkc) + srad(kcoord,ijkc) &
                   + 4._rfreal*(srvi+srvj+srvk)
        sumsrad  = max(sumsrad,1.e-30_rfreal)
        dt(ijkc) = vol(ijkc)/sumsrad
      ENDDO  ! i
    ENDDO    ! j
  ENDDO      ! k

! treat dummy cells -----------------------------------------------------------

  CALL rflo_copyvectorpatches( ilev,region,dt )
  CALL rflo_copyvectoredges( ilev,region,dt )
  CALL rflo_copyvectorcorners( ilev,region,dt )

  CALL rflo_copymatrixpatches( ilev,region,srad )
  CALL rflo_copymatrixedges( ilev,region,srad )
  CALL rflo_copymatrixcorners( ilev,region,srad )

! global time step (this processor) -------------------------------------------

  IF (global%flowType == flow_unsteady) THEN
    dtmin = global%dtMin

    DO k=kpcbeg,kpcend
      DO j=jpcbeg,jpcend
        DO i=ipcbeg,ipcend
          ijkc  = indijk(i,j,k,icoff,ijcoff)
          dtmin = min(dtmin,dt(ijkc))
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

    global%dtMin = dtmin
  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_timestepviscous

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_TimeStepViscous.F90,v $
! Revision 1.3  2008/12/06 08:44:28  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:39  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 20:51:40  wasistho
! lower to upper case
!
! Revision 1.17  2003/11/20 16:40:40  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.13  2003/10/01 23:52:10  jblazek
! Corrected bug in moving noslip wall BC and grid speeds.
!
! Revision 1.12  2003/05/15 02:57:04  jblazek
! Inlined index function.
!
! Revision 1.11  2002/09/05 17:40:22  jblazek
! Variable global moved into regions().
!
! Revision 1.10  2002/09/02 23:09:47  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.9  2002/08/30 18:25:55  jblazek
! Forgot to multiply grid speeds by face area ...
!
! Revision 1.8  2002/08/30 01:47:58  jblazek
! Added support for moving grids.
!
! Revision 1.7  2002/08/29 22:45:56  jblazek
! Added support for moving grids.
!
! Revision 1.6  2002/08/28 00:03:56  wasistho
! mueT put back to consist only turbulent part
!
! Revision 1.5  2002/08/24 03:17:15  wasistho
! put safety within #ifdef TURB
!
! Revision 1.4  2002/08/23 03:18:37  wasistho
! due to mueT as Total instead of Turbulent
!
! Revision 1.3  2002/03/18 23:11:33  jblazek
! Finished multiblock and MPI.
!
! Revision 1.2  2002/02/21 23:25:06  jblazek
! Blocks renamed as regions.
!
! Revision 1.1  2002/02/09 01:47:01  jblazek
! Added multi-probe option, residual smoothing, physical time step.
!
!******************************************************************************