PEUL_CentralFluxPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute central convective fluxes for smoke through a patch
!          by using an average of variables.
!
! Description: none.
!
! Input: region = data of current region
!        patch  = current patch.
!
! Output: region%levels%peul%rhs = convective fluxes added to the residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: PEUL_CentralFluxPatch.F90,v 1.5 2008/12/06 08:44:39 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE peul_centralfluxpatch( region,patch )

  USE moddatatypes
  USE modbndpatch,   ONLY : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE moderror
  USE modparameters
  USE peul_modparameters
  USE inrt_modparameters

  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset, rflo_getnodeoffset
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region
  TYPE(t_patch),  INTENT(IN)    :: patch

! ... loop variables
  INTEGER :: i,j,k,ipt

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ilev,lobound,bctype,nptypes,n1,n2
  INTEGER :: ibeg,iend,jbeg,jend,kbeg,kend,idir,jdir,kdir,noff
  INTEGER :: icoff,ijcoff,inoff,ijnoff,ijkcd,ijkcb0,ijknb
  INTEGER :: inode,jnode,knode,indcp,indmol
  INTEGER :: mixtdistrib,peuldistrib,mixti2d,peuli2d,gasmodel

  REAL(RFREAL) :: grhoa,grhoua,grhova,grhowa,grhoea
  REAL(RFREAL) :: sgn,sf(3),ds,vcont,mrate
  REAL(RFREAL) :: tburn,rhovrel(3),pa,uinj,vinj,winj,vf
  REAL(RFREAL), POINTER :: scv(:,:),gcv(:,:),gdv(:,:),ggv(:,:)
  REAL(RFREAL), POINTER :: srhs(:,:)
  REAL(RFREAL), POINTER :: sface(:,:),mixtvals(:,:),peulvals(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  rcsidentstring = '$RCSfile: PEUL_CentralFluxPatch.F90,v $ $Revision: 1.5 $'

  global => region%global

  CALL registerfunction( global,'PEUL_CentralFluxPatch',&
  'PEUL_CentralFluxPatch.F90' )

! begin -----------------------------------------------------------------------

! get dimensions and pointers -------------------------------------------------

  ilev    = region%currLevel
  lobound = patch%lbound

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  bctype      = patch%bcType
  noff        = abs(patch%l1end-patch%l1beg) + 1
  mixtdistrib = patch%mixt%distrib
  peuldistrib = patch%peul%distrib
  indcp       = region%levels(ilev)%mixt%indCp
  indmol      = region%levels(ilev)%mixt%indMol
  gasmodel   = region%mixtInput%gasModel

  gcv  => region%levels(ilev)%mixt%cv
  gdv  => region%levels(ilev)%mixt%dv
  ggv  => region%levels(ilev)%mixt%gv
  scv  => region%levels(ilev)%peul%cv
  srhs => region%levels(ilev)%peul%rhs

  nptypes = region%peulInput%nPtypes
  IF (region%levels(ilev)%peul%nCv /= nptypes) &
    CALL errorstop( global,err_peul_npmismatch,__line__ )

  mixtvals => patch%mixt%vals

  nullify(peulvals)
  IF (ASSOCIATED(patch%peul%vals)) THEN
    peulvals => patch%peul%vals
    IF (lbound(peulvals,1) /= 1 .OR. ubound(peulvals,1) /= nptypes) &
      CALL errorstop( global,err_peul_npmismatch,__line__ )
  ENDIF

! to take the right face vector and make it point outwards

  sgn   = +1._rfreal
  inode = 0
  jnode = 0
  knode = 0
  IF (lobound==2 .OR. lobound==4 .OR. lobound==6) THEN
    sgn   = -1._rfreal
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

! get the appropriate face vector and grid speed

  SELECT CASE (lobound)
  CASE (1:2)
    sface => region%levels(ilev)%grid%si
  CASE (3:4)
    sface => region%levels(ilev)%grid%sj
  CASE (5:6)
    sface => region%levels(ilev)%grid%sk
  END SELECT

! stationary grid -------------------------------------------------------------

  SELECT CASE(bctype)

! no mass flux for these cases

  CASE (bc_slipwall  :bc_slipwall  +bc_range, &
        bc_noslipwall:bc_noslipwall+bc_range, &
        bc_symmetry  :bc_symmetry  +bc_range)

! injection boundary (no mass flux if mass flow rate <= 0)

  CASE (bc_injection:bc_injection+bc_range)

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend

          SELECT CASE (lobound)

          CASE (1:2)
            n1 = j - jbeg
            n2 = k - kbeg
          CASE (3:4)
            n1 = k - kbeg
            n2 = i - ibeg
          CASE (5:6)
            n1 = i - ibeg
            n2 = j - jbeg

          END SELECT ! lobound

          mixti2d = mixtdistrib * indij(n1,n2,noff)
          mrate   = mixtvals(bcdat_inject_mfrate,mixti2d)

! ------- only need to augment source terms when there is a mass flux
! ------- (in contrast to gas case, where there is always a pressure term)

          IF (mrate > 0._rfreal) THEN

            peuli2d = peuldistrib * indij(n1,n2,noff)
            ijkcb0  = indijk(i,j,k,icoff,ijcoff)
            ijkcd   = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)
            ijknb   = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)

            sf(1) = sgn*sface(xcoord,ijknb)
            sf(2) = sgn*sface(ycoord,ijknb)
            sf(3) = sgn*sface(zcoord,ijknb)

            tburn      = mixtvals(bcdat_inject_temp  ,mixti2d)
            rhovrel(1) = mixtvals(bcdat_inject_rfvfu ,mixti2d)
            rhovrel(2) = mixtvals(bcdat_inject_rfvfv ,mixti2d)
            rhovrel(3) = mixtvals(bcdat_inject_rfvfw ,mixti2d)

            ds = sqrt(sf(1)*sf(1)+sf(2)*sf(2)+sf(3)*sf(3))
            IF (gasmodel == gas_model_tcperf) THEN
              CALL bcondinjectionperf( mixtdistrib,mrate,tburn,rhovrel,   &
                                       sf(1)/ds,sf(2)/ds,sf(3)/ds,        &
                                       ggv(gv_mixt_cp  ,ijkcb0*indcp ),   &
                                       ggv(gv_mixt_mol ,ijkcb0*indmol),   &
                                       gdv(dv_mixt_pres,ijkcb0       ),   &
                                       grhoa,grhoua,grhova,grhowa,grhoea, &
                                       pa,uinj,vinj,winj )
            ELSE
              CALL errorstop( region%global,err_unknown_bc,__line__ )
            ENDIF ! gasModel

            vcont = uinj*sf(1) + vinj*sf(2) + winj*sf(3)

            DO ipt=1,nptypes
              vf = vcont*peulvals(ipt,peuli2d) ! i.e., vf = vcont*sRhoa/gRhoa
              srhs(ipt,ijkcb0) = srhs(ipt,ijkcb0) + vf*grhoa
            END DO ! ipt

          END IF ! mRate
        ENDDO    ! i
      ENDDO      ! j
    ENDDO        ! k

! do not know how to handle these yet

  CASE (bc_regionint :bc_regionint +bc_range)

  CASE (bc_regnonconf:bc_regnonconf+bc_range)

! everything else

  CASE default

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! boundary
          ijkcd  = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)  ! dummy
          ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)

          grhoa  = 0.5_rfreal*(gcv(cv_mixt_dens,ijkcb0) + &
                               gcv(cv_mixt_dens,ijkcd))
          grhoua = 0.5_rfreal*(gcv(cv_mixt_xmom,ijkcb0) + &
                               gcv(cv_mixt_xmom,ijkcd))
          grhova = 0.5_rfreal*(gcv(cv_mixt_ymom,ijkcb0) + &
                               gcv(cv_mixt_ymom,ijkcd))
          grhowa = 0.5_rfreal*(gcv(cv_mixt_zmom,ijkcb0) + &
                               gcv(cv_mixt_zmom,ijkcd))

          sf(1) = sgn*sface(xcoord,ijknb)
          sf(2) = sgn*sface(ycoord,ijknb)
          sf(3) = sgn*sface(zcoord,ijknb)

          vcont = (grhoua*sf(1)+grhova*sf(2)+grhowa*sf(3))/grhoa

          DO ipt=1,nptypes
            srhs(ipt,ijkcb0) = srhs(ipt,ijkcb0) + &
              0.5_rfreal*vcont*(scv(ipt,ijkcb0)+scv(ipt,ijkcd))
          END DO ! ipt

        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

  END SELECT    ! bcType

! moving grid (add grid speeds) -----------------------------------------------

  IF (region%mixtInput%moveGrid) THEN
    CALL errorstop( global,err_peul_movegrid,__line__ )
  ENDIF         ! moveGrid

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE peul_centralfluxpatch

!******************************************************************************
!
! RCS Revision history:
!
! $Log: PEUL_CentralFluxPatch.F90,v $
! Revision 1.5  2008/12/06 08:44:39  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:51  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:40:20  mparmar
! Renamed patch variables
!
! Revision 1.2  2005/10/31 21:09:37  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.1  2004/12/01 21:09:27  haselbac
! Initial revision after changing case
!
! Revision 1.8  2004/07/28 15:42:13  jferry
! deleted defunct constructs: useDetangle, useSmokeDrag, useSmokeHeatTransfer
!
! Revision 1.7  2004/03/05 22:09:04  jferry
! created global variables for peul, plag, and inrt use
!
! Revision 1.6  2003/09/25 15:42:57  jferry
! Added mixture source terms due to active smoke (for Detangle interaction)
!
! Revision 1.5  2003/05/15 02:57:05  jblazek
! Inlined index function.
!
! Revision 1.4  2003/05/05 17:26:57  jferry
! fixed bug in setting n1, n2
!
! Revision 1.3  2003/04/09 15:11:31  jferry
! removed dependence on temporary storage structures
!
! Revision 1.2  2003/04/07 18:29:01  jferry
! added inflow boundary condition and initialization to a constant
!
! Revision 1.1  2003/02/11 22:52:50  jferry
! Initial import of Rocsmoke
!
!******************************************************************************