TURB_floRansExchangeDummyConf.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: exchange RaNS variables between interior and dummy cells of the
!          corresponding patches of the adjacent regions (both regions
!          are on the same processor).
!
! Description: none.
!
! Input: region    = current region
!        regionSrc = source region
!        patch     = current patch of region
!        patchSrc  = source patch of regionSrc.
!
! Output: regions%levels%turb%cv = RaNS variables in dummy cells.
!
! Notes: intended for conforming grid boundaries only.
!
!******************************************************************************
!
! $Id: TURB_floRansExchangeDummyConf.F90,v 1.4 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floransexchangedummyconf( region,regionSrc,patch,patchSrc )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modindexing, ONLY   : indijkmap
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset, rflo_getpatchmapping
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region, regionsrc
  TYPE(t_patch)  :: patch, patchsrc

! ... loop variables
  INTEGER :: idum, i, j, k, l, ii, jj, kk

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir, &
             icoff, ijcoff, ijkd, ilev, ncv
  INTEGER :: ibegsrc, iendsrc, jbegsrc, jendsrc, kbegsrc, kendsrc, &
             idirsrc, jdirsrc, kdirsrc, icoffsrc, ijcoffsrc, ijkcsrc
  INTEGER :: lb, lbs, l1srcdir, l2srcdir, mapmat(3,4)

  LOGICAL :: align

  REAL(RFREAL), POINTER :: tcv(:,:), tcvsrc(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansExchangeDummyConf', &
                         'TURB_floRansExchangeDummyConf.F90' )

! check if the source region is active

  IF (regionsrc%active == off) THEN
    CALL errorstop( region%global,err_srcregion_off,__line__ )
  ENDIF

! get dimensions and pointers

  ilev = region%currLevel

  CALL rflo_getpatchindices( region,patch,ilev,ibeg,iend, &
                             jbeg,jend,kbeg,kend )
  CALL rflo_getpatchindices( regionsrc,patchsrc,ilev,ibegsrc,iendsrc, &
                             jbegsrc,jendsrc,kbegsrc,kendsrc )
  CALL rflo_getpatchdirection( patch   ,idir   ,jdir,   kdir    )
  CALL rflo_getpatchdirection( patchsrc,idirsrc,jdirsrc,kdirsrc )
  CALL rflo_getcelloffset( region   ,ilev,icoff   ,ijcoff    )
  CALL rflo_getcelloffset( regionsrc,ilev,icoffsrc,ijcoffsrc )

  ncv    =  region%turbInput%nCv

  tcv    => region%levels(ilev)%turb%cv
  tcvsrc => regionsrc%levels(ilev)%turb%cv

! mapping between patches

                                       l1srcdir =  1
  IF (patch%srcL1beg > patch%srcL1end) l1srcdir = -1
                                       l2srcdir =  1
  IF (patch%srcL2beg > patch%srcL2end) l2srcdir = -1

  lb    = patch%lbound
  lbs   = patch%srcLbound
  align = patch%align

  CALL rflo_getpatchmapping( lb,lbs,l1srcdir,l2srcdir,align, &
                             idir,jdir,kdir,idirsrc,jdirsrc,kdirsrc, &
                             ibeg,iend,jbeg,jend,kbeg,kend, &
                             ibegsrc,iendsrc,jbegsrc,jendsrc,kbegsrc,kendsrc, &
                             mapmat )

! loop over dummy nodes of current patch

  DO idum=1,region%nDumCells
    DO k=kbeg,kend
      DO j=jbeg,jend
        DO i=ibeg,iend
          ii      = i - idum*idir
          jj      = j - idum*jdir
          kk      = k - idum*kdir
          ijkd    = indijk(ii,jj,kk,icoff,ijcoff)
          ijkcsrc = indijkmap(ii,jj,kk,mapmat,icoffsrc,ijcoffsrc)

          DO l=1,ncv
            tcv(l,ijkd) = tcvsrc(l,ijkcsrc)
          ENDDO

        ENDDO  ! i
      ENDDO    ! j
    ENDDO      ! k
  ENDDO        ! idum

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floransexchangedummyconf

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansExchangeDummyConf.F90,v $
! Revision 1.4  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.3  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.1  2003/10/07 02:17:03  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************