PLAG_PostProcessing.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write out ROCPART solution for visualization.
!
! Description: currently supported formats are:
!              - TECPLOT ASCII
!
! Input: case name from the list of arguments
!
! Output: to file.
!
! Notes: the output is collected in one file, but the regions are processed
!        separately to save memory.
!
!******************************************************************************
!
! $Id: PLAG_PostProcessing.F90,v 1.5 2008/12/06 08:45:07 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

PROGRAM rocpart_post

  USE moddatatypes
  USE moderror
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modmixture, ONLY    : t_mixt
  USE modpartlag, ONLY    : t_plag, t_plag_input
  USE plag_modinterfacespost, ONLY : buildversionstring, readinputfile,  &
                                     rflo_derivedinputvalues,            &
                                     rflo_readregiontopology,            &
                                     rflo_initinputvalues,               &
                                     plag_allocatememorypost,            &
                                     plag_binsortnozzleinlet,            &
                                     plag_binsortspatialdist,            &
                                     plag_deallocatememorypost,          &
                                     plag_calcderivedvariables,          &
                                     plag_intrpmixtproperties,           &
                                     plag_processeulerfield,             &
                                     plag_readsolutionfilepost,          &
                                     plag_userinput,                     &
                                     plag_writetecplotascii

#ifdef STATS  
  USE plag_modstats, ONLY: plag_createstat, plag_destroystat
  USE plag_modinterfacespost, ONLY : plag_readstatpost, &
                                     plag_writestattecascii
#endif

  USE modmpi
  USE modparameters
  USE plag_modparameters

  IMPLICIT NONE

! ... loop variables
  INTEGER :: ireg

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring, stamp, outfmt, msg, &
                       verbosity, versionstring, headerstring

  INTEGER :: ilev, outputformat
  INTEGER :: margin, versionwidth, errorflag
  INTEGER :: npclssum
  INTEGER :: iregbin
  INTEGER, PARAMETER :: headerwidth = 53
  INTEGER, PARAMETER :: nstats_tec_plag = 10

#ifdef STATS
  LOGICAL :: statsactive
#endif

  TYPE(t_global), POINTER :: global
  TYPE(t_region), POINTER :: regions(:)
  TYPE(t_plag)  , POINTER :: pplag

!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_PostProcessing.F90,v $ $Revision: 1.5 $'

  ALLOCATE( global )

  global%nFunTree = 0
  CALL registerfunction( global,'ROCPART_Post', 'PLAG_PostProcessing.F90' )

! initialize global parameters ------------------------------------------------

  global%verbLevel = verbose_none

  global%flowType    = flow_steady  ! stationary flow
  global%currentTime = -1._rfreal   ! no physical time set
  global%currentIter = -1           ! no iteration

  global%inDir  = './'              ! directory path
  global%outDir = './'

  global%nProcAlloc = 1
  global%myProcid   = masterproc    ! default process number (not an MPI code)
  global%mpierr     = err_none
  global%error      = err_none

  global%pi  = 4._rfreal*atan(1._rfreal)
  global%rad = global%pi/180._rfreal

  global%startLevel = 1
  
! print header ----------------------------------------------------------------

#ifdef MPI
  CALL mpi_init( global%mpierr )
  IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
#endif

  CALL buildversionstring( versionstring )

  headerstring = ' '
  versionwidth = len_trim(versionstring)
  margin       = (headerwidth-versionwidth)/2
  headerstring(margin+1:margin+versionwidth) = versionstring(1:versionwidth)
  headerstring(1:1) = '*'
  headerstring(headerwidth:headerwidth) = '*'

  WRITE(stdout,'(/,A)') solver_name//'  *****************************************************'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  *        ROCPART: Solution Postprocessing           *'
  WRITE(stdout,  '(A)') solver_name//'  *        ================================           *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,  '(A)') solver_name//'  '//trim(headerstring)
  WRITE(stdout,  '(A)') solver_name//'  *    Copyright (c) by the University of Illinois    *'
  WRITE(stdout,  '(A)') solver_name//'  *                                                   *'
  WRITE(stdout,'(A,/)') solver_name//'  *****************************************************'

! read argument list ----------------------------------------------------------

  CALL getarg(1,global%casename)
  CALL getarg(2,stamp)
  CALL getarg(3,outfmt)
  CALL getarg(4,verbosity)

  IF (len_trim(global%casename)==0 .OR. &
      len_trim(stamp)==0           .OR. &
      len_trim(verbosity)==0       .OR. &
      len_trim(outfmt)==0) THEN
    WRITE(stdout,'(/,A,/,A,/,9(A,/))') &
      solver_name//' Usage: plagpost <casename> <time> <format> <verbosity>', &
      solver_name, &
      solver_name//'        time      = time ', &
      solver_name//' ', &
      solver_name//'        format    = 3 - Tecplot ASCII',&
      solver_name//' ', &
      solver_name//'        verbosity = 0-2 '
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF

  READ(outfmt ,*) outputformat
  
  IF (outputformat <= 1) THEN
    outputformat = plot_fmt_generic
  ELSE IF (outputformat == 2) THEN
    outputformat = plot_fmt_tecplot
  ELSE
    outputformat = plot_fmt_tecascii
  ENDIF

! check for TECPLOT library

#ifdef NO_TECPLOT
  IF (outputformat == plot_fmt_tecplot) THEN
    WRITE(stdout,'(/,A,/)') solver_name// &
                            ' Sorry, not linked to TECPLOT library.'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop
  ENDIF
#endif

  READ(verbosity,*) global%verbLevel

! read region topology --------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading region topology ...'

  CALL rflo_readregiontopology( global,regions )

  DO ireg=1,global%nRegions
    regions(ireg)%startLevel = global%startLevel
    regions(ireg)%currLevel  = global%startLevel
    IF (regions(ireg)%nGridLevels < regions(ireg)%currLevel) THEN
      WRITE(msg,1000) solver_name,ireg,global%startLevel
      CALL errorstop( global,err_grid_level,__line__,msg )
    ENDIF
  ENDDO

! get user parameters ---------------------------------------------------------

  WRITE(stdout,'(/,A)') solver_name//' Reading user input ...'

  CALL rflo_initinputvalues( regions )
  CALL readinputfile( regions )
  CALL plag_userinput( regions )

  IF (global%flowType == flow_steady) THEN
    WRITE(stdout,'(/,A,/)') solver_name// &
                            ' Sorry, unable to run Rocpart Post-processing ', &
                            ' tool for steady state case.'
#ifdef MPI
    CALL mpi_finalize( global%mpierr )
#endif
    stop   
  ELSE
    READ(stamp,*) global%timeStamp
    global%currentTime = global%timeStamp
  ENDIF

  CALL rflo_derivedinputvalues( regions )

#ifndef PLAG
  WRITE(stdout,'(/,A,/)') solver_name// &
                          ' Sorry, unable to run Rocpart Post-processing ', &
                          ' tool since code was not compiled with PLAG.'
#ifdef MPI
  CALL mpi_finalize( global%mpierr )
#endif
  stop
#endif

#ifdef STATS
  statsactive = ( (global%plagUsed .EQV. .true.)     .AND. &
                  (global%flowType == flow_unsteady) .AND. &
                  (global%doStat == active)                )
#endif

! allocate memory -------------------------------------------------------------

  WRITE(stdout,'(A)') solver_name// &
                        ' Reading ROCPART solution and writing plot file ...'

  DO ireg=1,global%nRegions
    CALL plag_allocatememorypost( regions(ireg), ireg )
  ENDDO   ! iReg
  
! read solution ---------------------------------------------------------------

  CALL plag_readsolutionfilepost( regions )

! initialize cumulative sum ---------------------------------------------------

  npclssum = 0

! write data ------------------------------------------------------------------

  DO ireg=1,global%nRegions

    WRITE(stdout,'(A,I5.5)') solver_name//'   - region ',ireg
    
    ilev =  regions(ireg)%currLevel

! - compute cumulative number of particles in all regions

    npclssum = npclssum + regions(ireg)%levels(ilev)%plag%nPcls 

    IF ( ireg == global%nRegions ) &
      WRITE(stdout,'(A,I8.8)') 'Total Number of Particles = ',npclssum  
        
! - calculate derived variables

    CALL plag_calcderivedvariables( regions(ireg) )

! - write data 

    SELECT CASE ( outputformat )

! -- write data to TECPLOT file (ASCII)

      CASE ( plot_fmt_tecascii ) 
        CALL plag_writetecplotascii( ireg,ilev,regions(ireg) )

      CASE default
        CALL errorstop(global,err_reached_default,__line__)
    END SELECT ! outputFormat
  ENDDO   ! iReg

! write bined particle data at nozzle inlet (ASCII format)

  DO ireg=1,global%nRegions
    IF ( ireg == 41 .OR. ireg == 52 ) THEN
      iregbin = ireg
      CALL plag_binsortnozzleinlet( ireg,ilev,regions(ireg), iregbin )
      CALL plag_binsortspatialdist( ireg,ilev,regions(ireg), iregbin )
    END IF ! iReg 
  ENDDO   ! iReg

! process Eulerian grid-based data for PLAG -----------------------------------

  DO ireg=1,global%nRegions
    CALL plag_processeulerfield( regions,ireg,npclssum )    
  ENDDO   ! iReg
  
! deallocate memory -----------------------------------------------------------

  DO ireg=1,global%nRegions
    CALL plag_deallocatememorypost( regions(ireg), ireg )
  ENDDO   ! iReg

! ******************************************************************************
! Save currentTime as global value is clobbered by RFLO_ReadGridRegion
! ******************************************************************************
  
  global%currentTime = global%timeStamp

! process Eulerian grid-based statistics data for PLAG ------------------------

#ifdef STATS
  IF ( statsactive .EQV. .true. ) THEN 

! - trap error if expected number of statistics is less then set value  -------

    IF ( global%plagNStat > 0 ) THEN
      IF ( global%plagNStat < nstats_tec_plag ) &
        CALL errorstop( global,err_stats_tecplot,__line__, &
                        'plagNStat < NSTATS_TEC_PLAG' )
    ENDIF ! plagNStat > 0

! - write tecplot statistics file ---------------------------------------------
    
    DO ireg=1,global%nRegions

! -- allocate memory ----------------------------------------------------------

      IF ( ireg== 1 .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Allocating memory for statistics...'
      END IF ! global%verbLevel
      
      DO ilev=1,regions(ireg)%nGridLevels
        pplag => regions(ireg)%levels(ilev)%plag
        CALL plag_createstat( regions(ireg), pplag )
      END DO ! iLev

      IF ( ireg == global%nRegions .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Allocating memory for statistics done...'
      END IF ! global%verbLevel
      
! -- read statistics file ------------------------------------------------------
      
      IF ( ireg== 1 .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Reading statistics solution file for PLAG...'
      END IF ! global%verbLevel
      
      CALL plag_readstatpost( regions,ireg )    

      IF ( ireg == global%nRegions .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Reading statistics solution file for PLAG done...'
      END IF ! global%verbLevel
      
! -- write data to file --------------------------------------------------------

      WRITE(stdout,'(A,I5.5)') solver_name//'   Statistics - region ',ireg

      SELECT CASE ( outputformat )

! --- TECPLOT file (ASCII) -----------------------------------------------------

        CASE ( plot_fmt_tecascii ) 
          CALL plag_writestattecascii( regions,ireg )

        CASE default
          CALL errorstop(global,err_reached_default,__line__)
      END SELECT ! outputFormat
 
! -- deallocate memory ---------------------------------------------------------

      IF ( ireg== 1 .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Deallocating memory for statistics...'
      END IF ! global%verbLevel
      
      DO ilev=1,regions(ireg)%nGridLevels
        pplag => regions(ireg)%levels(ilev)%plag
        CALL plag_destroystat( regions(ireg), pplag )
      END DO ! iLev

      IF ( ireg == global%nRegions .AND. global%myProcid == masterproc .AND. &                              
           global%verbLevel > verbose_none ) THEN
        WRITE(stdout,'(A,3X,A)') solver_name,'Deallocating memory for statistics done...'
      END IF ! global%verbLevel
        
    ENDDO   ! iReg


  ENDIF ! statsActive
#endif
   
! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

  WRITE(stdout,'(/,A)') solver_name//' Finished.'

#ifdef MPI
  CALL mpi_finalize( global%mpierr )
#endif

1000 FORMAT(a,' Region ',i5,', grid level= ',i2,'.')

END PROGRAM rocpart_post

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_PostProcessing.F90,v $
! Revision 1.5  2008/12/06 08:45:07  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:18:18  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2005/02/16 23:44:16  fnajjar
! Moved statistics-specific routines inside ifdef construct
!
! Revision 1.2  2005/02/16 14:49:23  fnajjar
! Added infrastructure to write Tecplot-based statistics file
!
! Revision 1.1  2004/12/01 22:00:46  fnajjar
! Initial revision after changing case
!
! Revision 1.8  2004/11/17 22:13:17  fnajjar
! Cosmetic changes, removed support for enhanced Tecplot files and added call for eulerian data processing
!
! Revision 1.7  2004/11/13 21:58:48  fnajjar
! Added spatial binary sort and streamlined calls to binary sorts
!
! Revision 1.6  2004/06/29 14:06:19  fnajjar
! Removed call to interpolation of mixture properties since mixture data not allocated
!
! Revision 1.5  2004/05/24 14:24:18  fnajjar
! Included interpolation for mixture and binning routine
!
! Revision 1.4  2004/03/20 23:47:52  fnajjar
! Updated executable name in error trapping from rplagpost to plagpost
!
! Revision 1.3  2003/07/30 23:21:53  fnajjar
! Included cumulative sum of particles in IO
!
! Revision 1.2  2003/05/28 13:57:36  fnajjar
! Removed IndIJK as being an obsolete option
!
! Revision 1.1.1.1  2003/05/06 16:14:38  fnajjar
! Import of postprocessing tool for Rocpart
!
!******************************************************************************