TURB_floRansSARoeFluxPatch.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: compute SA convective fluxes through a patch
!          by using Roe`s upwind scheme.
!
! Description: none.
!
! Input: region = data of current region
!        patch  = current patch.
!
! Output: region%levels%turb%rhs = convective fluxes added to the residual.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_floRansSARoeFluxPatch.F90,v 1.6 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floranssaroefluxpatch( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getnodeoffset, bcondinjectionperf
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: i, j, k, n1, n2

! ... local variables
  INTEGER :: ilev, lbound, bctype, distrib, flowmodel, gasmodel, indcp, indmol
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, i2d, noff
  INTEGER :: icoff, ijcoff, ijkcd, ijkcd1, ijkcd2, ijkcb0, ijkcb1, ijknb
  INTEGER :: inoff, ijnoff, inode, jnode, knode, indsvel, spaceorder

  REAL(RFREAL) :: sgn, rhoa, rhoua, rhova, rhowa, rhoea, rhovrel(3), pa, &
                  mrate, tburn, rgas, ds, sv, limfac, limfac3, rvolref, &
                  eps2n, uinj, vinj, winj, vcont, rhl, rhr, qsl, qsr, vola, &
                  gam, ggm1, rl, rr, ul, ur, vl, vr, wl, wr, pl, pr, &
                  hl, hr, qsrl, qsrr, eps2(3), dvar(4), dvarm(4), dvarp(4), &
                  deltl(4), deltr(4), sf(3)
  REAL(RFREAL) :: rnutila
  REAL(RFREAL), POINTER :: cv(:,:), dv(:,:), gv(:,:), vol(:)
  REAL(RFREAL), POINTER :: tcv(:,:), trhs(:,:), sface(:,:), svel(:), vals(:,:)

! ... functions
  REAL(RFREAL) :: muscl3, af, bf, eps

!******************************************************************************
! limiter function

  muscl3(af,bf,eps) = (bf*(2._rfreal*af*af+eps)+af*(bf*bf+2._rfreal*eps))/ &
                      (2._rfreal*af*af+2._rfreal*bf*bf-af*bf+ &
                       3._rfreal*eps+1.e-30_rfreal)

  CALL registerfunction( region%global,'TURB_FloRansSARoeFluxPatch',&
  'TURB_floRansSARoeFluxPatch.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  bctype     = patch%bcType
  noff       = abs(patch%l1end-patch%l1beg) + 1
  distrib    = patch%mixt%distrib
  flowmodel  = region%mixtInput%flowModel
  gasmodel  = region%mixtInput%gasModel
  spaceorder = discr_order_1
  indcp      = region%levels(ilev)%mixt%indCp
  indmol     = region%levels(ilev)%mixt%indMol
  indsvel    = region%levels(ilev)%grid%indSvel
  limfac     = region%mixtInput%limFac

  cv   => region%levels(ilev)%mixt%cv
  dv   => region%levels(ilev)%mixt%dv
  gv   => region%levels(ilev)%mixt%gv
  vol  => region%levels(ilev)%grid%vol
  tcv  => region%levels(ilev)%turb%cv
  trhs => region%levels(ilev)%turb%rhs
  vals => patch%mixt%vals

! to take the right face vector and make it point outwards

  sgn   = +1._rfreal
  inode = 0
  jnode = 0
  knode = 0
  IF (lbound==2 .OR. lbound==4 .OR. lbound==6) THEN
    sgn   = -1._rfreal
    inode = -idir
    jnode = -jdir
    knode = -kdir
  ENDIF

! get the appropriate face vector and grid speed

  IF (lbound==1 .OR. lbound==2) THEN
    sface => region%levels(ilev)%grid%si
    svel  => region%levels(ilev)%grid%siVel
  ELSE IF (lbound==3 .OR. lbound==4) THEN
    sface => region%levels(ilev)%grid%sj
    svel  => region%levels(ilev)%grid%sjVel
  ELSE IF (lbound==5 .OR. lbound==6) THEN
    sface => region%levels(ilev)%grid%sk
    svel  => region%levels(ilev)%grid%skVel
  ENDIF

! normalise epsilon^2 for all limited variables (rho, u, v, w, p) -------------

  limfac3 = limfac*limfac*limfac
  rvolref = 1._rfreal/region%global%limVolRef**1.5_rfreal
  eps2(1) = limfac3*region%global%limRef(1)*region%global%limRef(1)*rvolref
  eps2(2) = limfac3*region%global%limRef(2)*region%global%limRef(2)*rvolref
  eps2(3) = limfac3*region%global%limRef(3)*region%global%limRef(3)*rvolref

! stationary grid -------------------------------------------------------------

  IF (bctype>=bc_slipwall .AND. bctype<=bc_slipwall+bc_range) THEN

  ELSE IF (bctype>=bc_noslipwall .AND. bctype<=bc_noslipwall+bc_range) THEN

  ELSE IF (bctype>=bc_symmetry .AND. bctype<=bc_symmetry+bc_range) THEN

  ELSE IF (bctype>=bc_injection .AND. bctype<=bc_injection+bc_range) THEN

! injection boundary (as wall if mass flow rate <= 0)

    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! boundary
          ijkcb1 = indijk(i+idir ,j+jdir ,k+kdir ,icoff,ijcoff)  ! interior
          ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
          sf(1)  = sgn*sface(xcoord,ijknb)
          sf(2)  = sgn*sface(ycoord,ijknb)
          sf(3)  = sgn*sface(zcoord,ijknb)
          sv     = sgn*svel(ijknb*indsvel)

          IF      (lbound==1 .OR. lbound==2) THEN
            n1 = j - jbeg
            n2 = k - kbeg
          ELSE IF (lbound==3 .OR. lbound==4) THEN
            n1 = k - kbeg
            n2 = i - ibeg
          ELSE IF (lbound==5 .OR. lbound==6) THEN
            n1 = i - ibeg
            n2 = j - jbeg
          ENDIF
          i2d        = distrib * indij(n1,n2,noff)
          mrate      = vals(bcdat_inject_mfrate,i2d)
          tburn      = vals(bcdat_inject_temp  ,i2d)
          rhovrel(1) = vals(bcdat_inject_rfvfu ,i2d)
          rhovrel(2) = vals(bcdat_inject_rfvfv ,i2d)
          rhovrel(3) = vals(bcdat_inject_rfvfw ,i2d)

          IF (mrate > 0._rfreal) THEN        ! surface burning
!            rnutila = 0.5_RFREAL*(tcv(CV_SA_NUTIL,ijkCB0)+ &
!                                  tcv(CV_SA_NUTIL,ijkCD))
            rnutila = 0.5_rfreal*(3._rfreal*tcv(cv_sa_nutil,ijkcb0)- &
                                            tcv(cv_sa_nutil,ijkcb1))
            ds = sqrt(sf(1)*sf(1)+sf(2)*sf(2)+sf(3)*sf(3))

            IF (gasmodel == gas_model_tcperf) THEN
              CALL bcondinjectionperf( distrib,mrate,tburn,rhovrel, &
                                       sf(1)/ds,sf(2)/ds,sf(3)/ds, &
                                       gv(gv_mixt_cp  ,ijkcb0*indcp ), &
                                       gv(gv_mixt_mol ,ijkcb0*indmol), &
                                       dv(dv_mixt_pres,ijkcb0       ), &
                                       rhoa,rhoua,rhova,rhowa,rhoea,pa, &
                                       uinj,vinj,winj )
            ELSE
              CALL errorstop( region%global,err_unknown_bc,__line__ )
            ENDIF
            vcont = uinj*sf(1) + vinj*sf(2) + winj*sf(3)

          ELSE                               ! not burning - slip/noslip wall
            rnutila = 0._rfreal
            vcont   = 0._rfreal
          ENDIF

          trhs(cv_sa_nutil,ijkcb0) = trhs(cv_sa_nutil,ijkcb0) + &
                                     vcont*rnutila
        ENDDO   ! i
      ENDDO     ! j
    ENDDO       ! k

! non-conforming region interface

  ELSE IF (bctype>=bc_regionint  .AND. bctype<=bc_regionint +bc_range) THEN

  ELSE IF (bctype>=bc_regnonconf .AND. bctype<=bc_regnonconf+bc_range) THEN

! everything else

  ELSE

    IF (spaceorder == discr_order_1) THEN
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkcb0 = indijk(i      ,j      ,k      ,icoff,ijcoff)  ! boundary
            ijkcd  = indijk(i-idir ,j-jdir ,k-kdir ,icoff,ijcoff)  ! dummy
            ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
            sf(1)  = sgn*sface(xcoord,ijknb)
            sf(2)  = sgn*sface(ycoord,ijknb)
            sf(3)  = sgn*sface(zcoord,ijknb)
            sv     = sgn*svel(ijknb*indsvel)

            qsl    = dv(dv_mixt_uvel,ijkcd)*sf(1) + &
                     dv(dv_mixt_vvel,ijkcd)*sf(2) + &
                     dv(dv_mixt_wvel,ijkcd)*sf(3) - sv
            qsr    = dv(dv_mixt_uvel,ijkcb0)*sf(1) + &
                     dv(dv_mixt_vvel,ijkcb0)*sf(2) + &
                     dv(dv_mixt_wvel,ijkcb0)*sf(3) - sv
            trhs(cv_sa_nutil,ijkcb0) = trhs(cv_sa_nutil,ijkcb0) + &
                                       0.5_rfreal*(qsl*tcv(cv_sa_nutil,ijkcd)+ &
                                                   qsr*tcv(cv_sa_nutil,ijkcb0))
          ENDDO ! i
        ENDDO   ! j
      ENDDO     ! k
    ELSE IF (spaceorder == discr_order_2) THEN
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkcb0 = indijk(i       ,j        ,k      ,icoff,ijcoff)  ! boundary
            ijkcb1 = indijk(i+  idir,j+  jdir,k+  kdir,icoff,ijcoff)  ! interior
            ijkcd1 = indijk(i-  idir,j-  jdir,k-  kdir,icoff,ijcoff)  ! dummy 1
            ijkcd2 = indijk(i-2*idir,j-2*jdir,k-2*kdir,icoff,ijcoff)  ! dummy 2
            ijknb  = indijk(i+inode,j+jnode,k+knode,inoff,ijnoff)
            sf(1)  = sgn*sface(xcoord,ijknb)
            sf(2)  = sgn*sface(ycoord,ijknb)
            sf(3)  = sgn*sface(zcoord,ijknb)
            sv     = sgn*svel(ijknb*indsvel)
            vola   = (0.5_rfreal*(vol(ijkcb0)+vol(ijkcd1)))**1.5_rfreal

            dvar(1)  = tcv(cv_sa_nutil,ijkcb0) - tcv(cv_sa_nutil,ijkcd1)
            dvar(2)  = dv(dv_mixt_uvel,ijkcb0) - dv(dv_mixt_uvel,ijkcd1)
            dvar(3)  = dv(dv_mixt_vvel,ijkcb0) - dv(dv_mixt_vvel,ijkcd1)
            dvar(4)  = dv(dv_mixt_wvel,ijkcb0) - dv(dv_mixt_wvel,ijkcd1)

            dvarm(1) = tcv(cv_sa_nutil,ijkcd1) - tcv(cv_sa_nutil,ijkcd2)
            dvarm(2) = dv(dv_mixt_uvel,ijkcd1) - dv(dv_mixt_uvel,ijkcd2)
            dvarm(3) = dv(dv_mixt_vvel,ijkcd1) - dv(dv_mixt_vvel,ijkcd2)
            dvarm(4) = dv(dv_mixt_wvel,ijkcd1) - dv(dv_mixt_wvel,ijkcd2)

            dvarp(1) = tcv(cv_sa_nutil,ijkcb1) - tcv(cv_sa_nutil,ijkcb0)
            dvarp(2) = dv(dv_mixt_uvel,ijkcb1) - dv(dv_mixt_uvel,ijkcb0)
            dvarp(3) = dv(dv_mixt_vvel,ijkcb1) - dv(dv_mixt_vvel,ijkcb0)
            dvarp(4) = dv(dv_mixt_wvel,ijkcb1) - dv(dv_mixt_wvel,ijkcb0)

            eps2n    = eps2(1)*vola
            deltl(1) = 0.5_rfreal*muscl3(dvar(1) ,dvarm(1),eps2n)
            deltr(1) = 0.5_rfreal*muscl3(dvarp(1),dvar(1) ,eps2n)
            eps2n    = eps2(2)*vola
            deltl(2) = 0.5_rfreal*muscl3(dvar(2) ,dvarm(2),eps2n)
            deltr(2) = 0.5_rfreal*muscl3(dvarp(2),dvar(2) ,eps2n)
            deltl(3) = 0.5_rfreal*muscl3(dvar(3) ,dvarm(3),eps2n)
            deltr(3) = 0.5_rfreal*muscl3(dvarp(3),dvar(3) ,eps2n)
            deltl(4) = 0.5_rfreal*muscl3(dvar(4) ,dvarm(4),eps2n)
            deltr(4) = 0.5_rfreal*muscl3(dvarp(4),dvar(4) ,eps2n)

            rl    = tcv(cv_sa_nutil,ijkcd1) + deltl(1)
            ul    = dv(dv_mixt_uvel,ijkcd1) + deltl(2)
            vl    = dv(dv_mixt_vvel,ijkcd1) + deltl(3)
            wl    = dv(dv_mixt_wvel,ijkcd1) + deltl(4)
            qsrl  = (ul*sf(1)+vl*sf(2)+ wl*sf(3)-sv)*rl

            rr    = tcv(cv_sa_nutil,ijkcb0) - deltr(1)
            ur    = dv(dv_mixt_uvel,ijkcb0) - deltr(2)
            vr    = dv(dv_mixt_vvel,ijkcb0) - deltr(3)
            wr    = dv(dv_mixt_wvel,ijkcb0) - deltr(4)
            qsrr  = (ur*sf(1)+vr*sf(2)+wr*sf(3)-sv)*rr

            trhs(cv_sa_nutil,ijkcb0) = trhs(cv_sa_nutil,ijkcb0) + &
                                       0.5_rfreal*(qsrl   +qsrr   )
          ENDDO ! i
        ENDDO   ! j
      ENDDO     ! k
    ENDIF       ! spaceOrder

  ENDIF         ! bcType

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floranssaroefluxpatch

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansSARoeFluxPatch.F90,v $
! Revision 1.6  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/08/19 15:40:50  mparmar
! Renamed patch variables
!
! Revision 1.3  2005/10/31 21:09:37  haselbac
! Changed specModel and SPEC_MODEL_NONE
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:46  wasistho
! changed turb nomenclature
!
! Revision 1.1  2003/10/27 04:54:38  wasistho
! added RaNS upwind schemes
!
!
!******************************************************************************