TURB_rFLO_RansResSmoothingCoeff.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: calculate coefficients for the implicit residual smoothing for 
!          RaNS class of turbulence
!
! Description: none.
!
! Input: region%levels%turb%srad = convective spectral radii for smoke.
!
! Output: region%levels%turb%epsIrs = smoothing coefficients.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_rFLO_RansResSmoothingCoeff.F90,v 1.3 2008/12/06 08:44:45 mtcampbe Exp $
!
! Copyright: (c) 2002 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_rflo_ransressmoothingcoeff( region ) ! PUBLIC

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal,     ONLY : t_global
  USE modinterfaces, ONLY : rflo_getdimensphys, rflo_getcelloffset
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region), INTENT(INOUT) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  CHARACTER(CHRLEN) :: rcsidentstring

  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, icoff, ijcoff, ijkc

  REAL(RFREAL) :: cflrat, smoocf, radij, radjk, radik, radji, radkj, radki
  REAL(RFREAL) :: psi, ex, ey, ez
  REAL(RFREAL), POINTER :: srad(:,:), epsirs(:,:)

  TYPE(t_global), POINTER :: global

!******************************************************************************

  global => region%global

  CALL registerfunction( global,'TURB_RFLO_RansResSmoothingCoeff',&
  'TURB_rFLO_RansResSmoothingCoeff.F90' )

  IF (region%turbInput%modelClass /= model_rans) goto 999

! begin -----------------------------------------------------------------------

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend,jpcbeg,jpcend, &
                           kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  srad   => region%levels(ilev)%turb%srad
  epsirs => region%levels(ilev)%turb%epsIrs

  smoocf = region%turbInput%smoocf

! loop over physical cells

  cflrat = sqrt(1._rfreal+4._rfreal*smoocf)
  psi    = 0.0625_rfreal

  DO k=kpcbeg,kpcend
    DO j=jpcbeg,jpcend
      DO i=ipcbeg,ipcend
        ijkc  = indijk(i,j,k,icoff,ijcoff)
        radij = srad(icoord,ijkc)/srad(jcoord,ijkc)
        radjk = srad(jcoord,ijkc)/srad(kcoord,ijkc)
        radik = srad(icoord,ijkc)/srad(kcoord,ijkc)
        radji = 1._rfreal/radij
        radkj = 1._rfreal/radjk
        radki = 1._rfreal/radik

        ex = 0.25_rfreal*((cflrat/(1._rfreal+psi*(radji+radki)))**2-1._rfreal)
        ey = 0.25_rfreal*((cflrat/(1._rfreal+psi*(radij+radkj)))**2-1._rfreal)
        ez = 0.25_rfreal*((cflrat/(1._rfreal+psi*(radik+radjk)))**2-1._rfreal)
        ex = min(smoocf,ex)
        ey = min(smoocf,ey)
        ez = min(smoocf,ez)

        epsirs(icoord,ijkc) = max(0._rfreal,ex)
        epsirs(jcoord,ijkc) = max(0._rfreal,ey)
        epsirs(kcoord,ijkc) = max(0._rfreal,ez)
      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! finalize --------------------------------------------------------------------

999  CONTINUE

  CALL deregisterfunction( global )

END SUBROUTINE turb_rflo_ransressmoothingcoeff

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_rFLO_RansResSmoothingCoeff.F90,v $
! Revision 1.3  2008/12/06 08:44:45  mtcampbe
! Updated license.
!
! Revision 1.2  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.1  2004/03/11 03:26:33  wasistho
! changed rocturb nomenclature
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/10/20 00:37:06  wasistho
! goto 999 before register function
!
! Revision 1.1  2003/10/07 02:17:03  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************