PEUL_CentralFlux.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective fluxes for smoke by average of variables.
!
! Description: none.
!
! Input: region = data of current region.
!
! Output: region%levels%peul%rhs = convective fluxes added to the residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_CentralFlux.F90,v 1.3 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_centralflux( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE inrt_modparameters

  USE modinterfaces,      ONLY : rflo_getdimensphys, rflo_getcelloffset, &
                                 rflo_getnodeoffset
  USE peul_modinterfaces, ONLY : peul_centralfluxpatch
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i,j,k,ipatch,ipt

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ipcbeg,ipcend,jpcbeg,jpcend,kpcbeg,kpcend,nptypes
  INTEGER :: ilev,icoff,ijcoff,inoff,ijnoff,ijkc0,ijkc1,ijkn,indsvel

  REAL(RFREAL) :: srhoa,grhoa,grhoua,grhova,grhowa,vcont,ds,svel,fc
  REAL(RFREAL), POINTER :: scv(:,:),gcv(:,:),srhs(:,:)
  REAL(RFREAL), POINTER :: si(:,:),sj(:,:),sk(:,:)
  REAL(RFREAL), POINTER :: sivel(:),sjvel(:),skvel(:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_CentralFlux.F90,v $ $Revision: 1.3 $'

  global => region%global

  CALL registerfunction( global,'PEUL_CentralFlux',&
  'PEUL_CentralFlux.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  gcv    => region%levels(ilev)%mixt%cv
  scv    => region%levels(ilev)%peul%cv
  srhs   => region%levels(ilev)%peul%rhs
  si     => region%levels(ilev)%grid%si
  sj     => region%levels(ilev)%grid%sj
  sk     => region%levels(ilev)%grid%sk
  sivel  => region%levels(ilev)%grid%siVel
  sjvel  => region%levels(ilev)%grid%sjVel
  skvel  => region%levels(ilev)%grid%skVel
  indsvel = region%levels(ilev)%grid%indSvel

  nptypes = region%peulInput%nPtypes
  IF (nptypes /= region%levels(ilev)%peul%nCv) &
    CALL errorstop( global,err_peul_npmismatch,__line__ )

! flux in i-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg+1,ipcend
        ijkc0 = indijk(i  ,j,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k,icoff,ijcoff)
        ijkn  = indijk(i  ,j,k,inoff,ijnoff)

        ds    = sqrt(si(xcoord,ijkn)*si(xcoord,ijkn)+ &
                     si(ycoord,ijkn)*si(ycoord,ijkn)+ &
                     si(zcoord,ijkn)*si(zcoord,ijkn))
        svel  = sivel(ijkn*indsvel)*ds

        grhoa  = 0.5_rfreal*(gcv(cv_mixt_dens,ijkc0)+gcv(cv_mixt_dens,ijkc1))
        grhoua = 0.5_rfreal*(gcv(cv_mixt_xmom,ijkc0)+gcv(cv_mixt_xmom,ijkc1))
        grhova = 0.5_rfreal*(gcv(cv_mixt_ymom,ijkc0)+gcv(cv_mixt_ymom,ijkc1))
        grhowa = 0.5_rfreal*(gcv(cv_mixt_zmom,ijkc0)+gcv(cv_mixt_zmom,ijkc1))

        vcont = (grhoua*si(xcoord,ijkn)+grhova*si(ycoord,ijkn)+&
                 grhowa*si(zcoord,ijkn))/grhoa - svel

        DO ipt=1,nptypes
          srhoa = 0.5_rfreal*(scv(ipt,ijkc0)+scv(ipt,ijkc1))
          fc    = vcont*srhoa
          srhs(ipt,ijkc0) = srhs(ipt,ijkc0) + fc
          srhs(ipt,ijkc1) = srhs(ipt,ijkc1) - fc
        ENDDO ! ipt

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in j-direction (except through boundary) -------------------------------

  DO k=kpcbeg,kpcend
    DO j=jpcbeg+1,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k,icoff,ijcoff)
        ijkn  = indijk(i,j  ,k,inoff,ijnoff)

        ds    = sqrt(sj(xcoord,ijkn)*sj(xcoord,ijkn)+ &
                     sj(ycoord,ijkn)*sj(ycoord,ijkn)+ &
                     sj(zcoord,ijkn)*sj(zcoord,ijkn))
        svel  = sjvel(ijkn*indsvel)*ds

        grhoa  = 0.5_rfreal*(gcv(cv_mixt_dens,ijkc0)+gcv(cv_mixt_dens,ijkc1))
        grhoua = 0.5_rfreal*(gcv(cv_mixt_xmom,ijkc0)+gcv(cv_mixt_xmom,ijkc1))
        grhova = 0.5_rfreal*(gcv(cv_mixt_ymom,ijkc0)+gcv(cv_mixt_ymom,ijkc1))
        grhowa = 0.5_rfreal*(gcv(cv_mixt_zmom,ijkc0)+gcv(cv_mixt_zmom,ijkc1))

        vcont = (grhoua*sj(xcoord,ijkn)+grhova*sj(ycoord,ijkn)+&
                 grhowa*sj(zcoord,ijkn))/grhoa - svel

        DO ipt=1,nptypes
          srhoa = 0.5_rfreal*(scv(ipt,ijkc0)+scv(ipt,ijkc1))
          fc    = vcont*srhoa
          srhs(ipt,ijkc0) = srhs(ipt,ijkc0) + fc
          srhs(ipt,ijkc1) = srhs(ipt,ijkc1) - fc
        ENDDO ! ipt

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! flux in k-direction (except through boundary) -------------------------------

  DO k=kpcbeg+1,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc0 = indijk(i,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j,k-1,icoff,ijcoff)
        ijkn  = indijk(i,j,k  ,inoff,ijnoff)

        ds    = sqrt(sk(xcoord,ijkn)*sk(xcoord,ijkn)+ &
                     sk(ycoord,ijkn)*sk(ycoord,ijkn)+ &
                     sk(zcoord,ijkn)*sk(zcoord,ijkn))
        svel  = skvel(ijkn*indsvel)*ds

        grhoa  = 0.5_rfreal*(gcv(cv_mixt_dens,ijkc0)+gcv(cv_mixt_dens,ijkc1))
        grhoua = 0.5_rfreal*(gcv(cv_mixt_xmom,ijkc0)+gcv(cv_mixt_xmom,ijkc1))
        grhova = 0.5_rfreal*(gcv(cv_mixt_ymom,ijkc0)+gcv(cv_mixt_ymom,ijkc1))
        grhowa = 0.5_rfreal*(gcv(cv_mixt_zmom,ijkc0)+gcv(cv_mixt_zmom,ijkc1))

        vcont = (grhoua*sk(xcoord,ijkn)+grhova*sk(ycoord,ijkn)+&
                 grhowa*sk(zcoord,ijkn))/grhoa - svel

        DO ipt=1,nptypes
          srhoa = 0.5_rfreal*(scv(ipt,ijkc0)+scv(ipt,ijkc1))
          fc    = vcont*srhoa
          srhs(ipt,ijkc0) = srhs(ipt,ijkc0) + fc
          srhs(ipt,ijkc1) = srhs(ipt,ijkc1) - fc
        ENDDO ! ipt

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! fluxes through boundaries ---------------------------------------------------

  DO ipatch=1,region%nPatches
    CALL peul_centralfluxpatch( region,region%levels(ilev)%patches(ipatch) )
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_centralflux

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_CentralFlux.F90,v $
! Revision 1.3  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/12/01 21:09:26  haselbac
! Initial revision after changing case
!
! Revision 1.7  2004/07/28 15:42:13  jferry
! deleted defunct constructs: useDetangle, useSmokeDrag, useSmokeHeatTransfer
!
! Revision 1.6  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.5  2003/09/25 15:42:57  jferry
! Added mixture source terms due to active smoke (for Detangle interaction)
!
! Revision 1.4  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.3  2003/05/01 22:57:24  jferry
! substituted macro for IndIJK
!
! Revision 1.2  2003/04/07 18:29:01  jferry
! added inflow boundary condition and initialization to a constant
!
! Revision 1.1  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
!******************************************************************************