TURB_rFLO_WriteSolution.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: write turbulence instantaneous solution to file
!
! Description: the following solution formats are supported:
!              - RocfloMP ASCII
!              - RocfloMP binary.
!
! Input: regions            = dimensions and turb. variables of all regions
!        global%currentTime = physical time
!        global%resInit     = initial residual.
!
! Output: to file.
!
! Notes: solution is stored only for the current grid level; it is also
!        stored for all dummy cells. All regions are written into one file.
!
!******************************************************************************
!
! $Id: TURB_rFLO_WriteSolution.F90,v 1.5 2009/08/26 12:28:53 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_rflo_writesolution( regions ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_writedatafileint, rflo_writedatafilereal, &
                            rflo_getdimensdummy, rflo_getcelloffset
  USE moderror
  USE modmpi
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), POINTER :: regions(:)

! ... loop variables
  INTEGER :: ireg, i, j, k, n

! ... local variables
  TYPE(t_global), POINTER :: global

  CHARACTER(2*CHRLEN+17)  :: fname

#ifdef MPI
  INTEGER :: status(mpi_status_size)
#endif
  INTEGER :: ilev, iregfile, ipc, jpc, kpc, ndumcells, ioff, ijoff, ijk
  INTEGER :: idcbeg, jdcbeg, kdcbeg, idcend, jdcend, kdcend, ijkbeg, ijkend
  INTEGER :: ndimc, nrvar, noutsol, globalclass, errorflag
  INTEGER, ALLOCATABLE :: ivar(:,:)

  REAL(RFREAL), POINTER     :: tv(:,:), tcv(:,:), vort(:,:), lens(:)
  REAL(RFREAL), ALLOCATABLE :: rvar(:,:), solfile(:,:)

!******************************************************************************

  global => regions(1)%global

  CALL registerfunction( global,'TURB_RFLO_WriteSolution',&
  'TURB_rFLO_WriteSolution.F90' )

! allocate fixed-size temporary data arrays -----------------------------------

  nrvar = 4

  ALLOCATE( ivar(6,1),stat=errorflag )
  ALLOCATE( rvar(nrvar,1),stat=errorflag )
  global%error = errorflag
  IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )

! open solution file (only master proc.) --------------------------------------

  IF (global%myProcid == masterproc) THEN

! - unsteady flow

    IF (global%flowType == flow_unsteady) THEN
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.turba_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,1PE11.5)') trim(global%outDir)//trim(global%casename)//'.turbb_', &
                                   global%currentTime
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = global%currentTime
      rvar(2,1) = 1._rfreal

! - steady flow

    ELSE
      IF (global%solutFormat == format_ascii) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.turba_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='formatted',status='unknown', &
             iostat=errorflag)
      ELSE IF (global%solutFormat == format_binary) THEN
        WRITE(fname,'(A,I6.6)') trim(global%outDir)//trim(global%casename)//'.turbb_', &
                                global%currentIter
        OPEN(if_solut,file=fname,form='unformatted',status='unknown', &
             iostat=errorflag)
      ELSE
        CALL errorstop( global,err_unknown_format,__line__ )
      ENDIF
      rvar(1,1) = 0._rfreal
      rvar(2,1) = global%resInit
    ENDIF
    rvar(3,1) = global%esg1Sum
    rvar(4,1) = global%esg4Sum

    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_open,__line__,'File: '//trim(fname) )

  ENDIF   ! MASTERPROC

! write time and initial residual to file --------------------------------------

  IF (global%myProcid == masterproc) THEN
    CALL rflo_writedatafilereal( global,if_solut,global%solutFormat,nrvar,1,rvar )
  ENDIF

! write solution data ----------------------------------------------------------

! first define no.of output solution by subsquent selection (order matters)

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid == global%myProcid) THEN
      IF (regions(ireg)%turbInput%modelClass == model_les) THEN
        globalclass = model_les
      ENDIF
    ENDIF
  ENDDO

  DO ireg=1,global%nRegions
    IF (regions(ireg)%procid == global%myProcid) THEN
      IF ((regions(ireg)%mixtInput%turbModel == turb_model_sa) .OR. &
          (regions(ireg)%mixtInput%turbModel == turb_model_dessa) .OR. &
          (regions(ireg)%mixtInput%turbModel == turb_model_hdessa)) THEN
        globalclass = model_rans
      ENDIF
    ENDIF
  ENDDO

  DO ireg=1,global%nRegions

! - get dimensions and pointers

    ilev = regions(ireg)%currLevel
    CALL rflo_getdimensdummy( regions(ireg),ilev,idcbeg,idcend, &
                              jdcbeg,jdcend,kdcbeg,kdcend )
    CALL rflo_getcelloffset( regions(ireg),ilev,ioff,ijoff )
    ijkbeg = indijk(idcbeg,jdcbeg,kdcbeg,ioff,ijoff)
    ijkend = indijk(idcend,jdcend,kdcend,ioff,ijoff)
    ndimc  = ijkend - ijkbeg + 1

! - allocate memory for data field and initiate it to zero

    IF (regions(ireg)%procid==global%myProcid .OR. &
        global%myProcid==masterproc) THEN
      noutsol = regions(ireg)%turbInput%nOutField 
      ALLOCATE( solfile(noutsol,ndimc),stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_allocate,__line__ )
      solfile = 0._rfreal
    ENDIF

! - copy solution(s), depending on model selected, into data structure

    IF (regions(ireg)%procid == global%myProcid) THEN
      IF (regions(ireg)%turbInput%modelClass == model_les) THEN
        tv => regions(ireg)%levels(ilev)%mixt%tv
        n = 0
        DO k=kdcbeg,kdcend
          DO j=jdcbeg,jdcend
            DO i=idcbeg,idcend
              n   = n + 1
              ijk = indijk(i,j,k,ioff,ijoff)
              solfile(1,n) = tv(tv_mixt_muet,ijk)
            ENDDO
          ENDDO
        ENDDO
        IF (noutsol == 2) THEN
          vort => regions(ireg)%levels(ilev)%turb%vort
          n = 0
          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n   = n + 1
                ijk = indijk(i,j,k,ioff,ijoff)
                solfile(2,n) = sqrt( vort(xcoord,ijk)*vort(xcoord,ijk) + &
                                     vort(ycoord,ijk)*vort(ycoord,ijk) + &
                                     vort(zcoord,ijk)*vort(zcoord,ijk) )
              ENDDO
            ENDDO
          ENDDO
        ENDIF  ! nOutSol
      ENDIF
      IF ((regions(ireg)%mixtInput%turbModel == turb_model_sa) .OR. &
          (regions(ireg)%mixtInput%turbModel == turb_model_dessa) .OR. &
          (regions(ireg)%mixtInput%turbModel == turb_model_hdessa)) THEN
        tcv  => regions(ireg)%levels(ilev)%turb%cv
        n = 0
        DO k=kdcbeg,kdcend
          DO j=jdcbeg,jdcend
            DO i=idcbeg,idcend
              n   = n + 1
              ijk = indijk(i,j,k,ioff,ijoff)
              solfile(1,n) = tcv(cv_sa_nutil,ijk)
            ENDDO
          ENDDO
        ENDDO
        IF (noutsol == 2) THEN
          vort => regions(ireg)%levels(ilev)%turb%vort
          n = 0
          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n   = n + 1
                ijk = indijk(i,j,k,ioff,ijoff)
                solfile(2,n) = sqrt( vort(xcoord,ijk)*vort(xcoord,ijk) + &
                                     vort(ycoord,ijk)*vort(ycoord,ijk) + &
                                     vort(zcoord,ijk)*vort(zcoord,ijk) )
              ENDDO
            ENDDO
          ENDDO
        ENDIF  ! nOutSol
        IF (noutsol == 3) THEN
          vort => regions(ireg)%levels(ilev)%turb%vort
          lens => regions(ireg)%levels(ilev)%turb%lens
          n = 0
          DO k=kdcbeg,kdcend
            DO j=jdcbeg,jdcend
              DO i=idcbeg,idcend
                n   = n + 1
                ijk = indijk(i,j,k,ioff,ijoff)
                solfile(2,n) = sqrt( vort(xcoord,ijk)*vort(xcoord,ijk) + &
                                     vort(ycoord,ijk)*vort(ycoord,ijk) + &
                                     vort(zcoord,ijk)*vort(zcoord,ijk) )
                solfile(3,n) = lens(ijk)
              ENDDO
            ENDDO
          ENDDO
        ENDIF  ! nOutSol
      ENDIF    ! turbModel/modelClass
    ENDIF      ! global%myProcid

! - write region number and dimensions (only master)

    IF (global%myProcid == masterproc) THEN
      ivar(1,1) = ireg
      ivar(2,1) = regions(ireg)%levels(ilev)%grid%ipc
      ivar(3,1) = regions(ireg)%levels(ilev)%grid%jpc
      ivar(4,1) = regions(ireg)%levels(ilev)%grid%kpc
      ivar(5,1) = regions(ireg)%nDumCells
      ivar(6,1) = noutsol
      CALL rflo_writedatafileint( global,if_solut,global%solutFormat,6,1,ivar )
    ENDIF

! - master receives and writes data, others send them

    IF (global%myProcid == masterproc) THEN
#ifdef MPI
      IF (regions(ireg)%procid /= masterproc) THEN
        CALL mpi_recv( solfile,noutsol*ndimc,mpi_rfreal, &
                       regions(ireg)%procid,ireg, &
                       global%mpiComm,status,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
      CALL rflo_writedatafilereal( global,if_solut,global%solutFormat,noutsol, &
                                   ndimc,solfile )
    ELSE   ! not the master
#ifdef MPI
      IF (regions(ireg)%procid == global%myProcid) THEN
        CALL mpi_send( solfile,noutsol*ndimc,mpi_rfreal, &
                       masterproc,ireg,global%mpiComm,global%mpierr )
        IF (global%mpierr /=0 ) CALL errorstop( global,err_mpi_trouble,__line__ )
      ENDIF
#endif
    ENDIF

    IF (ALLOCATED(solfile) .eqv. .true.) THEN
      DEALLOCATE( solfile,stat=errorflag )
      global%error = errorflag
      IF (global%error /= 0) CALL errorstop( global,err_deallocate,__line__ )
    ENDIF

  ENDDO     ! iReg

! finalize --------------------------------------------------------------------

  IF (global%myProcid == masterproc) THEN
    CLOSE(if_solut,iostat=errorflag)
    global%error = errorflag
    IF (global%error /= 0) &
      CALL errorstop( global,err_file_close,__line__,'File: '//trim(fname) )
  ENDIF

  CALL deregisterfunction( global )

END SUBROUTINE turb_rflo_writesolution

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLO_WriteSolution.F90,v $
! Revision 1.5  2009/08/26 12:28:53  mtcampbe
! Ported to Hera.   Fixed logical expression syntax errors.  Replaced all
! IF (logical_variable)  with IF (logical_variable .eqv. .true.) as
! consistent with the specification.  Also changed: IF( ASSOCIATED(expr) )
! to IF ( ASSOCIATED(expr) .eqv. .true. ).   Intel compilers produce code
! which silently fails for some mal-formed expressions, so these changes
! are a net which should ensure that they are evaluated as intended.
!
! Revision 1.4  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2005/03/09 06:37:50  wasistho
! incorporated HDESSA
!
! Revision 1.1  2004/03/11 03:26:34  wasistho
! changed rocturb nomenclature
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.5  2004/02/26 21:27:30  wasistho
! added esg1Sum and esg4Sum to Real heading for restart
!
! Revision 1.4  2004/02/11 03:24:50  wasistho
! added feature: variable number of turbulence output fields
!
! Revision 1.3  2004/02/07 01:13:26  wasistho
! modified TURB_WriteSolution
!
! Revision 1.2  2003/10/07 02:08:12  wasistho
! initial installation of RaNS-SA and DES
!
! Revision 1.1  2003/07/22 03:01:12  wasistho
! prepare more accurate rocturb restart
!
!
!******************************************************************************