rocstar/RFLO_SendBoundaryValues.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: store outgoing data into buffers for GenX.
!
! Description: none.
!
! Input: region     = dimensions of patches, types of BC`s, flow variables
!        initialize = initial data for GenX (true/false)..
!
! Output: regions%levels%patches = data in buffers for GenX.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: RFLO_SendBoundaryValues.F90,v 1.11 2010/02/18 21:47:38 juzhang Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_sendboundaryvalues( region,initialize )

  USE moddatatypes
  USE modglobal, ONLY     : t_global
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getpatchindicesnodes, rflo_getcelloffset, rflo_getnodeoffset, &
        mixtperf_r_m, mixtperf_d_prt
#ifdef PLAG
  USE modinterfaces, ONLY : plag_setsizegenx
#endif
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

  LOGICAL :: initialize

! ... loop variables
  INTEGER :: ipatch, i, j, k, ijkc, ijkd, ijkn, n1, n2, ng1, ng2

! ... local variables
  INTEGER :: ilev, bctype, lbnd, icoff, ijcoff, inoff, ijnoff, ijkn1
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: inode, jnode, knode, i2d, distrib, indmol, noff

  REAL(RFREAL)          :: sgn, ds, mrate, tburn, rgas, sxn, syn, szn, &
                           edgevector(3), deltn
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), gv(:,:), xyz(:,:), &
                           sface(:,:), vals(:,:)

  TYPE(t_global), POINTER :: global
  TYPE(t_patch) , POINTER :: patch

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_SendBoundaryValues',&
  'RFLO_SendBoundaryValues.F90' )

! store pointers to variables -------------------------------------------------

  ilev = region%currLevel
  !IF(initialize .eqv. .true.) THEN
  !   WRITE(*,*) 'RFLO: WARNING!! INITIALIZING in SENDBOUNDARYVALS!!'
  !ENDIF
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  indmol = region%levels(ilev)%mixt%indMol

  cv  => region%levels(ilev)%mixt%cv
  dv  => region%levels(ilev)%mixt%dv
  gv  => region%levels(ilev)%mixt%gv
  xyz => region%levels(ilev)%grid%xyz

! loop over all cells of the patch (if an interface)

  DO ipatch=1,region%nPatches

    patch   => region%levels(ilev)%patches(ipatch)
    bctype  =  patch%bcType
    lbnd  =  patch%lbound
    distrib =  patch%mixt%distrib
    noff    =  abs(patch%l1end-patch%l1beg) + 1
    vals    => patch%mixt%vals

    IF ( patch%bcCoupled == bc_external .OR. &   ! data from outside
        (patch%bcCoupled == bc_internal .AND. &  ! data from internal APN
         bctype == bc_injection_apn)) THEN        

      CALL rflo_getpatchindices( region,patch,ilev, &
                                 ibeg,iend,jbeg,jend,kbeg,kend )
      CALL rflo_getpatchdirection( patch,idir,jdir,kdir )

! --- to take the right face vector and make it point outwards

      sgn   = +1._rfreal
      inode = 0
      jnode = 0
      knode = 0
      IF (lbnd==2 .OR. lbnd==4 .OR. lbnd==6) THEN
        sgn   = -1._rfreal
        inode = -idir
        jnode = -jdir
        knode = -kdir
      ENDIF

! --- get the appropriate face vector

      IF (lbnd==1 .OR. lbnd==2) sface => region%levels(ilev)%grid%si
      IF (lbnd==3 .OR. lbnd==4) sface => region%levels(ilev)%grid%sj
      IF (lbnd==5 .OR. lbnd==6) sface => region%levels(ilev)%grid%sk

! --- outgoing data

      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkc = indijk(i      ,j      ,k      ,icoff,ijcoff)
            ijkd = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)
            ijkn = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
            ds   = sqrt(sface(xcoord,ijkn)*sface(xcoord,ijkn)+ &
                        sface(ycoord,ijkn)*sface(ycoord,ijkn)+ &
                        sface(zcoord,ijkn)*sface(zcoord,ijkn))
            sxn   = sgn*sface(xcoord,ijkn)/ds
            syn   = sgn*sface(ycoord,ijkn)/ds
            szn   = sgn*sface(zcoord,ijkn)/ds
  
            IF      (lbnd==1 .OR. lbnd==2) THEN
              n1 = j - jbeg
              n2 = k - kbeg
              ijkn1 = indijk(i+inode+1*idir,j+jnode,k+knode  ,inoff,ijnoff)
              IF (lbnd == 2) THEN
                ng1 = j - jbeg + 1
              ELSE
                ng1 = jend - j + 1
              ENDIF
              ng2 = k - kbeg + 1
            ELSE IF (lbnd==3 .OR. lbnd==4) THEN
              n1 = k - kbeg
              n2 = i - ibeg
              ijkn1 = indijk(i+inode,j+jnode+1*jdir,k+knode  ,inoff,ijnoff)
             IF (lbnd == 4) THEN
                ng2 = i - ibeg + 1
              ELSE
                ng2 = iend - i + 1
              ENDIF
              ng1 = k - kbeg + 1
            ELSE IF (lbnd==5 .OR. lbnd==6) THEN
              n1 = i - ibeg
              n2 = j - jbeg
              ijkn1 = indijk(i+inode,j+jnode,k+knode+1*kdir  ,inoff,ijnoff)
              IF (lbnd == 6) THEN
                ng1 = i - ibeg + 1
              ELSE
                ng1 = iend - i + 1
              ENDIF
              ng2 = j - jbeg + 1
            ENDIF
            IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN
              i2d   = distrib * indij(n1,n2,noff)
              mrate = vals(bcdat_inject_mfrate,i2d)
              tburn = vals(bcdat_inject_temp  ,i2d)

!  ----   cal distance from the centerroid to the center of the wall face (assuming body-fitted meshes)
              edgevector(1) = xyz(xcoord,ijkn1) - xyz(xcoord,ijkn)                
              edgevector(2) = xyz(ycoord,ijkn1) - xyz(ycoord,ijkn)                
              edgevector(3) = xyz(zcoord,ijkn1) - xyz(zcoord,ijkn)                
              deltn = 0.5*abs(sxn*edgevector(1)+syn*edgevector(2)+szn*edgevector(3))

              IF (bctype==bc_injection_apn) THEN
                patch%mdotAlp(    ng1,ng2) = mrate
                patch%tflmAlp(    ng1,ng2) = vals(bcdat_inject_temp  ,i2d)
                patch%rhofvfAlp(1,ng1,ng2) = vals(bcdat_inject_rfvfu ,i2d)
                patch%rhofvfAlp(2,ng1,ng2) = vals(bcdat_inject_rfvfv ,i2d)
                patch%rhofvfAlp(3,ng1,ng2) = vals(bcdat_inject_rfvfw ,i2d)
!                IF (mRate > 0._RFREAL) patch%bFlag(ng1,ng2) = 1
              ENDIF
              IF (initialize .eqv. .true.) THEN
                IF (mrate > 0._rfreal) THEN
                  patch%bFlag(ng1,ng2) = 1   ! face ignited
                ELSE
                  patch%bFlag(ng1,ng2) = 0   ! face not ignited yet
                ENDIF
              ENDIF

              IF (patch%bFlag(ng1,ng2) == 1) THEN    ! burning
                rgas                   = mixtperf_r_m( gv(gv_mixt_mol,ijkc*indmol) )
                patch%pf     (ng1,ng2) = dv(dv_mixt_pres,ijkc)
                patch%rhofAlp(ng1,ng2) = mixtperf_d_prt( dv(dv_mixt_pres,ijkc), &
                                                         rgas,tburn )
                patch%tempf  (ng1,ng2) = tburn
              ELSE                                   ! not burning
                patch%pf     (ng1,ng2) = 0.5_rfreal*(dv(dv_mixt_pres,ijkc)+ &
                                                     dv(dv_mixt_pres,ijkd))
                patch%rhofAlp(ng1,ng2) = 0.5_rfreal*(cv(cv_mixt_dens,ijkc)+ &
                                                     cv(cv_mixt_dens,ijkd))
                patch%tempf  (ng1,ng2) = 0.5_rfreal*(dv(dv_mixt_temp,ijkc)+ &
                                                     dv(dv_mixt_temp,ijkd))
              ENDIF
                patch%tempv  (ng1,ng2) = dv(dv_mixt_temp,ijkc)
              IF (bctype==bc_injection_ht) THEN
                patch%dnml   (ng1,ng2) = -deltn
             ELSE
                patch%dnml   (ng1,ng2) = deltn
              ENDIF
            ELSE                           ! not an injection boundary
              IF (initialize) THEN
                patch%bFlag(ng1,ng2) = 0   ! can never burn
              ENDIF
              patch%pf     (ng1,ng2) = 0.5_rfreal*(dv(dv_mixt_pres,ijkc)+ &
                                                   dv(dv_mixt_pres,ijkd))
              patch%rhofAlp(ng1,ng2) = 0.5_rfreal*(cv(cv_mixt_dens,ijkc)+ &
                                                   cv(cv_mixt_dens,ijkd))
              patch%tempf  (ng1,ng2) = 0.5_rfreal*(dv(dv_mixt_temp,ijkc)+ &
                                                   dv(dv_mixt_temp,ijkd))
            ENDIF
            patch%qc   (  ng1,ng2) = 0._rfreal
            patch%nfAlp(1,ng1,ng2) = sgn*sface(xcoord,ijkn)/ds
            patch%nfAlp(2,ng1,ng2) = sgn*sface(ycoord,ijkn)/ds
            patch%nfAlp(3,ng1,ng2) = sgn*sface(zcoord,ijkn)/ds
            patch%tracf(1,ng1,ng2) = patch%pf(ng1,ng2)*patch%nfAlp(1,ng1,ng2)
            patch%tracf(2,ng1,ng2) = patch%pf(ng1,ng2)*patch%nfAlp(2,ng1,ng2)
            patch%tracf(3,ng1,ng2) = patch%pf(ng1,ng2)*patch%nfAlp(3,ng1,ng2)
          ENDDO
        ENDDO
      ENDDO

    ENDIF  ! external BC

    IF (patch%bcMotion == bc_external) THEN        ! data from outside

! ----surface grid

      CALL rflo_getpatchindicesnodes( region,patch,ilev, &
                                      ibeg,iend,jbeg,jend,kbeg,kend )

      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkn = indijk(i,j,k,inoff,ijnoff)
            IF      (lbnd==1 .OR. lbnd==2) THEN
              IF (lbnd == 2) THEN
                ng1 = j - jbeg + 1
              ELSE
                ng1 = jend - j + 1
              ENDIF
              ng2 = k - kbeg + 1
            ELSE IF (lbnd==3 .OR. lbnd==4) THEN
              ng1 = k - kbeg + 1
              IF (lbnd == 4) THEN
                ng2 = i - ibeg + 1
              ELSE
                ng2 = iend - i + 1
              ENDIF
            ELSE IF (lbnd==5 .OR. lbnd==6) THEN
              IF (lbnd == 6) THEN
                ng1 = i - ibeg + 1
              ELSE
                ng1 = iend - i + 1
              ENDIF
              ng2 = j - jbeg + 1
            ENDIF
            patch%surfCoord(1,ng1,ng2) = xyz(xcoord,ijkn)
            patch%surfCoord(2,ng1,ng2) = xyz(ycoord,ijkn)
            patch%surfCoord(3,ng1,ng2) = xyz(zcoord,ijkn)
          ENDDO
        ENDDO
      ENDDO

    ENDIF  ! external Bc and motion
  ENDDO    ! iPatch

#ifdef PLAG
  IF (global%plagUsed)  CALL plag_setsizegenx( region )
#endif

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE rflo_sendboundaryvalues

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_SendBoundaryValues.F90,v $
! Revision 1.11  2010/02/18 21:47:38  juzhang
! Heat transfer bc for non-propellant surface documented in Rocburn_PY_HT.pdf in Rocburn_PY directory is implemented within Rocburn_PY. Major changes were made to Rocburn, Rocman3, RocfluidMP/genx, RocfluidMP/modflo directories.
!
! Revision 1.10  2008/12/06 08:44:01  mtcampbe
! Updated license.
!
! Revision 1.9  2008/11/19 22:17:15  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.8  2006/08/19 15:37:50  mparmar
! Renamed patch variables
!
! Revision 1.7  2006/01/25 06:04:03  wasistho
! set bflag for injectionAPN
!
! Revision 1.6  2006/01/25 04:32:11  wasistho
! added sending rhofvfalp and tflmalp for injectionAPN
!
! Revision 1.5  2006/01/23 22:44:21  wasistho
! added condition for internal injectionAPN
!
! Revision 1.4  2005/07/03 03:42:52  wasistho
! bcMotion external for surfCoord
!
! Revision 1.3  2005/02/01 21:18:00  wasistho
! reactivated bflag
!
! Revision 1.2  2005/01/20 20:05:49  wasistho
! temporary outcommented initial bflag condition
!
! Revision 1.1  2004/12/01 21:23:54  haselbac
! Initial revision after changing case
!
! Revision 1.18  2004/11/13 22:37:55  wasistho
! invert orientation of genx-surface-variables
!
! Revision 1.17  2004/07/02 22:07:19  fnajjar
! Added call to PLAG_SetSizeGenx for Roccom3 import
!
! Revision 1.16  2003/11/20 16:40:34  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.13  2003/08/14 20:06:58  jblazek
! Corrected bug associated with radiation flux qr.
!
! Revision 1.12  2003/08/09 02:14:14  wasistho
! restore version 1.10
!
! Revision 1.11  2003/08/09 02:09:26  wasistho
! added TURB and RADI_initGenxInterface
!
! Revision 1.10  2003/05/15 02:57:00  jblazek
! Inlined index function.
!
! Revision 1.9  2002/10/15 23:22:59  jblazek
! dded Rocturb to GenX compilation path.
!
! Revision 1.8  2002/10/15 17:51:35  jblazek
! And flippt the normals again ...
!
! Revision 1.7  2002/10/15 00:38:18  jblazek
! Added routine to send newest fluids density to GenX.
!
! Revision 1.6  2002/10/10 23:49:48  jblazek
! Changed orientation of surface grid.
!
! Revision 1.5  2002/10/03 21:33:48  jblazek
! Init. of bcflag moved from SendBoundaryValues to InitGenxInterface.
!
! Revision 1.4  2002/10/01 21:53:27  jiao
! Modified surface temperature evaluation for burning surfaces.
!
! Revision 1.3  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.2  2002/09/24 23:18:01  jblazek
! Changed bcflag to a pointer.
!
! Revision 1.1  2002/09/20 22:22:34  jblazek
! Finalized integration into GenX.
!
!******************************************************************************