TURB_floRansCorrCornEdgeCells.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: correct values in the corner and edge cells at noslip (viscous)
!          walls, symmetry boundaries, and non-burning injection boundaries.
!
! Description: none.
!
! Input: region = region dimensions, user input
!        patch  = current patch
!        bcType = type of boundary condition.
!
! Output: RaNS variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_floRansCorrCornEdgeCells.F90,v 1.6 2009/08/26 12:28:53 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floranscorrcornedgecells( region,patch,bcType )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
        rflo_getcelloffset, rflo_getdimensphys, rflo_getdimensdummy
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  INTEGER        :: bctype
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: idum, i, j, k, l, n1, n2, iside

! ... local variables
  LOGICAL :: dodummy(4)

  INTEGER :: idcbeg, idcend, jdcbeg, jdcend, kdcbeg, kdcend
  INTEGER :: ipcbeg, ipcend, jpcbeg, jpcend, kpcbeg, kpcend
  INTEGER :: ibegp, iendp, jbegp, jendp, kbegp, kendp, idir, jdir, kdir
  INTEGER :: ibeg(4), iend(4), jbeg(4), jend(4), kbeg(4), kend(4), nsides
  INTEGER :: ilev, ncv, lbound, icoff, ijcoff, noff, distrib
  INTEGER :: ijkc, ijkd, i2d

  REAL(RFREAL)          :: mrate
  REAL(RFREAL), POINTER :: tcv(:,:), vals(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansCorrCornEdgeCells', &
                         'TURB_floRansCorrCornEdgeCells.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev   = region%currLevel
  lbound = patch%lbound
  ncv    = region%turbInput%nCv

  CALL rflo_getdimensdummy( region,ilev,idcbeg,idcend, &
                            jdcbeg,jdcend,kdcbeg,kdcend )
  CALL rflo_getdimensphys( region,ilev,ipcbeg,ipcend, &
                           jpcbeg,jpcend,kpcbeg,kpcend )
  CALL rflo_getpatchindices( region,patch,ilev, &
                             ibegp,iendp,jbegp,jendp,kbegp,kendp )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  noff      = abs(patch%l1end-patch%l1beg) + 1
  distrib   = patch%mixt%distrib

  tcv  => region%levels(ilev)%turb%cv
  vals => patch%mixt%vals

! set loop indices ------------------------------------------------------------

  dodummy(:) = .false.
  nsides     = 0

  IF      (lbound==1 .OR. lbound==2) THEN
    ibeg(:) = ibegp
    iend(:) = iendp
    IF (jbegp == jpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jdcbeg
      jend(nsides)    = jpcbeg - 1
      IF (kbegp == kpcbeg) THEN
        kbeg(nsides)  = kdcbeg
      ELSE
        kbeg(nsides)  = kbegp
      ENDIF
      IF (kendp == kpcend) THEN
        kend(nsides)  = kdcend
      ELSE
        kend(nsides)  = kendp
      ENDIF
    ENDIF
    IF (jendp == jpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jpcend + 1
      jend(nsides)    = jdcend
      IF (kbegp == kpcbeg) THEN
        kbeg(nsides)  = kdcbeg
      ELSE
        kbeg(nsides)  = kbegp
      ENDIF
      IF (kendp == kpcend) THEN
        kend(nsides)  = kdcend
      ELSE
        kend(nsides)  = kendp
      ENDIF
    ENDIF
    IF (kbegp == kpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jbegp
      jend(nsides)    = jendp
      kbeg(nsides)    = kdcbeg
      kend(nsides)    = kpcbeg - 1
    ENDIF
    IF (kendp == kpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      jbeg(nsides)    = jbegp
      jend(nsides)    = jendp
      kbeg(nsides)    = kpcend + 1
      kend(nsides)    = kdcend
    ENDIF

  ELSE IF (lbound==3 .OR. lbound==4) THEN
    jbeg(:) = jbegp
    jend(:) = jendp
    IF (kbegp == kpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kdcbeg
      kend(nsides)    = kpcbeg - 1
      IF (ibegp == ipcbeg) THEN
        ibeg(nsides)  = idcbeg
      ELSE
        ibeg(nsides)  = ibegp
      ENDIF
      IF (iendp == ipcend) THEN
        iend(nsides)  = idcend
      ELSE
        iend(nsides)  = iendp
      ENDIF
    ENDIF
    IF (kendp == kpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kpcend + 1
      kend(nsides)    = kdcend
      IF (ibegp == ipcbeg) THEN
        ibeg(nsides)  = idcbeg
      ELSE
        ibeg(nsides)  = ibegp
      ENDIF
      IF (iendp == ipcend) THEN
        iend(nsides)  = idcend
      ELSE
        iend(nsides)  = iendp
      ENDIF
    ENDIF
    IF (ibegp == ipcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kbegp
      kend(nsides)    = kendp
      ibeg(nsides)    = idcbeg
      iend(nsides)    = ipcbeg - 1
    ENDIF
    IF (iendp == ipcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      kbeg(nsides)    = kbegp
      kend(nsides)    = kendp
      ibeg(nsides)    = ipcend + 1
      iend(nsides)    = idcend
    ENDIF

  ELSE IF (lbound==5 .OR. lbound==6) THEN
    kbeg(:) = kbegp
    kend(:) = kendp
    IF (ibegp == ipcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = idcbeg
      iend(nsides)    = ipcbeg - 1
      IF (jbegp == jpcbeg) THEN
        jbeg(nsides)  = jdcbeg
      ELSE
        jbeg(nsides)  = jbegp
      ENDIF
      IF (jendp == jpcend) THEN
        jend(nsides)  = jdcend
      ELSE
        jend(nsides)  = jendp
      ENDIF
    ENDIF
    IF (iendp == ipcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ipcend + 1
      iend(nsides)    = idcend
      IF (jbegp == jpcbeg) THEN
        jbeg(nsides)  = jdcbeg
      ELSE
        jbeg(nsides)  = jbegp
      ENDIF
      IF (jendp == jpcend) THEN
        jend(nsides)  = jdcend
      ELSE
        jend(nsides)  = jendp
      ENDIF
    ENDIF
    IF (jbegp == jpcbeg) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ibegp
      iend(nsides)    = iendp
      jbeg(nsides)    = jdcbeg
      jend(nsides)    = jpcbeg - 1
    ENDIF
    IF (jendp == jpcend) THEN
      nsides          = nsides + 1
      dodummy(nsides) = .true.
      ibeg(nsides)    = ibegp
      iend(nsides)    = iendp
      jbeg(nsides)    = jpcend + 1
      jend(nsides)    = jdcend
    ENDIF
  ENDIF

! loop over all cells of a patch ----------------------------------------------

  DO iside=1,nsides
    IF (dodummy(iside) .eqv. .true.) THEN

      DO idum=1,region%nDumCells
        DO k=kbeg(iside),kend(iside)
          DO j=jbeg(iside),jend(iside)
            DO i=ibeg(iside),iend(iside)
              ijkd = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)
              ijkc = indijk(i+(idum-1)*idir,j+(idum-1)*jdir,k+(idum-1)*kdir,icoff,ijcoff)

! ----------- noslip wall

              IF (bctype>=bc_noslipwall .AND. &
                  bctype<=bc_noslipwall+bc_range) THEN
                DO l=1,ncv
                  tcv(l,ijkd) = -tcv(l,ijkc)
                ENDDO

! ----------- symmetry boundary

              ELSE IF (bctype>=bc_symmetry .AND. &
                       bctype<=bc_symmetry+bc_range) THEN
                DO l=1,ncv
                  tcv(l,ijkd) =  tcv(l,ijkc)
                ENDDO

! ----------- non-burning injection boundary (like noslip wall)

              ELSE IF (bctype>=bc_injection .AND. &
                       bctype<=bc_injection+bc_range) THEN
                IF      (lbound==1 .OR. lbound==2) THEN
                  n1 = max(min(j,jendp),jbegp) - jbegp
                  n2 = max(min(k,kendp),kbegp) - kbegp
                ELSE IF (lbound==3 .OR. lbound==4) THEN
                  n1 = max(min(k,kendp),kbegp) - kbegp
                  n2 = max(min(i,iendp),ibegp) - ibegp
                ELSE IF (lbound==5 .OR. lbound==6) THEN
                  n1 = max(min(i,iendp),ibegp) - ibegp
                  n2 = max(min(j,jendp),jbegp) - jbegp
                ENDIF
                i2d   = distrib * indij(n1,n2,noff)
                mrate = vals(bcdat_inject_mfrate,i2d)
                IF (mrate <= 0._rfreal) THEN
                  DO l=1,ncv
                    tcv(l,ijkd) = -tcv(l,ijkc)
                  ENDDO
                ENDIF
              ENDIF

            ENDDO  ! i
          ENDDO    ! j
        ENDDO      ! k
      ENDDO        ! idum

    ENDIF  ! doDummy
  ENDDO    ! iside

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floranscorrcornedgecells

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansCorrCornEdgeCells.F90,v $
! Revision 1.6  2009/08/26 12:28:53  mtcampbe
! Ported to Hera.   Fixed logical expression syntax errors.  Replaced all
! IF (logical_variable)  with IF (logical_variable .eqv. .true.) as
! consistent with the specification.  Also changed: IF( ASSOCIATED(expr) )
! to IF ( ASSOCIATED(expr) .eqv. .true. ).   Intel compilers produce code
! which silently fails for some mal-formed expressions, so these changes
! are a net which should ensure that they are evaluated as intended.
!
! Revision 1.5  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2006/08/19 15:40:46  mparmar
! Renamed patch variables
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.1  2004/01/23 00:39:06  wasistho
! added communication routines for RaNS edge/corners
!
!
!******************************************************************************