TURB_floRansSetCornEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: set values in edge and corner cells of a region.
!
! Description: this is for the case if the cells are not located
!              within another region.
!
! Input: region = region data.
!
! Output: new values of RaNS variables.
!
! Notes: values in ALL edge and corner cells are averaged from neighboring
!        cells. Hence, this routine should be called first, before values
!        from adjacent regions are copied.
!
!******************************************************************************
!
! $Id: TURB_floRansSetCornEdgeCells.F90,v 1.6 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floranssetcornedgecells( region )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getdimensdummy, rflo_getdimensphys, &
                            rflo_getcelloffset
  USE moderror
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region

! ... loop variables
  INTEGER :: i, j, k

! ... local variables
  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ilev, ncv, gasmodel, icoff, ijcoff, ijkd, ijkc1, ijkc2

  REAL(RFREAL), POINTER :: tcv(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansSetCornEdgeCells', &
                         'TURB_floRansSetCornEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  ncv =  region%turbInput%nCv

  tcv => region%levels(ilev)%turb%cv

! edges 9, 10, 11, 12 ---------------------------------------------------------

  DO i=ipcbeg,ipcend
    DO j=jpcbeg-1,jdcbeg,-1         ! edges 9, 10
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i,j  ,k  ,icoff,ijcoff)
        ijkc1 = indijk(i,j+1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k+1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j+1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k-1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO

    DO j=jpcend+1,jdcend           ! edges 11, 12
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k+1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i,j,k,icoff,ijcoff)
        ijkc1 = indijk(i,j-1,k  ,icoff,ijcoff)
        ijkc2 = indijk(i,j  ,k-1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO
  ENDDO

! edges 2, 4, 6, 8 ------------------------------------------------------------

  DO j=jpcbeg,jpcend
    DO i=ipcbeg-1,idcbeg,-1        ! edges 2, 4
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i+1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k-1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i+1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k+1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO

    DO i=ipcend+1,idcend           ! edges 6, 8
      DO k=kpcend+1,kdcend
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k-1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO k=kpcbeg-1,kdcbeg,-1
        ijkd  = indijk(i  ,j,k  ,icoff,ijcoff)
        ijkc1 = indijk(i-1,j,k  ,icoff,ijcoff)
        ijkc2 = indijk(i  ,j,k+1,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO
  ENDDO

! edges 1, 3, 5, 7 ------------------------------------------------------------

  DO k=kdcbeg,kdcend
    DO i=ipcbeg-1,idcbeg,-1        ! edges 1, 3
      DO j=jpcbeg-1,jdcbeg,-1
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i+1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j+1,k,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO j=jpcend+1,jdcend
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i+1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j-1,k,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO

    DO i=ipcend+1,idcend           ! edges 5, 7
      DO j=jpcbeg-1,jdcbeg,-1
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j+1,k,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
      DO j=jpcend+1,jdcend
        ijkd  = indijk(i  ,j  ,k,icoff,ijcoff)
        ijkc1 = indijk(i-1,j  ,k,icoff,ijcoff)
        ijkc2 = indijk(i  ,j-1,k,icoff,ijcoff)
        CALL averageedgecells( ijkd,ijkc1,ijkc2,ncv,tcv )
      ENDDO
    ENDDO
  ENDDO

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

! =============================================================================
!   Averaging subroutine
! =============================================================================

  CONTAINS

    SUBROUTINE averageedgecells( ijkD,ijkC1,ijkC2,nCv,tcv )
      USE moddatatypes
      IMPLICIT NONE

      INTEGER               :: l
      INTEGER               :: ijkd, ijkc1, ijkc2, ncv
      REAL(RFREAL), POINTER :: tcv(:,:)

      DO l=1,ncv
        tcv(l,ijkd) = 0.5_rfreal*(tcv(l,ijkc1)+ tcv(l,ijkc2))
      ENDDO

    END SUBROUTINE averageedgecells

END SUBROUTINE turb_floranssetcornedgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansSetCornEdgeCells.F90,v $
! Revision 1.6  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2005/10/31 21:09:37  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.3  2004/09/27 23:29:04  wasistho
! changed TURB_AverageEdgeCells to AverageEdgeCells
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.1  2004/01/23 00:39:06  wasistho
! added communication routines for RaNS edge/corners
!
!
!******************************************************************************