PLAG_RFLO_SendRecvMetrics.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: driver to communicate buffer data of RFLO metrics, face centroids
!          and face normals, for adjacent regions on different processors.
!
! Description: none.
!
! Input: regions = data of all regions.
!
! Output: buffer data for metrics.
!
! Notes: None.
!
!******************************************************************************
!
! $Id: PLAG_RFLO_SendRecvMetrics.F90,v 1.4 2008/12/06 08:44:35 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_rflo_sendrecvmetrics( regions )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag
  USE plag_modinterfaces, ONLY: plag_rflo_recvmetrics,      &
                                plag_rflo_sendmetrics,      &  
                                plag_rflo_clearsendrequests
  USE moderror
  USE modmpi
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: icorner, iedge, ijk, ilev, ir, ireg 

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring
  
  INTEGER :: errorflag
  INTEGER :: ncorners, nedges  
  INTEGER :: nfaces, nfacecentroidsize, nfacenormalsize, nmetricsbuff

  TYPE(t_level),       POINTER :: plevel
  TYPE(t_dcelltransf), POINTER :: psendeccell, precveccell
  TYPE(t_plag),        POINTER :: pplag
  TYPE(t_global),      POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_RFLO_SendRecvMetrics.F90,v $ $Revision: 1.4 $'

  global => regions(1)%global

  CALL registerfunction( global,'PLAG_RFLO_SendRecvMetrics',&
  'PLAG_RFLO_SendRecvMetrics.F90' )

! Set dimensions --------------------------------------------------------------

  ncorners = 8
  nedges   = 12
  nfaces   = 6

  nfacecentroidsize = zcoord*kcoord
  nfacenormalsize   =      3*kcoord
  nmetricsbuff      = nfaces*(nfacecentroidsize + nfacenormalsize)

! Allocate communicaton buffers ===============================================

  DO ireg = 1, global%nRegions  
    IF ( regions(ireg)%procid==global%myProcid .AND. &   ! region active and
         regions(ireg)%active==active          .AND. &   ! on my processor
         global%nProcAlloc > 1                 ) THEN    ! only if multiple processors

      DO ilev=1,regions(ireg)%nGridLevels
        pplag => regions(ireg)%levels(ilev)%plag
        pplag%nRequestsMetrics = 0
        
        DO ir=1,global%nRegions
          psendeccell => regions(ireg)%levels(ilev)%sendEcCells(ir)
          precveccell => regions(ireg)%levels(ilev)%recvEcCells(ir)
          
          IF ( psendeccell%nCells > 0 ) THEN
            pplag%nRequestsMetrics = pplag%nRequestsMetrics+1
            psendeccell%iRequestMetrics = pplag%nRequestsMetrics
            ALLOCATE( psendeccell%buffMetrics(psendeccell%nCells*nmetricsbuff), &
                      stat=errorflag )
            global%error = errorflag
            IF ( global%error /= err_none ) &
              CALL errorstop( global,err_allocate,__line__ )
          ENDIF ! pSendEcCell%nCells
          
          IF ( precveccell%nCells > 0 ) THEN
            precveccell%iRequestMetrics = -999999
            ALLOCATE( precveccell%buffMetrics(precveccell%nCells*nmetricsbuff), &
                      stat=errorflag )
            global%error = errorflag
            IF ( global%error /= err_none ) &
            CALL errorstop( global,err_allocate,__line__ )
          ENDIF ! pRecvEcCell%nCell 
        ENDDO   ! ir

        ALLOCATE(pplag%requestsMetrics(pplag%nRequestsMetrics), stat=errorflag )
        global%error = errorflag
        IF ( global%error /= err_none ) &
          CALL errorstop( global,err_allocate,__line__ )

      ENDDO     ! iLev

    ENDIF       ! regions
  ENDDO         ! iReg

! synchronize through an MPI barrier ------------------------------------------

#ifdef MPI
  CALL mpi_barrier( global%mpiComm,global%mpierr )
  IF ( global%mpierr /= err_none ) &
    CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! communicate buffer ----------------------------------------------------------
                           
! send buffer------------------------------------------------------------------  

  DO ireg = 1, global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor        
      CALL plag_rflo_sendmetrics(regions, ireg)    
    ENDIF       ! regions    
  ENDDO         ! iReg

! receive buffer --------------------------------------------------------------

  DO ireg = 1, global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor        
      CALL plag_rflo_recvmetrics(regions, ireg)
    ENDIF ! regions
  ENDDO ! iReg 

! wait for data being received by other processors ----------------------------

  DO ireg = 1, global%nRegions
    IF (regions(ireg)%procid==global%myProcid .AND. &   ! region active and
        regions(ireg)%active==active) THEN              ! on my processor
      CALL plag_rflo_clearsendrequests(regions, ireg)
    ENDIF ! regions  
  ENDDO ! iReg

! synchronize through an MPI barrier ------------------------------------------

#ifdef MPI
  CALL mpi_barrier( global%mpiComm,global%mpierr )
  IF ( global%mpierr /= err_none ) &
    CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! deallocate communicaton buffers ---------------------------------------------

  DO ireg = 1, global%nRegions  
    IF ( regions(ireg)%procid==global%myProcid .AND. &   ! region active and
         regions(ireg)%active==active          .AND. &   ! on my processor
         global%nProcAlloc > 1                 ) THEN    ! only if multiple processors

      DO ilev=1,regions(ireg)%nGridLevels
        pplag => regions(ireg)%levels(ilev)%plag

        DO ir=1,global%nRegions
          psendeccell => regions(ireg)%levels(ilev)%sendEcCells(ir)
          precveccell => regions(ireg)%levels(ilev)%recvEcCells(ir)
          
          IF ( psendeccell%nCells > 0 ) THEN
            DEALLOCATE( psendeccell%buffMetrics, stat=errorflag )
            global%error = errorflag
            IF ( global%error /= err_none ) &
              CALL errorstop( global,err_deallocate,__line__ )
          ENDIF ! pSendEcCell%nCells
          
          IF ( precveccell%nCells > 0 ) THEN
            DEALLOCATE( precveccell%buffMetrics, stat=errorflag )
            global%error = errorflag
            IF ( global%error /= err_none ) &
            CALL errorstop( global,err_deallocate,__line__ )
          ENDIF ! pRecvEcCell%nCell 
        ENDDO   ! ir

        DEALLOCATE(pplag%requestsMetrics, stat=errorflag )
        global%error = errorflag
        IF ( global%error /= err_none ) &
          CALL errorstop( global,err_deallocate,__line__ )

      ENDDO     ! iLev

    ENDIF       ! regions
  ENDDO         ! iReg

! synchronize through an MPI barrier ------------------------------------------

#ifdef MPI
  CALL mpi_barrier( global%mpiComm,global%mpierr )
  IF ( global%mpierr /= err_none ) &
    CALL errorstop( global,err_mpi_trouble,__line__ )
#endif
  
! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflo_sendrecvmetrics

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLO_SendRecvMetrics.F90,v $
! Revision 1.4  2008/12/06 08:44:35  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2006/04/07 15:19:24  haselbac
! Removed tabs
!
! Revision 1.1  2004/12/01 20:58:14  fnajjar
! Initial revision after changing case
!
! Revision 1.1  2004/01/15 21:16:48  fnajjar
! Initial import for corner-edge cell metrics
!
!******************************************************************************