RFLO_CalcGradDummySymm.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: extrapolate gradients from the interior domain to the dummy points  
!          for symmetry boundary condition
!
! Description: dummy gradients mirrored from interior
!
! Input: region  = data of current region
!        lbound  = patch boundary index
!        idir,jdir,kdir = patch direction
!        inode,jnode,knode = patch nodes identifiers
!        ibeg,iend,jbeg,jend,kbeg,kend = patch cell indices
!        indBeg,indEnd,jndBeg,jndEnd,kndBeg,kndEnd = indices of patch nodes
!        iBegV, iEndV = begin and end var index
!        iBegG, iEndG = begin and end gradient index
!  
! Output: gradi, gradj, gradk = gradients at dummy faces of the current patch
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_CalcGradDummySymm.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcgraddummysymm( region,lbound, &
                                   idir  ,jdir  ,kdir  , &
                                   inode ,jnode ,knode , &
                                   ibeg  ,iend  ,jbeg  ,jend  ,kbeg  ,kend  , &
                                   indbeg,indend,jndbeg,jndend,kndbeg,kndend, &
                                   ibegv ,iendv ,ibegg ,iendg , &
                                   gradi ,gradj ,gradk )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: lbound, idir, jdir, kdir, inode, jnode, knode
  INTEGER        :: ibeg, iend, jbeg, jend, kbeg, kend
  INTEGER        :: indbeg, indend, jndbeg, jndend, kndbeg, kndend
  INTEGER        :: ibegv, iendv, ibegg, iendg
  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)

! ... loop variables
  INTEGER :: i, j, k, l, lx,ly,lz, idum, jdum, kdum

! ... local variables
  INTEGER :: ilev, inoff, ijnoff
  INTEGER :: ijknb, ijkni, ijknj, ijknk, ijknd, ijknr, ijknr1, ijknr2, ijknr3
  INTEGER :: im1jknb, ijm1knb, ijkm1nb
  INTEGER :: indxi(indbeg-1:indend), indxj(jndbeg-1:jndend)
  INTEGER :: indxk(kndbeg-1:kndend)
  INTEGER :: ig(3), jg(3), kg(3), ir(3), jr(3), kr(3)
  INTEGER :: idumb(3), jdumb(3), kdumb(3), idume(3), jdume(3), kdume(3)
  INTEGER :: nvar

  REAL(RFREAL)  :: dabsi, dabsj, dabsk
  REAL(RFREAL)  :: bgradi(ibegg:iendg)
  REAL(RFREAL)  :: bgradj(ibegg:iendg)
  REAL(RFREAL)  :: bgradk(ibegg:iendg)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcGradDummySymm',&
  'RFLO_CalcGradDummySymm.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  nvar = iendv - ibegv + 1

  dabsi = REAL(abs(idir))
  dabsj = REAL(abs(jdir))
  dabsk = REAL(abs(kdir))

  IF (lbound==1 .OR. lbound==3 .OR. lbound==5) THEN
    idumb(:) = -idir*region%nDumCells
    jdumb(:) = -jdir*region%nDumCells
    kdumb(:) = -kdir*region%nDumCells
    idume(:) = -idir
    jdume(:) = -jdir
    kdume(:) = -kdir
  ELSE
    idumb(:) = 0
    jdumb(:) = 0
    kdumb(:) = 0
    idume(:) = -idir*region%nDumCells
    jdume(:) = -jdir*region%nDumCells
    kdume(:) = -kdir*region%nDumCells
  ENDIF

  ig(:)=-abs(idir); jg(:)=-abs(jdir); kg(:)=-abs(kdir)
  ir(:)=0         ; jr(:)=0         ; kr(:)=0
  IF (lbound == 1) THEN
    ig(1)=0
    ir(2)=-1; ir(3)=-1
  ELSE IF (lbound == 3) THEN
    jg(2)=0
    jr(1)=-1; jr(3)=-1
  ELSE IF (lbound == 5) THEN
    kg(3)=0
    kr(1)=-1; kr(2)=-1
  ELSE IF (lbound == 2) THEN
    ig(1)=0
    idumb(1) = idumb(1)-idir
  ELSE IF (lbound == 4) THEN
    jg(2)=0
    jdumb(2) = jdumb(2)-jdir
  ELSE IF (lbound == 6) THEN
    kg(3)=0
    kdumb(3) = kdumb(3)-kdir
  ENDIF

! specify actual gradients at symmetry patch and denoted as reference gradients

  DO i=indbeg,indend
    indxi(i)=i
  Enddo
  DO j=jndbeg,jndend
    indxj(j)=j
  Enddo
  DO k=kndbeg,kndend
    indxk(k)=k
  Enddo
  indxi(indbeg-1)=indbeg
  indxj(jndbeg-1)=jndbeg
  indxk(kndbeg-1)=kndbeg

  DO k=kbeg+knode,kend+knode
    DO j=jbeg+jnode,jend+jnode
      DO i=ibeg+inode,iend+inode

        ijknb   = indijk(i  ,j  ,k         ,inoff,ijnoff)  ! ijk bnd nodes
        im1jknb = indijk(indxi(i-1),j  ,k  ,inoff,ijnoff)  ! im1jk bnd nodes
        ijm1knb = indijk(i  ,indxj(j-1),k  ,inoff,ijnoff)  ! ijm1k bnd nodes
        ijkm1nb = indijk(i  ,j  ,indxk(k-1),inoff,ijnoff)  ! ijkm1 bnd nodes

        ijknr1 = indijk(i+ir(1),j+jr(1),k+kr(1),inoff,ijnoff)  ! reference nodes
        ijknr2 = indijk(i+ir(2),j+jr(2),k+kr(2),inoff,ijnoff)  ! reference nodes
        ijknr3 = indijk(i+ir(3),j+jr(3),k+kr(3),inoff,ijnoff)  ! reference nodes
        DO l=ibegg,iendg
          gradi(l,ijknr1)=dabsi*gradi(l,ijknr1)+ &
                          dabsj*0.5_rfreal*(gradj(l,ijknb)+gradj(l,im1jknb))+ &
                          dabsk*0.5_rfreal*(gradk(l,ijknb)+gradk(l,im1jknb))

          gradj(l,ijknr2)=dabsj*gradj(l,ijknr2)+ &
                          dabsi*0.5_rfreal*(gradi(l,ijknb)+gradi(l,ijm1knb))+ &
                          dabsk*0.5_rfreal*(gradk(l,ijknb)+gradk(l,ijm1knb))

          gradk(l,ijknr3)=dabsk*gradk(l,ijknr3)+ &
                          dabsi*0.5_rfreal*(gradi(l,ijknb)+gradi(l,ijkm1nb))+ &
                          dabsj*0.5_rfreal*(gradj(l,ijknb)+gradj(l,ijkm1nb))
        ENDDO ! l
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fill in the last reference line of gradients ---------------------------------

  IF (lbound==1 .OR. lbound==2) THEN

    DO j=jbeg,jend
      ijknb = indijk(indbeg,j,kend,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(indbeg+ir(3),j,kndend,inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradk(l,ijknr)=gradi(l,ijknb)
      ENDDO
    ENDDO

    DO k=kbeg,kend
      ijknb = indijk(indbeg,jend,k,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(indbeg+ir(2),jndend,k,inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradj(l,ijknr)=gradi(l,ijknb)
      ENDDO
    ENDDO

  ELSEIF (lbound==3 .OR. lbound==4) THEN

    DO k=kbeg,kend
      ijknb = indijk(iend,jndbeg,k,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(indend,jndbeg+jr(1),k,inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradi(l,ijknr)=gradj(l,ijknb)
      ENDDO
    ENDDO

    DO i=ibeg,iend
      ijknb = indijk(i,jndbeg,kend,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(i,jndbeg+jr(3),kndend,inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradk(l,ijknr)=gradj(l,ijknb)
      ENDDO
    ENDDO

  ELSEIF (lbound==5 .OR. lbound==6) THEN

    DO j=jbeg,jend
      ijknb = indijk(iend,j,kndbeg,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(indend,j,kndbeg+kr(1),inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradi(l,ijknr)=gradk(l,ijknb)
      ENDDO
    END DO

    DO i=ibeg,iend
      ijknb = indijk(i,jend,kndbeg,inoff,ijnoff)  ! boundary nodes
      ijknr = indijk(i,jndend,kndbeg+kr(2),inoff,ijnoff)  ! reference nodes
      DO l=ibegg,iendg
        gradj(l,ijknr)=gradk(l,ijknb)
      ENDDO
    END DO

  ENDIF

! specify gradients at dummy points by extrapolation (mirroring) ---------------
! 2D loop over patch nodes 

  DO k=kndbeg,kndend
    DO j=jndbeg,jndend
      DO i=indbeg,indend

! ----- 1D loop in direction normal to patch to define dummy face-gradi,j, and k 

        ijknr1 = indijk(i+ir(1),j+jr(1),k+kr(1),inoff,ijnoff)  ! reference nodes
        ijknr2 = indijk(i+ir(2),j+jr(2),k+kr(2),inoff,ijnoff)  ! reference nodes
        ijknr3 = indijk(i+ir(3),j+jr(3),k+kr(3),inoff,ijnoff)  ! reference nodes
        DO l=ibegg,iendg
          bgradi(l)=gradi(l,ijknr1)
          bgradj(l)=gradj(l,ijknr2)
          bgradk(l)=gradk(l,ijknr3)
        ENDDO

        DO idum=idumb(1),idume(1)
          DO jdum=jdumb(1),jdume(1)
            DO kdum=kdumb(1),kdume(1) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)  ! dummy points
              ijkni = indijk(i+ig(1)-idum,j+jg(1)-jdum,k+kg(1)-kdum,inoff,ijnoff)  ! interior
              DO l=ibegg,iendg
                gradi(l,ijknd)=2.0_rfreal*bgradi(l)-gradi(l,ijkni)
              ENDDO
            ENDDO
          ENDDO  
        ENDDO    

        DO idum=idumb(2),idume(2)
          DO jdum=jdumb(2),jdume(2)
            DO kdum=kdumb(2),kdume(2) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff) ! dummy points
              ijknj = indijk(i+ig(2)-idum,j+jg(2)-jdum,k+kg(2)-kdum,inoff,ijnoff)  ! interior
              DO l=ibegg,iendg
                gradj(l,ijknd)=2.0_rfreal*bgradj(l)-gradj(l,ijknj)
              ENDDO
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(3),idume(3)
          DO jdum=jdumb(3),jdume(3)
            DO kdum=kdumb(3),kdume(3) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff) ! dummy points
              ijknk = indijk(i+ig(3)-idum,j+jg(3)-jdum,k+kg(3)-kdum,inoff,ijnoff)  ! interior
              DO l=ibegg,iendg
                gradk(l,ijknd)=2.0_rfreal*bgradk(l)-gradk(l,ijknk)
              ENDDO
            ENDDO
          ENDDO
        ENDDO

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calcgraddummysymm

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: RFLO_CalcGradDummySymm.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.9  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.6  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.5  2002/10/14 23:47:39  wasistho
! Minor tunning to get speedup
!
! Revision 1.4  2002/10/12 03:20:50  jblazek
! Replaced [io]stat=global%error with local errorFlag for Rocflo.
!
! Revision 1.3  2002/10/03 02:54:49  wasistho
! modification through indxi,j,k
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/09/02 22:58:54  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.3  2002/07/22 22:59:11  jblazek
! Some more clean up.
!
! Revision 1.2  2002/07/19 23:43:51  wasistho
! made compliant with CODING RULE
!
!******************************************************************************