RFLO_CalcGradDummy.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: extrapolate gradients from the interior domain or at the patch 
!          to the dummy points depending on the boundary condition.
!
! Description: dummy gradients of physical boundary copied from interior
!              dummy gradients of symmetry boundary mirrored from interior
!              outerst dummy gradients of connecting bnd copied from interior
!
! Input: region  = data of current region.
!        patch   = current patch.
!        iBegV, iEndV = begin and end var index
!        iBegG, iEndG = begin and end gradient index
!  
! Output: gradi, gradj, gradk = gradients at dummy points of the current patch
!                               plane 
!
! Notes: many parameters are passed as subroutine arguments to minimize
!        repetition of work
!
!******************************************************************************
!
! $Id: RFLO_CalcGradDummy.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcgraddummy( region,patch,iBegV,iEndV,iBegG,iEndG, &
                               gradi,gradj,gradk )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices,rflo_getpatchdirection, &
                            rflo_calcgraddummyphys,rflo_calcgraddummyconn, &
                            rflo_calcgraddummysymm
  USE moderror
  USE modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

  INTEGER :: ibegv, iendv, ibegg, iendg

  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)

! ... local variables
  INTEGER :: ilev, lbound, bctype
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER :: indbeg, indend, jndbeg, jndend, kndbeg, kndend
  INTEGER :: inode, jnode, knode, idir, jdir, kdir

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcGradDummy',&
       'RFLO_CalcGradDummy.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound
  bctype = patch%bcType

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )

! take the right face vector and make it point outwards ----------------------

  inode = 0
  jnode = 0
  knode = 0
  IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

  indbeg = ibeg + inode
  jndbeg = jbeg + jnode
  kndbeg = kbeg + knode
  indend = iend + inode + 1 - abs(idir)
  jndend = jend + jnode + 1 - abs(jdir)
  kndend = kend + knode + 1 - abs(kdir)
 
! call dummy extrapolation routines depending on bcType -----------------------

  IF ((bctype>=bc_slipwall   .AND. bctype<=bc_slipwall  +bc_range) .OR. &
      (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) .OR. &
      (bctype>=bc_injection  .AND. bctype<=bc_injection +bc_range) .OR. &
      (bctype>=bc_inflow     .AND. bctype<=bc_inflow    +bc_range) .OR. &
      (bctype>=bc_outflow    .AND. bctype<=bc_outflow   +bc_range) .OR. &
      (bctype>=bc_farfield   .AND. bctype<=bc_farfield  +bc_range)) THEN

! - complete dummy layers by zeroth extrapolation 

    CALL rflo_calcgraddummyphys( region,lbound, &
                                 idir  ,jdir  ,kdir  , &
                                 indbeg,indend,jndbeg,jndend,kndbeg,kndend, &
                                 ibegv ,iendv ,ibegg ,iendg , &
                                 gradi ,gradj ,gradk )

  ELSE IF (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range) THEN

! - complete dummy layers by linear extrapolation

    CALL rflo_calcgraddummysymm( region,lbound, &
                                  idir  ,jdir  ,kdir  , &
                                  inode ,jnode ,knode , &
                                  ibeg  ,iend  ,jbeg  ,jend  ,kbeg  ,kend  , &
                                  indbeg,indend,jndbeg,jndend,kndbeg,kndend, &
                                  ibegv ,iendv ,ibegg ,iendg , &
                                  gradi ,gradj ,gradk )

  ELSE IF ((bctype>=bc_tra_peri   .AND. bctype<=bc_tra_peri  +bc_range) .OR. &
           (bctype>=bc_rot_peri   .AND. bctype<=bc_rot_peri  +bc_range) .OR. &
           (bctype>=bc_regionconf .AND. bctype<=bc_regionconf+bc_range)) THEN

! - complete the outerst dummy layers by zeroth extrapolation

    CALL rflo_calcgraddummyconn( region,lbound, &
                                 idir  ,jdir  ,kdir  , &
                                 indbeg,indend,jndbeg,jndend,kndbeg,kndend, &
                                 ibegv ,iendv ,ibegg ,iendg , &
                                 gradi ,gradj ,gradk )

  ELSE IF (bctype>=bc_regionint .AND. bctype<=bc_regionint+bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! - everything else

  ELSE

  ENDIF

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calcgraddummy

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: RFLO_CalcGradDummy.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.7  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.4  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.3  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/09/02 22:58:54  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.3  2002/07/22 22:59:11  jblazek
! Some more clean up.
!
! Revision 1.2  2002/07/19 23:43:11  wasistho
! made compliant with CODING RULE
!
!******************************************************************************