PLAG_CalcDerivedVariables.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update PLAG derived variables (dv) arrays.
!
! Description: none.
!
! Input: region = current region.
!
! Output: region%levels%plag%dv
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PLAG_CalcDerivedVariables.F90,v 1.3 2008/12/06 08:44:33 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE plag_calcderivedvariables( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modpartlag, ONLY    : t_plag, t_plag_input
  USE moderror
  USE modparameters
  USE plag_modparameters
  IMPLICIT NONE

! ... parameters
  TYPE(t_region), INTENT(INOUT), TARGET :: region

! ... loop variables
  INTEGER :: icont, ipcls

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

#ifdef RFLO
  INTEGER :: ilev
#endif
  INTEGER :: ncont, npcls
  INTEGER, POINTER, DIMENSION(:)   :: pcvplagmass, pdvplagvolu
  INTEGER, POINTER, DIMENSION(:,:) :: paiv

  REAL(RFREAL) :: heatcapsum, masssum, masssumr, &
                  onethird, pi, pir, volusum
  REAL(RFREAL), POINTER, DIMENSION(:)   :: pdens, pmixtvol, pspcheat
  REAL(RFREAL), POINTER, DIMENSION(:,:) :: pcv, pdv
  
  TYPE(t_plag)  , POINTER :: pplag
  TYPE(t_global), POINTER :: global  
  
!******************************************************************************

  rcsidentstring = '$RCSfile: PLAG_CalcDerivedVariables.F90,v $ $Revision: 1.3 $'
  
  global => region%global
  
  CALL registerfunction( global, 'PLAG_CalcDerivedVariables',&
  'PLAG_CalcDerivedVariables.F90' )

! Get dimensions --------------------------------------------------------------

  onethird = 1.0_rfreal/3.0_rfreal  
  pi       = global%pi
  pir      = 1.0_rfreal/pi

#ifdef RFLO  
  ilev  = region%currLevel
  npcls = region%levels(ilev)%plag%nPcls
#endif
#ifdef RFLU
  npcls = region%plag%nPcls
#endif
  ncont = region%plagInput%nCont
  
! Set pointers ----------------------------------------------------------------

#ifdef RFLO  
  pmixtvol  => region%levels(ilev)%grid%vol     
  pplag     => region%levels(ilev)%plag
#endif
#ifdef RFLU
  pmixtvol  => region%grid%vol
  pplag     => region%plag
#endif

  paiv   => pplag%aiv  
  pcv    => pplag%cv
  pdv    => pplag%dv
  
  pcvplagmass => pplag%cvPlagMass
  pdvplagvolu => pplag%dvPlagVolu
  
  pdens     => region%plagInput%dens
  pspcheat  => region%plagInput%spht
  
! Calculate derived variables for Lagrangian field ----------------------------

  DO ipcls = 1, npcls

!- Compute particle mass ------------------------------------------------------

    masssum  = sum( pcv(pplag%cvPlagMass(:),ipcls) )    
    masssumr = 1.0_rfreal/masssum
    
!- Compute particle volume for each constituent -------------------------------  
  
    DO icont = 1, ncont
      pdv(pdvplagvolu(icont),ipcls) = pcv(pcvplagmass(icont),ipcls) / &
                                          pdens(icont)
    END DO ! iCont   
      
!- Compute particle volume ----------------------------------------------------

    volusum  = sum( pdv(pdvplagvolu(:),ipcls) )
      
!- Compute particle heat capacity ---------------------------------------------
     
    heatcapsum  = sum(pcv(pcvplagmass(:),ipcls) * pspcheat(:) )

!- Extract derived variables -------------------------------------------------- 
          
    pdv(dv_plag_uvel,ipcls) = pcv(cv_plag_xmom,ipcls) * masssumr
    pdv(dv_plag_vvel,ipcls) = pcv(cv_plag_ymom,ipcls) * masssumr
    pdv(dv_plag_wvel,ipcls) = pcv(cv_plag_zmom,ipcls) * masssumr
    
    pdv(dv_plag_dens,ipcls) = masssum/volusum
    pdv(dv_plag_diam,ipcls) = (6.0_rfreal*pir*volusum)**onethird
    pdv(dv_plag_area,ipcls) = (9.0_rfreal*pi *volusum/16.0_rfreal)**onethird    
    
    pdv(dv_plag_spht,ipcls) = heatcapsum * masssumr
    pdv(dv_plag_temp,ipcls) = (           pcv(cv_plag_ener,ipcls)*masssumr &
                            - 0.5_rfreal*(pdv(dv_plag_uvel,ipcls)**2       &
                                         +pdv(dv_plag_vvel,ipcls)**2       &
                                         +pdv(dv_plag_wvel,ipcls)**2 ) )/  &
                               pdv(dv_plag_spht,ipcls)
    
    pdv(dv_plag_volu,ipcls) = volusum       
  END DO  ! iPcls 

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE plag_calcderivedvariables

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PLAG_CalcDerivedVariables.F90,v $
! Revision 1.3  2008/12/06 08:44:33  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:45  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 20:57:01  fnajjar
! Initial revision after changing case
!
! Revision 1.6  2004/03/26 21:27:03  fnajjar
! Set particle volume in dv array
!
! Revision 1.5  2004/03/02 21:50:03  jferry
! Changed name of DV_PLAG_HTCP to DV_PLAG_SPHT
!
! Revision 1.4  2004/02/06 21:18:20  fnajjar
! Initial Integration of Rocpart with Rocflu
!
! Revision 1.3  2003/01/16 20:15:11  f-najjar
! Removed iRegionGlobal
!
! Revision 1.2  2002/12/03 19:55:37  f-najjar
! Fixed subroutine string name in RegisterFunction
!
! Revision 1.1  2002/10/25 14:14:44  f-najjar
! Initial Import of Rocpart
!
!
!******************************************************************************