PLAG_RFLO_RecvMetrics.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: receives RFLO metrics to edge and corner cells of an adjacent 
!          region.
!
! Description: kernel is pertinent when the other region is located
!              on a different processor.
!
! Input: regions = data of all regions
!        iReg    = current region.
!
! Output: new values of RFLO metrics variables.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_RFLO_RecvMetrics.F90,v 1.3 2008/12/06 08:44:34 mtcampbe Exp $
!
! Copyright: (c) 2004 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_rflo_recvmetrics( regions,iReg )

  USE moddatatypes
  USE modglobal, ONLY     : t_global
  USE moddatastruct, ONLY : t_region, t_level, t_dcelltransf
  USE modinterfaces, ONLY : rflo_getcelloffset, rflo_getedgecellsindices, &
                            rflo_getcornercellsindices
  USE moderror
  USE modmpi
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

  INTEGER, INTENT(IN)     :: ireg

! ... loop variables
  INTEGER :: ir, icorner, iedge, iface, i, j, k, ijk

! ... local variables
#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ibuff, icell, ilev, iregsrc, ndim, source, tag
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, icoff, ijcoff
  INTEGER :: nbuffsize, ncorners, nedges
  INTEGER :: nfaces, nfacecentroidsize, nfacenormalsize
  INTEGER :: inoff, ijnoff, ijkn
  INTEGER :: ndumcellssrc
  INTEGER :: nodecorn, nodeedge

  REAL(RFREAL), POINTER, DIMENSION(:,:)   :: psi, psj, psk
  REAL(RFREAL), POINTER, DIMENSION(:,:,:) :: pfc
 
  TYPE(t_region),      POINTER :: pregion 
  TYPE(t_level),       POINTER :: plevel
  TYPE(t_dcelltransf), POINTER :: precveccell
  TYPE(t_global),      POINTER :: global

!******************************************************************************

  global => regions(ireg)%global

  CALL registerfunction( global,'PLAG_RFLO_RecvMetrics',&
  'PLAG_RFLO_RecvMetrics.F90' )

! Get dimensions --------------------------------------------------------------

  ilev = regions(ireg)%currLevel
  ncorners  = 8
  nedges    = 12
  nfaces    = 6
  
! Compute buffer size has to store information --------------------------------
!  on the total number of faces for each cell .
  
  nfacecentroidsize = zcoord*kcoord
  nfacenormalsize   =      3*kcoord
  nbuffsize = (nfacecentroidsize + nfacenormalsize)

! Set pointers ----------------------------------------------------------------
  
  pregion => regions(ireg)
  plevel  => regions(ireg)%levels(ilev) 
  pfc     => regions(ireg)%levels(ilev)%plag%fc
  psi     => regions(ireg)%levels(ilev)%plag%si
  psj     => regions(ireg)%levels(ilev)%plag%sj
  psk     => regions(ireg)%levels(ilev)%plag%sk

! Get node offset -------------------------------------------------------------

  CALL rflo_getnodeoffset( pregion,ilev,inoff,ijnoff ) 

! copy data from buffer to dummy cells

  DO ir=1,global%nRegions
    IF (regions(ir)%procid /= global%myProcid) THEN
    IF (plevel%recvEcCells(ir)%nCells > 0) THEN

      precveccell => plevel%recvEcCells(ir)
      ndim        =  precveccell%nCells*nfaces
      ibuff       =  0

! - Receive buffers from source processor ---------------------------------------

#ifdef MPI
      source = regions(ir)%procid
      tag    = regions(ireg)%localNumber+ plag_tag_shift +mpi_patchoff +10

      CALL mpi_recv( precveccell%buffMetrics,nbuffsize*ndim,mpi_rfreal, &
                     source,tag,global%mpiComm,status,global%mpierr )
      IF ( global%mpierr /= err_none ) &
        CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

! -- Load edges ---------------------------------------------------------------

      DO iedge=1,nedges

! --- Bypass for noninteracting regions ---------------------------------------

        IF( .NOT. plevel%edgeCells(iedge)%interact ) goto 1999

! -- Bypass for degenerate edge cells -----------------------------------------

        IF( plevel%edgeCells(iedge)%degenrt /= degenerat_none ) goto 1999

! --- Current region infrastructure -------------------------------------------

        CALL rflo_getedgecellsindices( pregion,ilev,iedge, &
                                       ibeg,iend,jbeg,jend,kbeg,kend )

        ijk = 0
        DO k=kbeg,kend
        DO j=jbeg,jend
        DO i=ibeg,iend 
          ijk     =  ijk + 1
          ijkn    = indijk(i,j,k,inoff, ijnoff)
          iregsrc = plevel%edgeCells(iedge)%cells(ijk)%srcRegion
          IF ( iregsrc == ir ) THEN

            IF ( plevel%edgeCells(iedge)%cells(ijk)%rotate ) THEN
                    ! rotational periodicity
            ELSE

! --- Loop over all the Faces -------------------------------------------------
! --- Note: assumes coordinate alignment between regions ----------------------

              DO iface = 1, nfaces
                ibuff = ibuff + 1

                SELECT CASE (iface)
                  CASE(1,3,5)
                    nodeedge    = indijk(i,j,k,inoff, ijnoff)

                  CASE(2)
                    nodeedge    = indijk(i+1,j,k,inoff, ijnoff)

                  CASE(4)
                    nodeedge    = indijk(i,j+1,k,inoff, ijnoff)

                  CASE(6)
                    nodeedge    = indijk(i,j,k+1,inoff, ijnoff)
                END SELECT  

! ---- Load face centroids -----------------------------------------------------

                pfc(xcoord,icoord,nodeedge) = precveccell%buffMetrics(ibuff        )
                pfc(xcoord,jcoord,nodeedge) = precveccell%buffMetrics(ibuff+   ndim)
                pfc(xcoord,zcoord,nodeedge) = precveccell%buffMetrics(ibuff+ 2*ndim)

                pfc(ycoord,icoord,nodeedge) = precveccell%buffMetrics(ibuff+ 3*ndim)
                pfc(ycoord,jcoord,nodeedge) = precveccell%buffMetrics(ibuff+ 4*ndim)
                pfc(ycoord,zcoord,nodeedge) = precveccell%buffMetrics(ibuff+ 5*ndim)
                
                pfc(zcoord,icoord,nodeedge) = precveccell%buffMetrics(ibuff+ 6*ndim)
                pfc(zcoord,jcoord,nodeedge) = precveccell%buffMetrics(ibuff+ 7*ndim)
                pfc(zcoord,zcoord,nodeedge) = precveccell%buffMetrics(ibuff+ 8*ndim)

! --- Load face normals -------------------------------------------------------

                psi(xcoord,nodeedge)        = precveccell%buffMetrics(ibuff+ 9*ndim)
                psi(ycoord,nodeedge)        = precveccell%buffMetrics(ibuff+10*ndim)
                psi(zcoord,nodeedge)        = precveccell%buffMetrics(ibuff+11*ndim)

                psj(xcoord,nodeedge)        = precveccell%buffMetrics(ibuff+12*ndim)
                psj(ycoord,nodeedge)        = precveccell%buffMetrics(ibuff+13*ndim)
                psj(zcoord,nodeedge)        = precveccell%buffMetrics(ibuff+14*ndim)

                psk(xcoord,nodeedge)        = precveccell%buffMetrics(ibuff+15*ndim)
                psk(ycoord,nodeedge)        = precveccell%buffMetrics(ibuff+16*ndim)
                psk(zcoord,nodeedge)        = precveccell%buffMetrics(ibuff+17*ndim)
              ENDDO ! iFace 

             ENDIF  ! rotate
            ENDIF   !iRegSrc

          ENDDO     ! i
          ENDDO     ! j
          ENDDO     ! k

1999    CONTINUE
      ENDDO    ! iEdge

! --- Load corners ------------------------------------------------------------

      DO icorner=1,ncorners

! -- Bypass for noninteracting regions ----------------------------------------

        IF (.NOT. plevel%cornerCells(icorner)%interact) goto 2999

! -- Bypass for degenerate corner cells ---------------------------------------

        IF( plevel%cornerCells(icorner)%degenrt /= degenerat_none ) goto 2999

! -- Current region infrastructure ---------------------------------------------

        CALL rflo_getcornercellsindices( pregion,ilev,icorner, &
                                         ibeg,iend,jbeg,jend,kbeg,kend )

        ijk = 0
        DO k=kbeg,kend
        DO j=jbeg,jend
        DO i=ibeg,iend
          ijk     = ijk + 1
          ijkn    = indijk(i,j,k,inoff,ijnoff)
          iregsrc = plevel%cornerCells(icorner)%cells(ijk)%srcRegion
          IF ( iregsrc == ir ) THEN

            IF ( plevel%cornerCells(icorner)%cells(ijk)%rotate ) THEN
                   ! rotational periodicity
            ELSE

! --- Loop over all the Faces -------------------------------------------------
! --- Note: assumes coordinate alignment between regions ----------------------

              DO iface = 1, nfaces
                ibuff = ibuff + 1

                SELECT CASE (iface)
                  CASE(1,3,5)
                    nodecorn = indijk(i,j,k,inoff, ijnoff)

                  CASE(2)
                    nodecorn = indijk(i+1,j,k,inoff, ijnoff)

                  CASE(4)
                    nodecorn = indijk(i,j+1,k,inoff, ijnoff)

                  CASE(6)
                    nodecorn = indijk(i,j,k+1,inoff, ijnoff)
                END SELECT  

! ---- Load face centroids -----------------------------------------------------

                pfc(xcoord,icoord,nodecorn) = precveccell%buffMetrics(ibuff        )
                pfc(xcoord,jcoord,nodecorn) = precveccell%buffMetrics(ibuff+   ndim)
                pfc(xcoord,zcoord,nodecorn) = precveccell%buffMetrics(ibuff+ 2*ndim)

                pfc(ycoord,icoord,nodecorn) = precveccell%buffMetrics(ibuff+ 3*ndim)
                pfc(ycoord,jcoord,nodecorn) = precveccell%buffMetrics(ibuff+ 4*ndim)
                pfc(ycoord,zcoord,nodecorn) = precveccell%buffMetrics(ibuff+ 5*ndim)
                
                pfc(zcoord,icoord,nodecorn) = precveccell%buffMetrics(ibuff+ 6*ndim)
                pfc(zcoord,jcoord,nodecorn) = precveccell%buffMetrics(ibuff+ 7*ndim)
                pfc(zcoord,zcoord,nodecorn) = precveccell%buffMetrics(ibuff+ 8*ndim)

! --- Load face normals -------------------------------------------------------

                psi(xcoord,nodecorn)        = precveccell%buffMetrics(ibuff+ 9*ndim)
                psi(ycoord,nodecorn)        = precveccell%buffMetrics(ibuff+10*ndim)
                psi(zcoord,nodecorn)        = precveccell%buffMetrics(ibuff+11*ndim)
                psj(xcoord,nodecorn)        = precveccell%buffMetrics(ibuff+12*ndim)
                psj(ycoord,nodecorn)        = precveccell%buffMetrics(ibuff+13*ndim)
                psj(zcoord,nodecorn)        = precveccell%buffMetrics(ibuff+14*ndim)
                psk(xcoord,nodecorn)        = precveccell%buffMetrics(ibuff+15*ndim)
                psk(ycoord,nodecorn)        = precveccell%buffMetrics(ibuff+16*ndim)
                psk(zcoord,nodecorn)        = precveccell%buffMetrics(ibuff+17*ndim)
              ENDDO ! iFace 

             ENDIF  ! rotate
            ENDIF   !iRegSrc

          ENDDO     ! i
          ENDDO     ! j
          ENDDO     ! k

2999    CONTINUE 
      ENDDO    ! icorner

    ENDIF      ! some cells to receive
    ENDIF      ! not my processor
  ENDDO        ! ir

! finalize

  CALL deregisterfunction( global )

END SUBROUTINE plag_rflo_recvmetrics

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_RFLO_RecvMetrics.F90,v $
! Revision 1.3  2008/12/06 08:44:34  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:47  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:58:11  fnajjar
! Initial revision after changing case
!
! Revision 1.4  2004/11/29 19:22:39  fnajjar
! Added bypass statement for dengerate cells
!
! Revision 1.3  2004/03/21 00:43:32  fnajjar
! Fixed tags to be smaller number since Frost run-time system complains about size
!
! Revision 1.2  2004/03/06 21:25:05  fnajjar
! Added PLAG_TAG_SHIFT to MPI-based communication tags
!
! Revision 1.1  2004/01/15 21:16:48  fnajjar
! Initial import for corner-edge cell metrics
!
!******************************************************************************