TURB_floRansBcondInjection.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: update RaNS variables in dummy cells at injection patch
!
! Description: none.
!
! Input: region = region dimensions, user input
!        patch  = current patch.
!
! Output: region%levels%turb%cv = RaNS variables in dummy cells.
!
! Notes: none.
!
!******************************************************************************
!
! $Id: TURB_floRansBcondInjection.F90,v 1.6 2008/12/06 08:44:44 mtcampbe Exp $
!
! Copyright: (c) 2003 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_floransbcondinjection( region,patch )

  USE moddatatypes
  USE modbndpatch, ONLY   : t_patch
  USE moddatastruct, ONLY : t_region
  USE modinterfaces, ONLY : rflo_getpatchindices, rflo_getpatchdirection, &
                            rflo_getcelloffset
  USE moderror
  USE modparameters
  USE turb_modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  TYPE(t_patch)  :: patch

! ... loop variables
  INTEGER :: idum, i, j, k, l

! ... local variables
  INTEGER :: ibeg, iend, jbeg, jend, kbeg, kend, idir, jdir, kdir
  INTEGER :: ilev, lbound, n1, n2, i2d, distrib, noff
  INTEGER :: icoff, ijcoff, ijkc, ijkc1, ijkc2, ijkd, ncv

  REAL(RFREAL) :: mrate
  REAL(RFREAL), POINTER :: tcv(:,:), vals(:,:)

!******************************************************************************

  CALL registerfunction( region%global,'TURB_FloRansBcondInjection',&
  'TURB_floRansBcondInjection.F90' )

! get dimensions and pointers

  ilev   = region%currLevel
  lbound = patch%lbound

  CALL rflo_getpatchindices( region,patch,ilev, &
                             ibeg,iend,jbeg,jend,kbeg,kend )
  CALL rflo_getpatchdirection( patch,idir,jdir,kdir )
  CALL rflo_getcelloffset( region,ilev,icoff,ijcoff )

  noff    =  abs(patch%l1end-patch%l1beg) + 1
  distrib =  patch%mixt%distrib
  ncv     =  region%turbInput%nCv
  tcv     => region%levels(ilev)%turb%cv
  vals    => patch%mixt%vals

! loop over all cells of a patch

  IF ((region%mixtInput%turbModel == turb_model_sa) .OR. &
      (region%mixtInput%turbModel == turb_model_dessa) .OR. &
      (region%mixtInput%turbModel == turb_model_hdessa)) THEN

    DO idum=1,region%nDumCells
      DO k=kbeg,kend
        DO j=jbeg,jend
          DO i=ibeg,iend
            ijkd  = indijk(i-idum*idir,j-idum*jdir,k-idum*kdir,icoff,ijcoff)
            ijkc  = &
            indijk(i-(idum-1)*idir,j-(idum-1)*jdir,k-(idum-1)*kdir,icoff,ijcoff)
            ijkc1 = &
            indijk(i-(idum-2)*idir,j-(idum-2)*jdir,k-(idum-2)*kdir,icoff,ijcoff)
            ijkc2 = &
            indijk(i+(idum-1)*idir,j+(idum-1)*jdir,k+(idum-1)*kdir,icoff,ijcoff)

            IF      (lbound==1 .OR. lbound==2) THEN
              n1 = j - jbeg
              n2 = k - kbeg
            ELSE IF (lbound==3 .OR. lbound==4) THEN
              n1 = k - kbeg
              n2 = i - ibeg
            ELSE IF (lbound==5 .OR. lbound==6) THEN
              n1 = i - ibeg
              n2 = j - jbeg
            ENDIF
            i2d   = distrib * indij(n1,n2,noff)
            mrate = vals(bcdat_inject_mfrate,i2d)

            IF (mrate > 0._rfreal) THEN  ! burning surface
              IF (idum == 1) THEN
                DO l=1,ncv
                  tcv(l,ijkd) = tcv(l,ijkc)
                ENDDO
              ELSE
                DO l=1,ncv
                  tcv(l,ijkd) = 2._rfreal*tcv(l,ijkc) - tcv(l,ijkc1)
                ENDDO
              ENDIF
            ELSE                       ! non burning surface, as ns-wall
              DO l=1,ncv
                tcv(l,ijkd) = - tcv(l,ijkc2)
              ENDDO
            ENDIF
          ENDDO  ! i
        ENDDO    ! j
      ENDDO      ! k
    ENDDO        ! idum

  ELSE

    CALL errorstop( region%global,err_turb_ransinput,__line__, &
                   'injection bc is not ready yet for RaNS model selected' )
  ENDIF

! finalize

  CALL deregisterfunction( region%global )

END SUBROUTINE turb_floransbcondinjection

!******************************************************************************
!
! RCS Revision history:
!
! $Log: TURB_floRansBcondInjection.F90,v $
! Revision 1.6  2008/12/06 08:44:44  mtcampbe
! Updated license.
!
! Revision 1.5  2008/11/19 22:17:56  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.4  2006/08/19 15:40:44  mparmar
! Renamed patch variables
!
! Revision 1.3  2005/03/09 06:36:53  wasistho
! incorporated HDESSA
!
! Revision 1.2  2004/03/12 02:55:36  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2004/01/21 03:44:04  wasistho
! fixed distrib and ijkC, C1, C2, D
!
! Revision 1.1  2003/10/07 02:17:02  wasistho
! initial installation of RaNS-SA and DES
!
!
!******************************************************************************