TURB_floFaceWidthDummyPhys.F90

Go to the documentation of this file.

! *********************************************************************
! * Rocstar Simulation Suite                                          *
! * Copyright@2015, Illinois Rocstar LLC. All rights reserved.        *
! *                                                                   *
! * Illinois Rocstar LLC                                              *
! * Champaign, IL                                                     *
! * www.illinoisrocstar.com                                           *
! * sales@illinoisrocstar.com                                         *
! *                                                                   *
! * License: See LICENSE file in top level of distribution package or *
! * http://opensource.org/licenses/NCSA                               *
! *********************************************************************
! *********************************************************************
! * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,   *
! * EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES   *
! * OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND          *
! * NONINFRINGEMENT.  IN NO EVENT SHALL THE CONTRIBUTORS OR           *
! * COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER       *
! * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,   *
! * Arising FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE    *
! * USE OR OTHER DEALINGS WITH THE SOFTWARE.                          *
! *********************************************************************
!******************************************************************************
!
! Purpose: Extrapolate face widths from the interior domain or at the patch 
!          to the dummy points at physical and symmetry boundaries.
!
! Description: The face widths at dummy faces are obtained by
!              mirroring from the interior faces.
!
! Input: region   = current region data
!        lbound   = patch boundary ID
!        i,j,kdir = direction identifier
!        i,j,kndBeg = i,j,k begin index
!        i,j,kndEnd = i,j,k end index
!  
! Output: Face widths workI, workJ, workK at dummy faces.
!
! Notes: Mother routine = TURB_FloFaceWidth.
!
!******************************************************************************
!
! $Id: TURB_floFaceWidthDummyPhys.F90,v 1.5 2008/12/06 08:44:43 mtcampbe Exp $
!
! Copyright: (c) 2001 by the University of Illinois
!
!******************************************************************************

SUBROUTINE turb_flofacewidthdummyphys( region,lbound,idir,jdir,kdir, &
                                    indbeg,indend,jndbeg,jndend,kndbeg,kndend )

  USE moddatatypes
  USE moddatastruct, ONLY : t_region
  USE modglobal, ONLY     : t_global
  USE modinterfaces, ONLY : rflo_getnodeoffset
  USE moderror
  USE modparameters
  IMPLICIT NONE

#include "Indexing.h"

! ... parameters
  TYPE(t_region) :: region
  INTEGER        :: lbound, idir, jdir, kdir
  INTEGER        :: indbeg, indend, jndbeg, jndend, kndbeg, kndend

! ... loop variables
  INTEGER :: i, j, k, idum, jdum, kdum

! ... local variables
  CHARACTER(CHRLEN)       :: rcsidentstring
  TYPE(t_global), POINTER :: global

  INTEGER :: ilev, inoff, ijnoff
  INTEGER :: ijknb, ijkni, ijknj, ijknk, ijknd
  INTEGER :: ig(3), jg(3), kg(3), ir(3), jr(3), kr(3)
  INTEGER :: idumb(3), jdumb(3), kdumb(3), idume(3), jdume(3), kdume(3)

!******************************************************************************

  rcsidentstring = '$RCSfile: TURB_floFaceWidthDummyPhys.F90,v $'

  global => region%global
  CALL registerfunction( global,'TURB_FloFaceWidthDummyPhys',&
  'TURB_floFaceWidthDummyPhys.F90' )

! get dimensions and pointers -------------------------------------------------

  ilev = region%currLevel
  CALL rflo_getnodeoffset( region,ilev,inoff,ijnoff )

  IF (lbound==1 .OR. lbound==3 .OR. lbound==5) THEN
    idumb(:) = -idir*region%nDumCells
    jdumb(:) = -jdir*region%nDumCells
    kdumb(:) = -kdir*region%nDumCells
    idume(:) = -idir
    jdume(:) = -jdir
    kdume(:) = -kdir
  ELSE
    idumb(:) = 0
    jdumb(:) = 0
    kdumb(:) = 0
    idume(:) = -idir*region%nDumCells
    jdume(:) = -jdir*region%nDumCells
    kdume(:) = -kdir*region%nDumCells
  ENDIF

  ig(:)=-abs(idir); jg(:)=-abs(jdir); kg(:)=-abs(kdir)
  IF (lbound == 1) THEN
    ig(1)=0
  ELSE IF (lbound == 3) THEN
    jg(2)=0
  ELSE IF (lbound == 5) THEN
    kg(3)=0
  ELSE IF (lbound == 2) THEN
    ig(1)=0
    idumb(1) = idumb(1)-idir
  ELSE IF (lbound == 4) THEN
    jg(2)=0
    jdumb(2) = jdumb(2)-jdir
  ELSE IF (lbound == 6) THEN
    kg(3)=0
    kdumb(3) = kdumb(3)-kdir
  ENDIF

! specify facewidths at dummy faces by mirroring
! 2D loop over patch nodes 

  DO k=kndbeg,kndend
    DO j=jndbeg,jndend
      DO i=indbeg,indend

! ----- 1D loop in direction normal to patch to define dummy face values

        DO idum=idumb(1),idume(1)
          DO jdum=jdumb(1),jdume(1)
            DO kdum=kdumb(1),kdume(1) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff)  ! dummy points
              ijkni = indijk(i+ig(1)-idum,j+jg(1)-jdum,k+kg(1)-kdum,inoff,ijnoff) ! interior
              region%levels(ilev)%turb%workI(1,ijknd) = &
              region%levels(ilev)%turb%workI(1,ijkni)
              region%levels(ilev)%turb%workI(2,ijknd) = &
              region%levels(ilev)%turb%workI(2,ijkni)
            ENDDO
          ENDDO  
        ENDDO    

        DO idum=idumb(2),idume(2)
          DO jdum=jdumb(2),jdume(2)
            DO kdum=kdumb(2),kdume(2) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff) ! dummy points
              ijknj = indijk(i+ig(2)-idum,j+jg(2)-jdum,k+kg(2)-kdum,inoff,ijnoff) ! interior
              region%levels(ilev)%turb%workJ(1,ijknd) = &
              region%levels(ilev)%turb%workJ(1,ijknj)
              region%levels(ilev)%turb%workJ(2,ijknd) = &
              region%levels(ilev)%turb%workJ(2,ijknj)
            ENDDO
          ENDDO
        ENDDO

        DO idum=idumb(3),idume(3)
          DO jdum=jdumb(3),jdume(3)
            DO kdum=kdumb(3),kdume(3) 
              ijknd = indijk(i+idum,j+jdum,k+kdum,inoff,ijnoff) ! dummy points
              ijknk = indijk(i+ig(3)-idum,j+jg(3)-jdum,k+kg(3)-kdum,inoff,ijnoff) ! interior
              region%levels(ilev)%turb%workK(1,ijknd) = &
              region%levels(ilev)%turb%workK(1,ijknk)
              region%levels(ilev)%turb%workK(2,ijknd) = &
              region%levels(ilev)%turb%workK(2,ijknk)
            ENDDO
          ENDDO
        ENDDO

      ENDDO   ! i
    ENDDO     ! j
  ENDDO       ! k

! finalize --------------------------------------------------------------------

  CALL deregisterfunction( global )

END SUBROUTINE turb_flofacewidthdummyphys

!******************************************************************************
!
! RCS Revision history:
! 
! $Log: TURB_floFaceWidthDummyPhys.F90,v $
! Revision 1.5  2008/12/06 08:44:43  mtcampbe
! Updated license.
!
! Revision 1.4  2008/11/19 22:17:55  mtcampbe
! Added Illinois Open Source License/Copyright
!
! Revision 1.3  2004/08/04 02:49:46  wasistho
! removed turb%avgCoI,J,K as it is defined as grid%c2fCoI,J,K
!
! Revision 1.2  2004/03/12 02:55:35  wasistho
! changed rocturb routine names
!
! Revision 1.1  2004/03/08 23:35:45  wasistho
! changed turb nomenclature
!
! Revision 1.2  2003/05/15 02:57:06  jblazek
! Inlined index function.
!
! Revision 1.1  2002/10/14 23:55:29  wasistho
! Install Rocturb
!
!******************************************************************************