rocstar/RFLO_GetDeformation.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: obtain deformation to boundary nodes from GenX.
!
! Description: none.
!
! Input: region     = grid dimensions and topology
!        boundMoved = flag for boundaries of region which have moved.
!
! Output: dNode = deformations at all six boundaries.
!
! Notes: variable dNode contains the whole 3-D field.
!
!******************************************************************************
!
! $Id: RFLO_GetDeformation.F90,v 1.8 2009/08/12 04:15:57 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE rflo_getdeformation( region,boundMoved,dNode )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getpatchindicesnodes, rflo_getnodeoffset, &
                            rflo_getdimensphysnodes
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  LOGICAL :: boundmoved(6)

  REAL(RFREAL), POINTER :: dnode(:,:)

  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: ipatch, i, j, k, ng1, ng2, ijkn

! ... local variables
  INTEGER :: ilev, lbound, ibeg, iend, jbeg, jend, kbeg, kend, inoff, ijnoff
  INTEGER :: ipnbeg, ipnend, jpnbeg, jpnend, kpnbeg, kpnend, nfixed
  LOGICAL, POINTER :: allexternal(:)

  TYPE(t_global), POINTER :: global
  TYPE(t_patch), POINTER  :: patch

  REAL(RFREAL) :: dextrem(1:2),dist

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'RFLO_GetDeformation',&
  'RFLO_GetDeformation.F90' )

! initialize variables --------------------------------------------------------

  ilev = 1     ! finest grid
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )
  CALL rflo_getdimensphysnodes( region,ilev,ipnbeg,ipnend, &
                                jpnbeg,jpnend,kpnbeg,kpnend )

! zero out displacements

  dnode(:,:) = 0._rfreal

! reset boundary movement flags

  allexternal => region%levels(ilev)%grid%allExternal
  boundmoved(:)  = .false.
  allexternal(:) = .false. 

! obtain displacements --------------------------------------------------------

  IF ( global%myProcid == 0 .AND. & 
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A,1X,I3)') solver_name, &
                                   'Getting displacements from Rocstar....'
  END IF ! global%myProcid


  DO ipatch=1,region%nPatches
    patch  => region%levels(ilev)%patches(ipatch)
    lbound =  patch%lbound
    dextrem(2) = 10.0_rfreal
    dextrem(1) = 0._rfreal
    nfixed = 0
    IF (patch%bcMotion == bc_external) THEN
       CALL rflo_getpatchindicesnodes( region,patch,ilev, &
            ibeg,iend,jbeg,jend,kbeg,kend )
       boundmoved(lbound) = .true.
       
       DO k=kbeg,kend
          DO j=jbeg,jend
             DO i=ibeg,iend
                ijkn = indijk(i,j,k,inoff,ijnoff)
                IF      (lbound==1 .OR. lbound==2) THEN
                   IF (lbound == 2) THEN
                      ng1 = j - jbeg + 1
                   ELSE
                      ng1 = jend - j + 1
                   ENDIF
                   ng2 = k - kbeg + 1
                ELSE IF (lbound==3 .OR. lbound==4) THEN
                   ng1 = k - kbeg + 1
                   IF (lbound == 4) THEN
                      ng2 = i - ibeg + 1
                   ELSE
                      ng2 = iend - i + 1
                   ENDIF
                ELSE IF (lbound==5 .OR. lbound==6) THEN
                   IF (lbound == 6) THEN
                      ng1 = i - ibeg + 1
                   ELSE
                      ng1 = iend - i + 1
                   ENDIF
                   ng2 = j - jbeg + 1
                ENDIF
                dnode(xcoord,ijkn) = patch%duAlp(1,ng1,ng2)
                dnode(ycoord,ijkn) = patch%duAlp(2,ng1,ng2)
                dnode(zcoord,ijkn) = patch%duAlp(3,ng1,ng2)
                dist = sqrt(dnode(xcoord,ijkn)*dnode(xcoord,ijkn) +&
                     dnode(ycoord,ijkn)*dnode(ycoord,ijkn) + &
                     dnode(zcoord,ijkn)*dnode(zcoord,ijkn))
                if(dist > dextrem(2)) dextrem(2) = dist
                if(dist < dextrem(1)) dextrem(1) = dist
                if(dist < 1e-12_rfreal) nfixed = nfixed + 1
             ENDDO
          ENDDO
       ENDDO
!       WRITE(*,*) 'MOTION EXTREMA FOR PATCH: ',dextrem(1),dextrem(2),nfixed
      IF (lbound==1 .OR. lbound==2) THEN
        IF (jbeg==jpnbeg .AND. jend==jpnend .AND. &
            kbeg==kpnbeg .AND. kend==kpnend) THEN
          allexternal(lbound) = .true.
        ENDIF
      ELSEIF (lbound==3 .OR. lbound==4) THEN
        IF (ibeg==ipnbeg .AND. iend==ipnend .AND. &
            kbeg==kpnbeg .AND. kend==kpnend) THEN
          allexternal(lbound) = .true.
        ENDIF
      ELSEIF (lbound==5 .OR. lbound==6) THEN
        IF (ibeg==ipnbeg .AND. iend==ipnend .AND. &
            jbeg==jpnbeg .AND. jend==jpnend) THEN
          allexternal(lbound) = .true.
        ENDIF
      ENDIF

    ELSE  ! external BC
 !     IF(patch%bcMotion .ne. BC_EXTERNAL) THEN
      IF (patch%mixt%setMotion .AND. &
         global%verbLevel >= verbose_high) THEN
         WRITE(*,*) 'SETTING MOTION ON PATCH '
        CALL rflo_getpatchindicesnodes( region,patch,ilev, &
                                        ibeg,iend,jbeg,jend,kbeg,kend )
        boundmoved(lbound) = .true.
      
        DO k=kbeg,kend
          DO j=jbeg,jend
            DO i=ibeg,iend
              ijkn = indijk(i,j,k,inoff,ijnoff)
              if(dnode(xcoord,ijkn) .eq. 0) then
                 dnode(xcoord,ijkn) = patch%mixt%bndVel(xcoord)*global%dtMin
              endif
              if(dnode(ycoord,ijkn) .eq. 0) then
                 dnode(ycoord,ijkn) = patch%mixt%bndVel(ycoord)*global%dtMin
              endif
              if(dnode(xcoord,ijkn) .eq. 0) then
                 dnode(zcoord,ijkn) = patch%mixt%bndVel(zcoord)*global%dtMin
              endif
            ENDDO
          ENDDO
        ENDDO

      ENDIF  ! motion prescribed internally
    ENDIF    ! external BC
  ENDDO      ! iPatch

! finalize --------------------------------------------------------------------
  IF ( global%myProcid == 0 .AND. & 
       global%verbLevel >= verbose_high ) THEN
    WRITE(stdout,'(A,1X,A,1X,I3)') solver_name, &
                                   'Getting displacements from Rocstar done.'
  END IF ! global%myProcid

999  CALL deregisterfunction( global )

END SUBROUTINE rflo_getdeformation

!******************************************************************************
!
! RCS Revision history:
!
! $Log: RFLO_GetDeformation.F90,v $
! Revision 1.8  2009/08/12 04:15:57  mtcampbe
! Major update, bugfix from Abe development, more propagation compatibility,
! some Rocstar IO changes, Ju's temporary clipping fix for turbulence. A bug
! fix for initialization IO.
!
! Revision 1.7  2008/12/06 08:44:00  mtcampbe
! Updated license.
!
! Revision 1.6  2008/11/19 22:17:14  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.5  2006/08/19 15:37:49  mparmar
! Renamed patch variables
!
! Revision 1.4  2005/09/28 20:49:26  wasistho
! modified for non-external moving boundary
!
! Revision 1.3  2005/06/13 21:45:33  wasistho
! changed patch%bcCoupled to patch%bcMotion
!
! Revision 1.2  2005/06/05 23:03:02  wasistho
! distinguish external boundary to be fully and partly external
!
! Revision 1.1  2004/12/01 21:23:50  haselbac
! Initial revision after changing case
!
! Revision 1.8  2004/11/13 22:37:41  wasistho
! invert orientation of genx-surface-variables
!
! Revision 1.7  2003/11/20 16:40:33  mdbrandy
! Backing out RocfluidMP changes from 11-17-03
!
! Revision 1.4  2003/05/15 02:57:00  jblazek
! Inlined index function.
!
! Revision 1.3  2002/10/10 23:49:48  jblazek
! Changed orientation of surface grid.
!
! Revision 1.2  2002/09/27 00:57:09  jblazek
! Changed makefiles - no makelinks needed.
!
! Revision 1.1  2002/09/20 22:22:34  jblazek
! Finalized integration into GenX.
!
!******************************************************************************