RFLO_CalcGradDummyConn.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: determine gradients at the outerst dummy layers of connecting 
!          boundaries
!
! Description: copy defined gradients at the dummy points to the outerst dummy 
!              layers of connecting boundaries
!
! Input: region  = data of current region
!        lbound  = patch boundary index
!        idir,jdir,kdir = patch direction
!        indBeg,indEnd,jndBeg,jndEnd,kndBeg,kndEnd = indices of patch nodes
!        iBegV, iEndV = begin and end var index
!        iBegG, iEndG = begin and end gradient index
!  
! Output: gradi, gradj, gradk = gradients at dummy faces of the current patch
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_CalcGradDummyConn.F90,v 1.3 2008/12/06 08:44:06 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_calcgraddummyconn( region,lbound, &
                                   idir  ,jdir  ,kdir  , &
                                   indbeg,indend,jndbeg,jndend,kndbeg,kndend, &
                                   ibegv ,iendv ,ibegg ,iendg , &
                                   gradi ,gradj ,gradk )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: lbound,idir,jdir,kdir
  INTEGER        :: indbeg, indend, jndbeg, jndend, kndbeg, kndend
  INTEGER        :: ibegv, iendv, ibegg, iendg
  REAL(RFREAL), POINTER :: gradi(:,:), gradj(:,:), gradk(:,:)

! ... loop variables
  INTEGER :: i, j, k, idum, jdum, kdum

! ... local variables
  INTEGER :: ilev, inoff, ijnoff
  INTEGER :: ijkni, ijknj, ijknk, ijknd
  INTEGER :: ig(3), jg(3), kg(3)
  INTEGER :: idumb(3), jdumb(3), kdumb(3), idume(3), jdume(3), kdume(3)

!******************************************************************************

  CALL registerfunction( region%global,'RFLO_CalcGradDummyConn',&
       'RFLO_CalcGradDummyConn.F90' )

! get dimensions -------------------------------------------------------------

  ilev = region%currLevel
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  idumb(:) = -idir*region%nDumCells
  jdumb(:) = -jdir*region%nDumCells
  kdumb(:) = -kdir*region%nDumCells
  idume(:) = idumb(:)
  jdume(:) = jdumb(:)
  kdume(:) = kdumb(:)

  ig(:) = -idir*(region%nDumCells-1)
  jg(:) = -jdir*(region%nDumCells-1)
  kg(:) = -kdir*(region%nDumCells-1)
  IF (lbound == 2) THEN
    idumb(2) = idumb(2)+idir; idumb(3) = idumb(3)+idir
    ig(2) = ig(2)+idir; ig(3) = ig(3)+idir
  ELSE IF (lbound == 4) THEN
    jdumb(1) = jdumb(1)+jdir; jdumb(3) = jdumb(3)+jdir
    jg(1) = jg(1)+jdir; jg(3) = jg(3)+jdir
  ELSE IF (lbound == 6) THEN
    kdumb(1) = kdumb(1)+kdir; kdumb(2) = kdumb(2)+kdir
    kg(1) = kg(1)+kdir; kg(2) = kg(2)+kdir
  ENDIF

! 2D loop over patch nodes ----------------------------------------------------

  DO k=kndbeg,kndend
    DO j=jndbeg,jndend
      DO i=indbeg,indend

        ijkni = indijk(i+ig(1),j+jg(1),k+kg(1),inoff,ijnoff)  ! i reference
        ijknj = indijk(i+ig(2),j+jg(2),k+kg(2),inoff,ijnoff)  ! j reference
        ijknk = indijk(i+ig(3),j+jg(3),k+kg(3),inoff,ijnoff)  ! k reference

! ----- 1D loop in direction normal to patch to define grads at dummy faces

        DO idum=idumb(1),idume(1)
          DO jdum=jdumb(1),jdume(1)
            DO kdum=kdumb(1),kdume(1) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              gradi(:,ijknd) = gradi(:,ijkni)
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(2),idume(2)
          DO jdum=jdumb(2),jdume(2)
            DO kdum=kdumb(2),kdume(2) 
              ijknd  = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              gradj(:,ijknd) = gradj(:,ijknj)
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(3),idume(3)
          DO jdum=jdumb(3),jdume(3)
            DO kdum=kdumb(3),kdume(3) 
              ijknd  = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)
              gradk(:,ijknd) = gradk(:,ijknk)
            ENDDO
          ENDDO
        ENDDO

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE rflo_calcgraddummyconn

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: RFLO_CalcGradDummyConn.F90,v $
! Revision 1.3  2008/12/06 08:44:06  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:20  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/11/29 21:25:16  wasistho
! lower to upper case
!
! Revision 1.6  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.3  2003/05/15 02:57:01  jblazek
! Inlined index function.
!
! Revision 1.2  2002/09/05 17:40:19  jblazek
! Variable global moved into regions().
!
! Revision 1.1  2002/09/02 22:58:54  wasistho
! RFLO grad routines migrated from rocflo to libflo
!
! Revision 1.3  2002/07/22 22:59:11  jblazek
! Some more clean up.
!
! Revision 1.2  2002/07/19 23:43:21  wasistho
! made compliant with CODING RULE
!
!******************************************************************************